puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17
  18 $enable_load_balancer = hiera('enable_load_balancer', true)
  19
  20 if hiera('step') >= 1 {
  21
  22   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  23
  24   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  25
  26   if $enable_load_balancer {
  27     class { '::tripleo::loadbalancer' :
  28       controller_hosts => $controller_node_ips,
  29       manage_vip       => true,
  30     }
  31   }
  32
  33 }
  34
  35 if hiera('step') >= 2 {
  36
  37   if count(hiera('ntp::servers')) > 0 {
  38     include ::ntp
  39   }
  40
  41   # MongoDB
  42   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  43     include ::mongodb::globals
  44
  45     include ::mongodb::server
  46     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  47     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  48
  49     $mongodb_replset = hiera('mongodb::server::replset')
  50     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  51     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  52       mongodb_replset { $mongodb_replset :
  53         members => $mongo_node_ips_with_port,
  54       }
  55     }
  56   }
  57
  58   # Redis
  59   $redis_node_ips = hiera('redis_node_ips')
  60   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  61
  62   if $redis_master_hostname == $::hostname {
  63     $slaveof = undef
  64   } else {
  65     $slaveof = "${redis_master_hostname} 6379"
  66   }
  67   class {'::redis' :
  68     slaveof => $slaveof,
  69   }
  70
  71   if count($redis_node_ips) > 1 {
  72     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  73     include ::redis::sentinel
  74     include ::tripleo::redis_notification
  75   }
  76
  77   if str2bool(hiera('enable_galera', true)) {
  78     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  79   } else {
  80     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  81   }
  82   # TODO Galara
  83   class { '::mysql::server':
  84     config_file             => $mysql_config_file,
  85     override_options        => {
  86       'mysqld' => {
  87         'bind-address'     => hiera('mysql_bind_host'),
  88         'max_connections'  => hiera('mysql_max_connections'),
  89         'open_files_limit' => '-1',
  90       },
  91     },
  92     remove_default_accounts => true,
  93   }
  94
  95   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  96   # Create all the database schemas
  97   include ::keystone::db::mysql
  98   include ::glance::db::mysql
  99   include ::nova::db::mysql
 100   include ::neutron::db::mysql
 101   include ::cinder::db::mysql
 102   include ::heat::db::mysql
 103   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 104     include ::ceilometer::db::mysql
 105   }
 106
 107   $rabbit_nodes = hiera('rabbit_node_ips')
 108   if count($rabbit_nodes) > 1 {
 109     class { '::rabbitmq':
 110       config_cluster          => true,
 111       cluster_nodes           => $rabbit_nodes,
 112       tcp_keepalive           => false,
 113       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 114       config_variables        => hiera('rabbitmq_config_variables'),
 115       environment_variables   => hiera('rabbitmq_environment'),
 116     }
 117     rabbitmq_policy { 'ha-all@/':
 118       pattern    => '^(?!amq\.).*',
 119       definition => {
 120         'ha-mode' => 'all',
 121       },
 122     }
 123   } else {
 124     include ::rabbitmq
 125   }
 126
 127   # pre-install swift here so we can build rings
 128   include ::swift
 129
 130   $enable_ceph = hiera('ceph_storage_count', 0) > 0
 131
 132   if $enable_ceph {
 133     class { '::ceph::profile::params':
 134       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 135     }
 136     include ::ceph::profile::mon
 137   }
 138
 139   if str2bool(hiera('enable_ceph_storage', false)) {
 140     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 141       exec { 'set selinux to permissive on boot':
 142         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 143         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 144         path    => ['/usr/bin', '/usr/sbin'],
 145       }
 146
 147       exec { 'set selinux to permissive':
 148         command => 'setenforce 0',
 149         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 150         path    => ['/usr/bin', '/usr/sbin'],
 151       } -> Class['ceph::profile::osd']
 152     }
 153
 154     include ::ceph::profile::osd
 155   }
 156
 157   if str2bool(hiera('enable_external_ceph', false)) {
 158     include ::ceph::profile::client
 159   }
 160
 161 } #END STEP 2
 162
 163 if hiera('step') >= 3 {
 164
 165   include ::keystone
 166   include ::keystone::roles::admin
 167   include ::keystone::endpoint
 168
 169   #TODO: need a cleanup-keystone-tokens.sh solution here
 170   keystone_config {
 171     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 172   }
 173   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 174     ensure  => 'directory',
 175     owner   => 'keystone',
 176     group   => 'keystone',
 177     require => Package['keystone'],
 178   }
 179   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 180     content => hiera('keystone_signing_certificate'),
 181     owner   => 'keystone',
 182     group   => 'keystone',
 183     notify  => Service['keystone'],
 184     require => File['/etc/keystone/ssl/certs'],
 185   }
 186   file { '/etc/keystone/ssl/private/signing_key.pem':
 187     content => hiera('keystone_signing_key'),
 188     owner   => 'keystone',
 189     group   => 'keystone',
 190     notify  => Service['keystone'],
 191     require => File['/etc/keystone/ssl/private'],
 192   }
 193   file { '/etc/keystone/ssl/certs/ca.pem':
 194     content => hiera('keystone_ca_certificate'),
 195     owner   => 'keystone',
 196     group   => 'keystone',
 197     notify  => Service['keystone'],
 198     require => File['/etc/keystone/ssl/certs'],
 199   }
 200
 201   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 202   case $glance_backend {
 203       'swift': { $backend_store = 'glance.store.swift.Store' }
 204       'file': { $backend_store = 'glance.store.filesystem.Store' }
 205       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 206       default: { fail('Unrecognized glance_backend parameter.') }
 207   }
 208   $http_store = ['glance.store.http.Store']
 209   $glance_store = concat($http_store, $backend_store)
 210
 211   # TODO: notifications, scrubber, etc.
 212   include ::glance
 213   class { '::glance::api':
 214     known_stores => $glance_store,
 215   }
 216   include ::glance::registry
 217   include join(['::glance::backend::', $glance_backend])
 218
 219   class { '::nova' :
 220     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 221   }
 222   include ::nova::config
 223   include ::nova::api
 224   include ::nova::cert
 225   include ::nova::conductor
 226   include ::nova::consoleauth
 227   include ::nova::network::neutron
 228   include ::nova::vncproxy
 229   include ::nova::scheduler
 230   include ::nova::scheduler::filter
 231
 232   include ::neutron
 233   include ::neutron::server
 234   include ::neutron::server::notifications
 235   include ::neutron::agents::l3
 236   include ::neutron::agents::dhcp
 237   include ::neutron::agents::metadata
 238
 239   file { '/etc/neutron/dnsmasq-neutron.conf':
 240     content => hiera('neutron_dnsmasq_options'),
 241     owner   => 'neutron',
 242     group   => 'neutron',
 243     notify  => Service['neutron-dhcp-service'],
 244     require => Package['neutron'],
 245   }
 246
 247   class { '::neutron::plugins::ml2':
 248     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 249     tenant_network_types => [hiera('neutron_tenant_network_type')],
 250     mechanism_drivers    => [hiera('neutron_mechanism_drivers')],
 251   }
 252   class { '::neutron::agents::ml2::ovs':
 253     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 254     tunnel_types    => split(hiera('neutron_tunnel_types'), ','),
 255   }
 256   if 'cisco_n1kv' in hiera('neutron_mechanism_drivers') {
 257     include ::neutron::plugins::ml2::cisco::nexus1000v
 258
 259     class { '::neutron::agents::n1kv_vem':
 260       n1kv_source  => hiera('n1kv_vem_source', undef),
 261       n1kv_version => hiera('n1kv_vem_version', undef),
 262     }
 263
 264     class { '::n1k_vsm':
 265       n1kv_source       => hiera('n1kv_vsm_source', undef),
 266       n1kv_version      => hiera('n1kv_vsm_version', undef),
 267       pacemaker_control => false,
 268     }
 269   }
 270
 271   if 'cisco_ucsm' in hiera('neutron_mechanism_drivers') {
 272     include ::neutron::plugins::ml2::cisco::ucsm
 273   }
 274   if 'cisco_nexus' in hiera('neutron_mechanism_drivers') {
 275     include ::neutron::plugins::ml2::cisco::nexus
 276     include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 277   }
 278
 279   if hiera('neutron_enable_bigswitch_ml2', false) {
 280     include ::neutron::plugins::ml2::bigswitch::restproxy
 281   }
 282   neutron_l3_agent_config {
 283     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 284   }
 285   neutron_dhcp_agent_config {
 286     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 287   }
 288
 289   Service['neutron-server'] -> Service['neutron-dhcp-service']
 290   Service['neutron-server'] -> Service['neutron-l3']
 291   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 292   Service['neutron-server'] -> Service['neutron-metadata']
 293
 294   include ::cinder
 295   include ::cinder::api
 296   include ::cinder::glance
 297   include ::cinder::scheduler
 298   include ::cinder::volume
 299   class { '::cinder::setup_test_volume':
 300     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 301   }
 302
 303   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 304   if $cinder_enable_iscsi {
 305     $cinder_iscsi_backend = 'tripleo_iscsi'
 306
 307     cinder::backend::iscsi { $cinder_iscsi_backend :
 308       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 309       iscsi_helper     => hiera('cinder_iscsi_helper'),
 310     }
 311   }
 312
 313   if $enable_ceph {
 314
 315     $ceph_pools = hiera('ceph_pools')
 316     ceph::pool { $ceph_pools :
 317       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 318       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 319       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 320     }
 321
 322     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 323
 324   } else {
 325     $cinder_pool_requires = []
 326   }
 327
 328   if hiera('cinder_enable_rbd_backend', false) {
 329     $cinder_rbd_backend = 'tripleo_ceph'
 330
 331     cinder::backend::rbd { $cinder_rbd_backend :
 332       rbd_pool        => hiera('cinder_rbd_pool_name'),
 333       rbd_user        => hiera('ceph_client_user_name'),
 334       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 335       require         => $cinder_pool_requires,
 336     }
 337   }
 338
 339   if hiera('cinder_enable_netapp_backend', false) {
 340     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 341
 342     cinder_config {
 343       "${cinder_netapp_backend}/host": value => 'hostgroup';
 344     }
 345
 346     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 347       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 348     }
 349
 350     cinder::backend::netapp { $cinder_netapp_backend :
 351       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 352       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 353       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 354       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 355       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 356       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 357       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 358       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 359       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 360       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 361       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 362       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 363       nfs_shares                   => $cinder_netapp_nfs_shares,
 364       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 365       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 366       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 367       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 368       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 369       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 370       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 371     }
 372   }
 373
 374   if hiera('cinder_enable_nfs_backend', false) {
 375     $cinder_nfs_backend = 'tripleo_nfs'
 376
 377     if str2bool($::selinux) {
 378       selboolean { 'virt_use_nfs':
 379         value      => on,
 380         persistent => true,
 381       } -> Package['nfs-utils']
 382     }
 383
 384     package {'nfs-utils': } ->
 385     cinder::backend::nfs { $cinder_nfs_backend :
 386       nfs_servers       => hiera('cinder_nfs_servers'),
 387       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 388       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 389     }
 390   }
 391
 392   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 393   class { '::cinder::backends' :
 394     enabled_backends => $cinder_enabled_backends,
 395   }
 396
 397   # swift proxy
 398   include ::memcached
 399   include ::swift::proxy
 400   include ::swift::proxy::proxy_logging
 401   include ::swift::proxy::healthcheck
 402   include ::swift::proxy::cache
 403   include ::swift::proxy::keystone
 404   include ::swift::proxy::authtoken
 405   include ::swift::proxy::staticweb
 406   include ::swift::proxy::ratelimit
 407   include ::swift::proxy::catch_errors
 408   include ::swift::proxy::tempurl
 409   include ::swift::proxy::formpost
 410
 411   # swift storage
 412   if str2bool(hiera('enable_swift_storage', true)) {
 413     class { '::swift::storage::all':
 414       mount_check => str2bool(hiera('swift_mount_check')),
 415     }
 416     if(!defined(File['/srv/node'])) {
 417       file { '/srv/node':
 418         ensure  => directory,
 419         owner   => 'swift',
 420         group   => 'swift',
 421         require => Package['openstack-swift'],
 422       }
 423     }
 424     $swift_components = ['account', 'container', 'object']
 425     swift::storage::filter::recon { $swift_components : }
 426     swift::storage::filter::healthcheck { $swift_components : }
 427   }
 428
 429   # Ceilometer
 430   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 431   case $ceilometer_backend {
 432     /mysql/ : {
 433       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 434     }
 435     default : {
 436       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 437     }
 438   }
 439   include ::ceilometer
 440   include ::ceilometer::config
 441   include ::ceilometer::api
 442   include ::ceilometer::agent::notification
 443   include ::ceilometer::agent::central
 444   include ::ceilometer::alarm::notifier
 445   include ::ceilometer::alarm::evaluator
 446   include ::ceilometer::expirer
 447   include ::ceilometer::collector
 448   include ::ceilometer::agent::auth
 449   class { '::ceilometer::db' :
 450     database_connection => $ceilometer_database_connection,
 451   }
 452
 453   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 454
 455   # Heat
 456   include ::heat
 457   include ::heat::api
 458   include ::heat::api_cfn
 459   include ::heat::api_cloudwatch
 460   include ::heat::engine
 461
 462   # Horizon
 463   if 'cisco_n1kv' in hiera('neutron_mechanism_drivers') {
 464     $_profile_support = 'cisco'
 465   } else {
 466     $_profile_support = 'None'
 467   }
 468   $neutron_options   = {'profile_support' => $_profile_support }
 469
 470   class { '::horizon':
 471     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 472     neutron_options => $neutron_options,
 473   }
 474
 475   $snmpd_user = hiera('snmpd_readonly_user_name')
 476   snmp::snmpv3_user { $snmpd_user:
 477     authtype => 'MD5',
 478     authpass => hiera('snmpd_readonly_user_password'),
 479   }
 480   class { '::snmp':
 481     agentaddress => ['udp:161','udp6:[::1]:161'],
 482     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 483   }
 484
 485   hiera_include('controller_classes')
 486
 487 } #END STEP 3
 488
 489 if hiera('step') >= 4 {
 490   include ::keystone::cron::token_flush
 491 } #END STEP 4
 492
 493 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 494 package_manifest{$package_manifest_name: ensure => present}