puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27 }
  28
  29 if hiera('step') >= 2 {
  30
  31   if count(hiera('ntp::servers')) > 0 {
  32     include ::ntp
  33   }
  34
  35   include ::timezone
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40     include ::mongodb::client
  41     include ::mongodb::server
  42     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  43     # without the brackets as 'members' argument for the 'mongodb_replset'
  44     # resource.
  45     if str2bool(hiera('mongodb::server::ipv6', false)) {
  46       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  47       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  48       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  49     } else {
  50       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  51       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  52     }
  53     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  54
  55     $mongodb_replset = hiera('mongodb::server::replset')
  56     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  57     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  58       mongodb_replset { $mongodb_replset :
  59         members => $mongo_node_ips_with_port_nobr,
  60       }
  61     }
  62   }
  63
  64   if str2bool(hiera('enable_galera', true)) {
  65     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  66   } else {
  67     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  68   }
  69   # TODO Galara
  70   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  71   # set bind-address to a hostname instead of an ip address; to move Mysql
  72   # from internal_api on another network we'll have to customize both
  73   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  74   class { '::mysql::server':
  75     config_file             => $mysql_config_file,
  76     override_options        => {
  77       'mysqld' => {
  78         'bind-address'     => $::hostname,
  79         'max_connections'  => hiera('mysql_max_connections'),
  80         'open_files_limit' => '-1',
  81       },
  82     },
  83     remove_default_accounts => true,
  84   }
  85
  86   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  87   # Create all the database schemas
  88   include ::nova::db::mysql
  89   include ::nova::db::mysql_api
  90   if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
  91     include ::gnocchi::db::mysql
  92   }
  93   if downcase(hiera('ceilometer_backend')) == 'mysql' {
  94     include ::ceilometer::db::mysql
  95     include ::aodh::db::mysql
  96   }
  97
  98   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
  99
 100   if $enable_ceph {
 101     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 102     if str2bool(hiera('ceph_ipv6', false)) {
 103       $mon_host = hiera('ceph_mon_host_v6')
 104     } else {
 105       $mon_host = hiera('ceph_mon_host')
 106     }
 107     class { '::ceph::profile::params':
 108       mon_initial_members => $mon_initial_members,
 109       mon_host            => $mon_host,
 110     }
 111     include ::ceph::conf
 112     include ::ceph::profile::mon
 113   }
 114
 115   if str2bool(hiera('enable_ceph_storage', false)) {
 116     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 117       exec { 'set selinux to permissive on boot':
 118         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 119         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 120         path    => ['/usr/bin', '/usr/sbin'],
 121       }
 122
 123       exec { 'set selinux to permissive':
 124         command => 'setenforce 0',
 125         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 126         path    => ['/usr/bin', '/usr/sbin'],
 127       } -> Class['ceph::profile::osd']
 128     }
 129
 130     include ::ceph::conf
 131     include ::ceph::profile::osd
 132   }
 133
 134   if str2bool(hiera('enable_external_ceph', false)) {
 135     if str2bool(hiera('ceph_ipv6', false)) {
 136       $mon_host = hiera('ceph_mon_host_v6')
 137     } else {
 138       $mon_host = hiera('ceph_mon_host')
 139     }
 140     class { '::ceph::profile::params':
 141       mon_host            => $mon_host,
 142     }
 143     include ::ceph::conf
 144     include ::ceph::profile::client
 145   }
 146
 147 } #END STEP 2
 148
 149 if hiera('step') >= 4 {
 150
 151   $nova_ipv6 = hiera('nova::use_ipv6', false)
 152   if $nova_ipv6 {
 153     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 154   } else {
 155     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 156   }
 157
 158   class { '::nova' :
 159     memcached_servers => $memcached_servers
 160   }
 161   include ::nova::config
 162   include ::nova::api
 163   include ::nova::cert
 164   include ::nova::consoleauth
 165   include ::nova::network::neutron
 166   include ::nova::vncproxy
 167   include ::nova::scheduler
 168   include ::nova::scheduler::filter
 169
 170   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 171
 172     # TODO(devvesa) provide non-controller ips for these services
 173     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 174     $cassandra_node_ips = hiera('neutron_api_node_ips')
 175
 176     # Run zookeeper in the controller if configured
 177     if hiera('enable_zookeeper_on_controller') {
 178       class {'::tripleo::cluster::zookeeper':
 179         zookeeper_server_ips => $zookeeper_node_ips,
 180         # TODO: create a 'bind' hiera key for zookeeper
 181         zookeeper_client_ip  => hiera('neutron::bind_host'),
 182         zookeeper_hostnames  => hiera('controller_node_names')
 183       }
 184     }
 185
 186     # Run cassandra in the controller if configured
 187     if hiera('enable_cassandra_on_controller') {
 188       class {'::tripleo::cluster::cassandra':
 189         cassandra_servers => $cassandra_node_ips,
 190         # TODO: create a 'bind' hiera key for cassandra
 191         cassandra_ip      => hiera('neutron::bind_host'),
 192       }
 193     }
 194
 195     class {'::tripleo::network::midonet::agent':
 196       zookeeper_servers => $zookeeper_node_ips,
 197       cassandra_seeds   => $cassandra_node_ips
 198     }
 199
 200     class {'::tripleo::network::midonet::api':
 201       zookeeper_servers    => $zookeeper_node_ips,
 202       vip                  => hiera('public_virtual_ip'),
 203       keystone_ip          => hiera('public_virtual_ip'),
 204       keystone_admin_token => hiera('keystone::admin_token'),
 205       # TODO: create a 'bind' hiera key for api
 206       bind_address         => hiera('neutron::bind_host'),
 207       admin_password       => hiera('admin_password')
 208     }
 209
 210     # TODO: find a way to get an empty list from hiera
 211     class {'::neutron':
 212       service_plugins => []
 213     }
 214
 215   }
 216   else {
 217
 218     # ML2 plugin
 219     include ::neutron
 220   }
 221
 222   include ::neutron::config
 223
 224   # If the value of core plugin is set to 'nuage' or'opencontrail' or 'plumgrid',
 225   # include nuage or opencontrail or plumgrid core plugins
 226   # else use the default value of 'ml2'
 227   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 228     include ::neutron::plugins::nuage
 229   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 230     include ::neutron::plugins::opencontrail
 231   }
 232   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 233     class { '::neutron::plugins::plumgrid' :
 234       connection                   => hiera('neutron::server::database_connection'),
 235       controller_priv_host         => hiera('keystone_admin_api_vip'),
 236       admin_password               => hiera('admin_password'),
 237       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 238     }
 239   } else {
 240
 241     # If the value of core plugin is set to 'midonet',
 242     # skip all the ML2 configuration
 243     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 244
 245       class {'::neutron::plugins::midonet':
 246         midonet_api_ip    => hiera('public_virtual_ip'),
 247         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 248         keystone_password => hiera('neutron::server::password')
 249       }
 250     } else {
 251
 252       include ::neutron::plugins::ml2
 253       include ::neutron::agents::ml2::ovs
 254
 255       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 256         include ::neutron::plugins::ml2::cisco::nexus1000v
 257
 258         class { '::neutron::agents::n1kv_vem':
 259           n1kv_source  => hiera('n1kv_vem_source', undef),
 260           n1kv_version => hiera('n1kv_vem_version', undef),
 261         }
 262
 263         class { '::n1k_vsm':
 264           n1kv_source       => hiera('n1kv_vsm_source', undef),
 265           n1kv_version      => hiera('n1kv_vsm_version', undef),
 266           pacemaker_control => false,
 267         }
 268       }
 269
 270       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 271         include ::neutron::plugins::ml2::cisco::ucsm
 272       }
 273       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 274         include ::neutron::plugins::ml2::cisco::nexus
 275         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 276       }
 277
 278       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 279         include ::neutron::plugins::ml2::bigswitch::restproxy
 280         include ::neutron::agents::bigswitch
 281       }
 282       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 283     }
 284
 285     Service['neutron-server'] -> Service['neutron-metadata']
 286   }
 287
 288   if $enable_ceph {
 289     $ceph_pools = hiera('ceph_pools')
 290     ceph::pool { $ceph_pools :
 291       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 292       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 293       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 294     }
 295   }
 296
 297   # swift storage
 298   if str2bool(hiera('enable_swift_storage', true)) {
 299     class { '::swift::storage::all':
 300       mount_check => str2bool(hiera('swift_mount_check')),
 301     }
 302     if(!defined(File['/srv/node'])) {
 303       file { '/srv/node':
 304         ensure  => directory,
 305         owner   => 'swift',
 306         group   => 'swift',
 307         require => Package['openstack-swift'],
 308       }
 309     }
 310     $swift_components = ['account', 'container', 'object']
 311     swift::storage::filter::recon { $swift_components : }
 312     swift::storage::filter::healthcheck { $swift_components : }
 313   }
 314
 315   # Ceilometer
 316   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 317   case $ceilometer_backend {
 318     /mysql/ : {
 319       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 320     }
 321     default : {
 322       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 323     }
 324   }
 325   include ::ceilometer
 326   include ::ceilometer::config
 327   include ::ceilometer::api
 328   include ::ceilometer::agent::notification
 329   include ::ceilometer::agent::central
 330   include ::ceilometer::expirer
 331   include ::ceilometer::collector
 332   include ::ceilometer::agent::auth
 333   include ::ceilometer::dispatcher::gnocchi
 334   class { '::ceilometer::db' :
 335     database_connection => $ceilometer_database_connection,
 336   }
 337
 338   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 339
 340   # Aodh
 341   class { '::aodh' :
 342     database_connection => $ceilometer_database_connection,
 343   }
 344   include ::aodh::db::sync
 345   # To manage the upgrade:
 346   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 347   include ::aodh::auth
 348   include ::aodh::api
 349   include ::aodh::wsgi::apache
 350   include ::aodh::evaluator
 351   include ::aodh::notifier
 352   include ::aodh::listener
 353   include ::aodh::client
 354
 355   # Horizon
 356   include ::apache::mod::remoteip
 357   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 358     $_profile_support = 'cisco'
 359   } else {
 360     $_profile_support = 'None'
 361   }
 362   $neutron_options   = {'profile_support' => $_profile_support }
 363
 364   $memcached_ipv6 = hiera('memcached_ipv6', false)
 365   if $memcached_ipv6 {
 366     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 367   } else {
 368     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 369   }
 370
 371   class { '::horizon':
 372     cache_server_ip => $horizon_memcached_servers,
 373     neutron_options => $neutron_options,
 374   }
 375
 376   # Gnocchi
 377   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 378   class { '::gnocchi':
 379     database_connection => $gnocchi_database_connection,
 380   }
 381   include ::gnocchi::api
 382   include ::gnocchi::wsgi::apache
 383   include ::gnocchi::client
 384   include ::gnocchi::db::sync
 385   include ::gnocchi::storage
 386   include ::gnocchi::metricd
 387   include ::gnocchi::statsd
 388   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 389   case $gnocchi_backend {
 390       'swift': { include ::gnocchi::storage::swift }
 391       'file': { include ::gnocchi::storage::file }
 392       'rbd': { include ::gnocchi::storage::ceph }
 393       default: { fail('Unrecognized gnocchi_backend parameter.') }
 394   }
 395
 396   $snmpd_user = hiera('snmpd_readonly_user_name')
 397   snmp::snmpv3_user { $snmpd_user:
 398     authtype => 'MD5',
 399     authpass => hiera('snmpd_readonly_user_password'),
 400   }
 401   class { '::snmp':
 402     agentaddress => ['udp:161','udp6:[::1]:161'],
 403     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 404   }
 405
 406   hiera_include('controller_classes')
 407
 408 } #END STEP 4
 409
 410 if hiera('step') >= 5 {
 411   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 412
 413   if $nova_enable_db_purge {
 414     include ::nova::cron::archive_deleted_rows
 415   }
 416 } #END STEP 5
 417
 418 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 419 package_manifest{$package_manifest_name: ensure => present}