puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  24
  25   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  26
  27   if $enable_load_balancer {
  28     class { '::tripleo::loadbalancer' :
  29       controller_hosts => $controller_node_ips,
  30       manage_vip       => true,
  31     }
  32   }
  33
  34 }
  35
  36 if hiera('step') >= 2 {
  37
  38   if count(hiera('ntp::servers')) > 0 {
  39     include ::ntp
  40   }
  41
  42   include ::timezone
  43
  44   # MongoDB
  45   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  46     include ::mongodb::globals
  47
  48     include ::mongodb::server
  49     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  50     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  51
  52     $mongodb_replset = hiera('mongodb::server::replset')
  53     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  54     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  55       mongodb_replset { $mongodb_replset :
  56         members => $mongo_node_ips_with_port,
  57       }
  58     }
  59   }
  60
  61   # Redis
  62   $redis_node_ips = hiera('redis_node_ips')
  63   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  64
  65   if $redis_master_hostname == $::hostname {
  66     $slaveof = undef
  67   } else {
  68     $slaveof = "${redis_master_hostname} 6379"
  69   }
  70   class {'::redis' :
  71     slaveof => $slaveof,
  72   }
  73
  74   if count($redis_node_ips) > 1 {
  75     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  76     include ::redis::sentinel
  77     include ::tripleo::redis_notification
  78   }
  79
  80   if str2bool(hiera('enable_galera', true)) {
  81     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  82   } else {
  83     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  84   }
  85   # TODO Galara
  86   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  87   # set bind-address to a hostname instead of an ip address; to move Mysql
  88   # from internal_api on another network we'll have to customize both
  89   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  90   class { '::mysql::server':
  91     config_file             => $mysql_config_file,
  92     override_options        => {
  93       'mysqld' => {
  94         'bind-address'     => $::hostname,
  95         'max_connections'  => hiera('mysql_max_connections'),
  96         'open_files_limit' => '-1',
  97       },
  98     },
  99     remove_default_accounts => true,
 100   }
 101
 102   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 103   # Create all the database schemas
 104   include ::keystone::db::mysql
 105   include ::glance::db::mysql
 106   include ::nova::db::mysql
 107   include ::neutron::db::mysql
 108   include ::cinder::db::mysql
 109   include ::heat::db::mysql
 110   include ::sahara::db::mysql
 111   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 112     include ::ceilometer::db::mysql
 113   }
 114
 115   $rabbit_nodes = hiera('rabbit_node_ips')
 116   if count($rabbit_nodes) > 1 {
 117     class { '::rabbitmq':
 118       config_cluster          => true,
 119       cluster_nodes           => $rabbit_nodes,
 120       tcp_keepalive           => false,
 121       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 122       config_variables        => hiera('rabbitmq_config_variables'),
 123       environment_variables   => hiera('rabbitmq_environment'),
 124     }
 125     rabbitmq_policy { 'ha-all@/':
 126       pattern    => '^(?!amq\.).*',
 127       definition => {
 128         'ha-mode' => 'all',
 129       },
 130     }
 131   } else {
 132     include ::rabbitmq
 133   }
 134
 135   # pre-install swift here so we can build rings
 136   include ::swift
 137
 138   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 139
 140   if $enable_ceph {
 141     class { '::ceph::profile::params':
 142       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 143     }
 144     include ::ceph::profile::mon
 145   }
 146
 147   if str2bool(hiera('enable_ceph_storage', false)) {
 148     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 149       exec { 'set selinux to permissive on boot':
 150         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 151         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 152         path    => ['/usr/bin', '/usr/sbin'],
 153       }
 154
 155       exec { 'set selinux to permissive':
 156         command => 'setenforce 0',
 157         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 158         path    => ['/usr/bin', '/usr/sbin'],
 159       } -> Class['ceph::profile::osd']
 160     }
 161
 162     include ::ceph::profile::osd
 163   }
 164
 165   if str2bool(hiera('enable_external_ceph', false)) {
 166     include ::ceph::profile::client
 167   }
 168
 169 } #END STEP 2
 170
 171 if hiera('step') >= 3 {
 172
 173   include ::keystone
 174   include ::keystone::roles::admin
 175   include ::keystone::endpoint
 176
 177   #TODO: need a cleanup-keystone-tokens.sh solution here
 178   keystone_config {
 179     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 180   }
 181   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 182     ensure  => 'directory',
 183     owner   => 'keystone',
 184     group   => 'keystone',
 185     require => Package['keystone'],
 186   }
 187   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 188     content => hiera('keystone_signing_certificate'),
 189     owner   => 'keystone',
 190     group   => 'keystone',
 191     notify  => Service['keystone'],
 192     require => File['/etc/keystone/ssl/certs'],
 193   }
 194   file { '/etc/keystone/ssl/private/signing_key.pem':
 195     content => hiera('keystone_signing_key'),
 196     owner   => 'keystone',
 197     group   => 'keystone',
 198     notify  => Service['keystone'],
 199     require => File['/etc/keystone/ssl/private'],
 200   }
 201   file { '/etc/keystone/ssl/certs/ca.pem':
 202     content => hiera('keystone_ca_certificate'),
 203     owner   => 'keystone',
 204     group   => 'keystone',
 205     notify  => Service['keystone'],
 206     require => File['/etc/keystone/ssl/certs'],
 207   }
 208
 209   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 210   case $glance_backend {
 211       'swift': { $backend_store = 'glance.store.swift.Store' }
 212       'file': { $backend_store = 'glance.store.filesystem.Store' }
 213       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 214       default: { fail('Unrecognized glance_backend parameter.') }
 215   }
 216   $http_store = ['glance.store.http.Store']
 217   $glance_store = concat($http_store, $backend_store)
 218
 219   # TODO: notifications, scrubber, etc.
 220   include ::glance
 221   class { '::glance::api':
 222     known_stores => $glance_store,
 223   }
 224   include ::glance::registry
 225   include join(['::glance::backend::', $glance_backend])
 226
 227   class { '::nova' :
 228     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 229   }
 230   include ::nova::config
 231   include ::nova::api
 232   include ::nova::cert
 233   include ::nova::conductor
 234   include ::nova::consoleauth
 235   include ::nova::network::neutron
 236   include ::nova::vncproxy
 237   include ::nova::scheduler
 238   include ::nova::scheduler::filter
 239
 240   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 241
 242     # TODO(devvesa) provide non-controller ips for these services
 243     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 244     $cassandra_node_ips = hiera('neutron_api_node_ips')
 245
 246     # Run zookeeper in the controller if configured
 247     if hiera('enable_zookeeper_on_controller') {
 248       class {'::tripleo::cluster::zookeeper':
 249         zookeeper_server_ips => $zookeeper_node_ips,
 250         zookeeper_client_ip  => $ipaddress,
 251         zookeeper_hostnames  => hiera('controller_node_names')
 252       }
 253     }
 254
 255     # Run cassandra in the controller if configured
 256     if hiera('enable_cassandra_on_controller') {
 257       class {'::tripleo::cluster::cassandra':
 258         cassandra_servers => $cassandra_node_ips,
 259         cassandra_ip      => $ipaddress
 260       }
 261     }
 262
 263     class {'::tripleo::network::midonet::agent':
 264       zookeeper_servers => $zookeeper_node_ips,
 265       cassandra_seeds   => $cassandra_node_ips
 266     }
 267
 268     class {'::tripleo::network::midonet::api':
 269       zookeeper_servers    => $zookeeper_node_ips,
 270       vip                  => $ipaddress,
 271       keystone_ip          => $ipaddress,
 272       keystone_admin_token => hiera('keystone::admin_token'),
 273       bind_address         => $ipaddress,
 274       admin_password       => hiera('admin_password')
 275     }
 276
 277     # TODO: find a way to get an empty list from hiera
 278     class {'::neutron':
 279       service_plugins => []
 280     }
 281
 282   }
 283   else {
 284
 285     # ML2 plugin
 286     include ::neutron
 287   }
 288
 289   include ::neutron::server
 290   include ::neutron::server::notifications
 291
 292   # If the value of core plugin is set to 'nuage',
 293   # include nuage core plugin, and it does not
 294   # need the l3, dhcp and metadata agents
 295   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 296     include ::neutron::plugins::nuage
 297   } else {
 298     include ::neutron::agents::l3
 299     include ::neutron::agents::dhcp
 300     include ::neutron::agents::metadata
 301
 302     file { '/etc/neutron/dnsmasq-neutron.conf':
 303       content => hiera('neutron_dnsmasq_options'),
 304       owner   => 'neutron',
 305       group   => 'neutron',
 306       notify  => Service['neutron-dhcp-service'],
 307       require => Package['neutron'],
 308     }
 309
 310     # If the value of core plugin is set to 'midonet',
 311     # skip all the ML2 configuration
 312     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 313
 314       class {'::neutron::plugins::midonet':
 315         midonet_api_ip    => $ipaddress,
 316         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 317         keystone_password => hiera('neutron::server::auth_password')
 318       }
 319     } else {
 320
 321       include ::neutron::plugins::ml2
 322       include ::neutron::agents::ml2::ovs
 323
 324       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 325         include ::neutron::plugins::ml2::cisco::nexus1000v
 326
 327         class { '::neutron::agents::n1kv_vem':
 328           n1kv_source  => hiera('n1kv_vem_source', undef),
 329           n1kv_version => hiera('n1kv_vem_version', undef),
 330         }
 331
 332         class { '::n1k_vsm':
 333           n1kv_source       => hiera('n1kv_vsm_source', undef),
 334           n1kv_version      => hiera('n1kv_vsm_version', undef),
 335           pacemaker_control => false,
 336         }
 337       }
 338
 339       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 340         include ::neutron::plugins::ml2::cisco::ucsm
 341       }
 342       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 343         include ::neutron::plugins::ml2::cisco::nexus
 344         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 345       }
 346
 347       if hiera('neutron_enable_bigswitch_ml2', false) {
 348         include ::neutron::plugins::ml2::bigswitch::restproxy
 349       }
 350       neutron_l3_agent_config {
 351         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 352       }
 353       neutron_dhcp_agent_config {
 354         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 355       }
 356       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 357     }
 358
 359     Service['neutron-server'] -> Service['neutron-dhcp-service']
 360     Service['neutron-server'] -> Service['neutron-l3']
 361     Service['neutron-server'] -> Service['neutron-metadata']
 362   }
 363
 364   include ::cinder
 365   include ::cinder::api
 366   include ::cinder::glance
 367   include ::cinder::scheduler
 368   include ::cinder::volume
 369   class { '::cinder::setup_test_volume':
 370     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 371   }
 372
 373   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 374   if $cinder_enable_iscsi {
 375     $cinder_iscsi_backend = 'tripleo_iscsi'
 376
 377     cinder::backend::iscsi { $cinder_iscsi_backend :
 378       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 379       iscsi_helper     => hiera('cinder_iscsi_helper'),
 380     }
 381   }
 382
 383   if $enable_ceph {
 384
 385     $ceph_pools = hiera('ceph_pools')
 386     ceph::pool { $ceph_pools :
 387       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 388       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 389       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 390     }
 391
 392     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 393
 394   } else {
 395     $cinder_pool_requires = []
 396   }
 397
 398   if hiera('cinder_enable_rbd_backend', false) {
 399     $cinder_rbd_backend = 'tripleo_ceph'
 400
 401     cinder::backend::rbd { $cinder_rbd_backend :
 402       rbd_pool        => hiera('cinder_rbd_pool_name'),
 403       rbd_user        => hiera('ceph_client_user_name'),
 404       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 405       require         => $cinder_pool_requires,
 406     }
 407   }
 408
 409   if hiera('cinder_enable_eqlx_backend', false) {
 410     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 411
 412     cinder_config {
 413       "${cinder_eqlx_backend}/host": value => 'hostgroup';
 414     }
 415
 416     cinder::backend::eqlx { $cinder_eqlx_backend :
 417       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 418       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 419       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 420       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 421       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 422       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 423       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_lpool', undef),
 424       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 425       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 426       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 427     }
 428   }
 429
 430   if hiera('cinder_enable_dellsc_backend', false) {
 431     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 432
 433     cinder_config {
 434       "${cinder_dellsc_backend}/host": value => 'hostgroup';
 435     }
 436
 437     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 438       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 439       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 440       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 441       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 442       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 443       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 444       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 445       dell_sc_port          => hiera('cinder::backend::dellsc_iscsi::dell_sc_port', undef),
 446       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 447       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 448     }
 449   }
 450
 451   if hiera('cinder_enable_netapp_backend', false) {
 452     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 453
 454     cinder_config {
 455       "${cinder_netapp_backend}/host": value => 'hostgroup';
 456     }
 457
 458     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 459       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 460     }
 461
 462     cinder::backend::netapp { $cinder_netapp_backend :
 463       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 464       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 465       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 466       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 467       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 468       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 469       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 470       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 471       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 472       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 473       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 474       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 475       nfs_shares                   => $cinder_netapp_nfs_shares,
 476       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 477       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 478       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 479       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 480       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 481       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 482       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 483     }
 484   }
 485
 486   if hiera('cinder_enable_nfs_backend', false) {
 487     $cinder_nfs_backend = 'tripleo_nfs'
 488
 489     if str2bool($::selinux) {
 490       selboolean { 'virt_use_nfs':
 491         value      => on,
 492         persistent => true,
 493       } -> Package['nfs-utils']
 494     }
 495
 496     package {'nfs-utils': } ->
 497     cinder::backend::nfs { $cinder_nfs_backend :
 498       nfs_servers       => hiera('cinder_nfs_servers'),
 499       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 500       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 501     }
 502   }
 503
 504   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 505   class { '::cinder::backends' :
 506     enabled_backends => $cinder_enabled_backends,
 507   }
 508
 509   # swift proxy
 510   include ::memcached
 511   include ::swift::proxy
 512   include ::swift::proxy::proxy_logging
 513   include ::swift::proxy::healthcheck
 514   include ::swift::proxy::cache
 515   include ::swift::proxy::keystone
 516   include ::swift::proxy::authtoken
 517   include ::swift::proxy::staticweb
 518   include ::swift::proxy::ratelimit
 519   include ::swift::proxy::catch_errors
 520   include ::swift::proxy::tempurl
 521   include ::swift::proxy::formpost
 522
 523   # swift storage
 524   if str2bool(hiera('enable_swift_storage', true)) {
 525     class { '::swift::storage::all':
 526       mount_check => str2bool(hiera('swift_mount_check')),
 527     }
 528     if(!defined(File['/srv/node'])) {
 529       file { '/srv/node':
 530         ensure  => directory,
 531         owner   => 'swift',
 532         group   => 'swift',
 533         require => Package['openstack-swift'],
 534       }
 535     }
 536     $swift_components = ['account', 'container', 'object']
 537     swift::storage::filter::recon { $swift_components : }
 538     swift::storage::filter::healthcheck { $swift_components : }
 539   }
 540
 541   # Ceilometer
 542   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 543   case $ceilometer_backend {
 544     /mysql/ : {
 545       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 546     }
 547     default : {
 548       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 549     }
 550   }
 551   include ::ceilometer
 552   include ::ceilometer::config
 553   include ::ceilometer::api
 554   include ::ceilometer::agent::notification
 555   include ::ceilometer::agent::central
 556   include ::ceilometer::expirer
 557   include ::ceilometer::collector
 558   include ::ceilometer::agent::auth
 559   class { '::ceilometer::db' :
 560     database_connection => $ceilometer_database_connection,
 561   }
 562
 563   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 564
 565   # Heat
 566   include ::heat
 567   include ::heat::api
 568   include ::heat::api_cfn
 569   include ::heat::api_cloudwatch
 570   include ::heat::engine
 571
 572   # Sahara
 573   include ::sahara
 574   include ::sahara::service::api
 575   include ::sahara::service::engine
 576
 577   # Horizon
 578   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 579     $_profile_support = 'cisco'
 580   } else {
 581     $_profile_support = 'None'
 582   }
 583   $neutron_options   = {'profile_support' => $_profile_support }
 584
 585   class { '::horizon':
 586     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 587     neutron_options => $neutron_options,
 588   }
 589
 590   $snmpd_user = hiera('snmpd_readonly_user_name')
 591   snmp::snmpv3_user { $snmpd_user:
 592     authtype => 'MD5',
 593     authpass => hiera('snmpd_readonly_user_password'),
 594   }
 595   class { '::snmp':
 596     agentaddress => ['udp:161','udp6:[::1]:161'],
 597     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 598   }
 599
 600   hiera_include('controller_classes')
 601
 602 } #END STEP 3
 603
 604 if hiera('step') >= 4 {
 605   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 606   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 607   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 608
 609   if $keystone_enable_db_purge {
 610     include ::keystone::cron::token_flush
 611   }
 612   if $nova_enable_db_purge {
 613     include ::nova::cron::archive_deleted_rows
 614   }
 615   if $cinder_enable_db_purge {
 616     include ::cinder::cron::db_purge
 617   }
 618 } #END STEP 4
 619
 620 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 621 package_manifest{$package_manifest_name: ensure => present}