puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if hiera('step') >= 1 {
  28
  29   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  30   $enable_pacemaker = str2bool(hiera('enable_pacemaker'))
  31   $enable_keepalived = !$enable_pacemaker
  32
  33   class { '::tripleo::loadbalancer' :
  34     controller_hosts => $controller_node_ips,
  35     manage_vip       => $enable_keepalived,
  36   }
  37
  38   if $enable_pacemaker {
  39     $pacemaker_cluster_members = regsubst(hiera('controller_node_ips'), ',', ' ', 'G')
  40     if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  41       $pacemaker_master = true
  42     } else {
  43       $pacemaker_master = false
  44     }
  45     user { 'hacluster':
  46      ensure => present,
  47     } ->
  48     class { '::pacemaker':
  49       hacluster_pwd => hiera('hacluster_pwd'),
  50     } ->
  51     class { '::pacemaker::corosync':
  52       cluster_members => $pacemaker_cluster_members,
  53       setup_cluster   => $pacemaker_master,
  54     }
  55     class { '::pacemaker::stonith':
  56       disable => true,
  57     }
  58     if $pacemaker_master {
  59       $control_vip = hiera('tripleo::loadbalancer::controller_virtual_ip')
  60       pacemaker::resource::ip { 'control_vip':
  61         ip_address => $control_vip,
  62       }
  63       $public_vip = hiera('tripleo::loadbalancer::public_virtual_ip')
  64       pacemaker::resource::ip { 'public_vip':
  65         ip_address => $public_vip,
  66       }
  67       pacemaker::resource::systemd { 'haproxy':
  68         clone => true,
  69       }
  70     }
  71   }
  72
  73 }
  74
  75 if hiera('step') >= 2 {
  76
  77   if count(hiera('ntp::servers')) > 0 {
  78     include ::ntp
  79   }
  80
  81   # MongoDB
  82   include ::mongodb::globals
  83   include ::mongodb::server
  84   $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
  85   $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
  86   $mongo_node_string = join($mongo_node_ips_with_port, ',')
  87
  88   $mongodb_replset = hiera('mongodb::server::replset')
  89   $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  90   if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  91     mongodb_replset { $mongodb_replset :
  92       members => $mongo_node_ips_with_port,
  93     }
  94   }
  95
  96   # Redis
  97   $redis_node_ips = split(hiera('redis_node_ips'), ',')
  98   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  99
 100   if $redis_master_hostname == $::hostname {
 101     $slaveof = undef
 102   } else {
 103     $slaveof = "${redis_master_hostname} 6379"
 104   }
 105   class {'::redis' :
 106     slaveof => $slaveof,
 107   }
 108
 109   if count($redis_node_ips) > 1 {
 110     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
 111     include ::redis::sentinel
 112     class {'::tripleo::redis_notification' :
 113       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 114     }
 115   }
 116
 117   if str2bool(hiera('enable_galera', 'true')) {
 118     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 119   } else {
 120     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 121   }
 122   # TODO Galara
 123   class { 'mysql::server':
 124     config_file => $mysql_config_file,
 125     override_options => {
 126       'mysqld' => {
 127         'bind-address' => hiera('controller_host')
 128       }
 129     }
 130   }
 131
 132   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 133   # Create all the database schemas
 134   # Example DSN format: mysql://user:password@host/dbname
 135   $allowed_hosts = ['%',hiera('controller_host')]
 136   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 137   class { 'keystone::db::mysql':
 138     user          => $keystone_dsn[3],
 139     password      => $keystone_dsn[4],
 140     host          => $keystone_dsn[5],
 141     dbname        => $keystone_dsn[6],
 142     allowed_hosts => $allowed_hosts,
 143   }
 144   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 145   class { 'glance::db::mysql':
 146     user          => $glance_dsn[3],
 147     password      => $glance_dsn[4],
 148     host          => $glance_dsn[5],
 149     dbname        => $glance_dsn[6],
 150     allowed_hosts => $allowed_hosts,
 151   }
 152   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 153   class { 'nova::db::mysql':
 154     user          => $nova_dsn[3],
 155     password      => $nova_dsn[4],
 156     host          => $nova_dsn[5],
 157     dbname        => $nova_dsn[6],
 158     allowed_hosts => $allowed_hosts,
 159   }
 160   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 161   class { 'neutron::db::mysql':
 162     user          => $neutron_dsn[3],
 163     password      => $neutron_dsn[4],
 164     host          => $neutron_dsn[5],
 165     dbname        => $neutron_dsn[6],
 166     allowed_hosts => $allowed_hosts,
 167   }
 168   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 169   class { 'cinder::db::mysql':
 170     user          => $cinder_dsn[3],
 171     password      => $cinder_dsn[4],
 172     host          => $cinder_dsn[5],
 173     dbname        => $cinder_dsn[6],
 174     allowed_hosts => $allowed_hosts,
 175   }
 176   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 177   class { 'heat::db::mysql':
 178     user          => $heat_dsn[3],
 179     password      => $heat_dsn[4],
 180     host          => $heat_dsn[5],
 181     dbname        => $heat_dsn[6],
 182     allowed_hosts => $allowed_hosts,
 183   }
 184
 185   $rabbit_nodes = split(downcase(hiera('rabbit_node_names', $::hostname)), ',')
 186   if count($rabbit_nodes) > 1 {
 187     $rabbit_cluster = true
 188   }
 189   else {
 190     $rabbit_cluster = false
 191   }
 192   class { 'rabbitmq':
 193     config_cluster   => $rabbit_cluster,
 194     cluster_nodes    => $rabbit_nodes,
 195     node_ip_address  => hiera('controller_host'),
 196   }
 197   if $rabbit_cluster {
 198     rabbitmq_policy { 'ha-all@/':
 199       pattern    => '^(?!amq\.).*',
 200       definition => {
 201         'ha-mode'      => 'all',
 202         'ha-sync-mode' => 'automatic',
 203       },
 204     }
 205   }
 206   rabbitmq_vhost { '/':
 207     provider => 'rabbitmqctl',
 208   }
 209
 210   # pre-install swift here so we can build rings
 211   include ::swift
 212
 213   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 214   $enable_ceph = $cinder_enable_rbd_backend
 215
 216   if $enable_ceph {
 217     class { 'ceph::profile::params':
 218       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 219     }
 220     include ::ceph::profile::mon
 221   }
 222
 223   if str2bool(hiera('enable_ceph_storage', 'false')) {
 224     include ::ceph::profile::client
 225     include ::ceph::profile::osd
 226   }
 227
 228 } #END STEP 2
 229
 230 if hiera('step') >= 3 {
 231
 232   include ::keystone
 233
 234   #TODO: need a cleanup-keystone-tokens.sh solution here
 235   keystone_config {
 236     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 237   }
 238   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 239     ensure  => 'directory',
 240     owner   => 'keystone',
 241     group   => 'keystone',
 242     require => Package['keystone'],
 243   }
 244   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 245     content => hiera('keystone_signing_certificate'),
 246     owner   => 'keystone',
 247     group   => 'keystone',
 248     notify  => Service['keystone'],
 249     require => File['/etc/keystone/ssl/certs'],
 250   }
 251   file { '/etc/keystone/ssl/private/signing_key.pem':
 252     content => hiera('keystone_signing_key'),
 253     owner   => 'keystone',
 254     group   => 'keystone',
 255     notify  => Service['keystone'],
 256     require => File['/etc/keystone/ssl/private'],
 257   }
 258   file { '/etc/keystone/ssl/certs/ca.pem':
 259     content => hiera('keystone_ca_certificate'),
 260     owner   => 'keystone',
 261     group   => 'keystone',
 262     notify  => Service['keystone'],
 263     require => File['/etc/keystone/ssl/certs'],
 264   }
 265
 266   # TODO: notifications, scrubber, etc.
 267   include ::glance
 268   include ::glance::api
 269   include ::glance::registry
 270   include ::glance::backend::swift
 271
 272   class { 'nova':
 273     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 274   }
 275
 276   include ::nova::api
 277   include ::nova::cert
 278   include ::nova::conductor
 279   include ::nova::consoleauth
 280   include ::nova::network::neutron
 281   include ::nova::vncproxy
 282   include ::nova::scheduler
 283
 284   include ::neutron
 285   include ::neutron::server
 286   include ::neutron::agents::dhcp
 287   include ::neutron::agents::l3
 288
 289   file { '/etc/neutron/dnsmasq-neutron.conf':
 290     content => hiera('neutron_dnsmasq_options'),
 291     owner   => 'neutron',
 292     group   => 'neutron',
 293     notify  => Service['neutron-dhcp-service'],
 294     require => Package['neutron'],
 295   }
 296
 297   class { 'neutron::plugins::ml2':
 298     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 299     tenant_network_types => [hiera('neutron_tenant_network_type')],
 300     type_drivers         => [hiera('neutron_tenant_network_type')],
 301   }
 302
 303   class { 'neutron::agents::ml2::ovs':
 304     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 305     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 306   }
 307
 308   class { 'neutron::agents::metadata':
 309     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 310   }
 311
 312   Service['neutron-server'] -> Service['neutron-dhcp-service']
 313   Service['neutron-server'] -> Service['neutron-l3']
 314   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 315   Service['neutron-server'] -> Service['neutron-metadata']
 316
 317   include ::cinder
 318   include ::cinder::api
 319   include ::cinder::glance
 320   include ::cinder::scheduler
 321   include ::cinder::volume
 322   class {'cinder::setup_test_volume':
 323     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 324   }
 325
 326   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 327   if $cinder_enable_iscsi {
 328     $cinder_iscsi_backend = 'tripleo_iscsi'
 329
 330     cinder::backend::iscsi { $cinder_iscsi_backend :
 331       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 332       iscsi_helper     => hiera('cinder_iscsi_helper'),
 333     }
 334   }
 335
 336   if $enable_ceph {
 337
 338     Ceph_pool {
 339       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 340       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 341       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 342     }
 343
 344     $ceph_pools = hiera('ceph_pools')
 345     ceph::pool { $ceph_pools : }
 346   }
 347
 348   if $cinder_enable_rbd_backend {
 349     $cinder_rbd_backend = 'tripleo_ceph'
 350
 351     cinder_config {
 352       "${cinder_rbd_backend}/host": value => 'hostgroup';
 353     }
 354
 355     cinder::backend::rbd { $cinder_rbd_backend :
 356       rbd_pool        => 'volumes',
 357       rbd_user        => 'openstack',
 358       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 359       require         => Ceph::Pool['volumes'],
 360     }
 361   }
 362
 363   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 364   class { '::cinder::backends' :
 365     enabled_backends => $cinder_enabled_backends,
 366   }
 367
 368   # swift proxy
 369   include ::memcached
 370   include ::swift::proxy
 371   include ::swift::proxy::proxy_logging
 372   include ::swift::proxy::healthcheck
 373   include ::swift::proxy::cache
 374   include ::swift::proxy::keystone
 375   include ::swift::proxy::authtoken
 376   include ::swift::proxy::staticweb
 377   include ::swift::proxy::ceilometer
 378   include ::swift::proxy::ratelimit
 379   include ::swift::proxy::catch_errors
 380   include ::swift::proxy::tempurl
 381   include ::swift::proxy::formpost
 382
 383   # swift storage
 384   if str2bool(hiera('enable_swift_storage', 'true')) {
 385     class {'swift::storage::all':
 386       mount_check => str2bool(hiera('swift_mount_check'))
 387     }
 388     if(!defined(File['/srv/node'])) {
 389       file { '/srv/node':
 390         ensure  => directory,
 391         owner   => 'swift',
 392         group   => 'swift',
 393         require => Package['openstack-swift'],
 394       }
 395     }
 396     $swift_components = ['account', 'container', 'object']
 397     swift::storage::filter::recon { $swift_components : }
 398     swift::storage::filter::healthcheck { $swift_components : }
 399   }
 400
 401   # Ceilometer
 402   include ::ceilometer
 403   include ::ceilometer::api
 404   include ::ceilometer::agent::notification
 405   include ::ceilometer::agent::central
 406   include ::ceilometer::alarm::notifier
 407   include ::ceilometer::alarm::evaluator
 408   include ::ceilometer::expirer
 409   include ::ceilometer::collector
 410   class { '::ceilometer::db' :
 411     database_connection => $ceilometer_mongodb_conn_string,
 412   }
 413   class { 'ceilometer::agent::auth':
 414     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 415   }
 416
 417   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 418
 419   # Heat
 420   include ::heat
 421   include ::heat::api
 422   include ::heat::api_cfn
 423   include ::heat::api_cloudwatch
 424   include ::heat::engine
 425
 426   $snmpd_user = hiera('snmpd_readonly_user_name')
 427   snmp::snmpv3_user { $snmpd_user:
 428     authtype => 'MD5',
 429     authpass => hiera('snmpd_readonly_user_password'),
 430   }
 431   class { 'snmp':
 432     agentaddress => ['udp:161','udp6:[::1]:161'],
 433     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 434   }
 435
 436 } #END STEP 3