puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27 }
  28
  29 if hiera('step') >= 2 {
  30
  31   if count(hiera('ntp::servers')) > 0 {
  32     include ::ntp
  33   }
  34
  35   include ::timezone
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  40     # without the brackets as 'members' argument for the 'mongodb_replset'
  41     # resource.
  42     if str2bool(hiera('mongodb::server::ipv6', false)) {
  43       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  44       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  45       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  46     } else {
  47       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  48       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  49     }
  50     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  51
  52     $mongodb_replset = hiera('mongodb::server::replset')
  53     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  54   }
  55
  56   if str2bool(hiera('enable_galera', true)) {
  57     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  58   } else {
  59     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  60   }
  61   # TODO Galara
  62   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  63   # set bind-address to a hostname instead of an ip address; to move Mysql
  64   # from internal_api on another network we'll have to customize both
  65   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  66   class { '::mysql::server':
  67     config_file             => $mysql_config_file,
  68     override_options        => {
  69       'mysqld' => {
  70         'bind-address'     => $::hostname,
  71         'max_connections'  => hiera('mysql_max_connections'),
  72         'open_files_limit' => '-1',
  73       },
  74     },
  75     remove_default_accounts => true,
  76   }
  77
  78   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  79   # Create all the database schemas
  80   include ::nova::db::mysql
  81   include ::nova::db::mysql_api
  82   if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
  83     include ::gnocchi::db::mysql
  84   }
  85   if downcase(hiera('ceilometer_backend')) == 'mysql' {
  86     include ::ceilometer::db::mysql
  87     include ::aodh::db::mysql
  88   }
  89
  90   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
  91
  92   if $enable_ceph {
  93     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
  94     if str2bool(hiera('ceph_ipv6', false)) {
  95       $mon_host = hiera('ceph_mon_host_v6')
  96     } else {
  97       $mon_host = hiera('ceph_mon_host')
  98     }
  99     class { '::ceph::profile::params':
 100       mon_initial_members => $mon_initial_members,
 101       mon_host            => $mon_host,
 102     }
 103     include ::ceph::conf
 104     include ::ceph::profile::mon
 105   }
 106
 107   if str2bool(hiera('enable_ceph_storage', false)) {
 108     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 109       exec { 'set selinux to permissive on boot':
 110         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 111         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 112         path    => ['/usr/bin', '/usr/sbin'],
 113       }
 114
 115       exec { 'set selinux to permissive':
 116         command => 'setenforce 0',
 117         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 118         path    => ['/usr/bin', '/usr/sbin'],
 119       } -> Class['ceph::profile::osd']
 120     }
 121
 122     include ::ceph::conf
 123     include ::ceph::profile::osd
 124   }
 125
 126   if str2bool(hiera('enable_external_ceph', false)) {
 127     if str2bool(hiera('ceph_ipv6', false)) {
 128       $mon_host = hiera('ceph_mon_host_v6')
 129     } else {
 130       $mon_host = hiera('ceph_mon_host')
 131     }
 132     class { '::ceph::profile::params':
 133       mon_host            => $mon_host,
 134     }
 135     include ::ceph::conf
 136     include ::ceph::profile::client
 137   }
 138
 139 } #END STEP 2
 140
 141 if hiera('step') >= 4 {
 142
 143   $nova_ipv6 = hiera('nova::use_ipv6', false)
 144   if $nova_ipv6 {
 145     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 146   } else {
 147     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 148   }
 149
 150   class { '::nova' :
 151     memcached_servers => $memcached_servers
 152   }
 153   include ::nova::config
 154   include ::nova::network::neutron
 155
 156   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 157
 158     # TODO(devvesa) provide non-controller ips for these services
 159     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 160     $cassandra_node_ips = hiera('neutron_api_node_ips')
 161
 162     # Run zookeeper in the controller if configured
 163     if hiera('enable_zookeeper_on_controller') {
 164       class {'::tripleo::cluster::zookeeper':
 165         zookeeper_server_ips => $zookeeper_node_ips,
 166         # TODO: create a 'bind' hiera key for zookeeper
 167         zookeeper_client_ip  => hiera('neutron::bind_host'),
 168         zookeeper_hostnames  => hiera('controller_node_names')
 169       }
 170     }
 171
 172     # Run cassandra in the controller if configured
 173     if hiera('enable_cassandra_on_controller') {
 174       class {'::tripleo::cluster::cassandra':
 175         cassandra_servers => $cassandra_node_ips,
 176         # TODO: create a 'bind' hiera key for cassandra
 177         cassandra_ip      => hiera('neutron::bind_host'),
 178       }
 179     }
 180
 181     class {'::tripleo::network::midonet::agent':
 182       zookeeper_servers => $zookeeper_node_ips,
 183       cassandra_seeds   => $cassandra_node_ips
 184     }
 185
 186     class {'::tripleo::network::midonet::api':
 187       zookeeper_servers    => $zookeeper_node_ips,
 188       vip                  => hiera('public_virtual_ip'),
 189       keystone_ip          => hiera('public_virtual_ip'),
 190       keystone_admin_token => hiera('keystone::admin_token'),
 191       # TODO: create a 'bind' hiera key for api
 192       bind_address         => hiera('neutron::bind_host'),
 193       admin_password       => hiera('admin_password')
 194     }
 195
 196     # TODO: find a way to get an empty list from hiera
 197     # TODO: when doing the composable midonet plugin, don't forget to
 198     # set service_plugins to an empty array in Hiera.
 199     class {'::neutron':
 200       service_plugins => []
 201     }
 202
 203   }
 204
 205   # If the value of core plugin is set to 'nuage' or'opencontrail'
 206   # include nuage or opencontrail core plugins
 207   # else use the default value of 'ml2'
 208   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 209     include ::neutron::plugins::nuage
 210   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 211     include ::neutron::plugins::opencontrail
 212   } else {
 213
 214     # If the value of core plugin is set to 'midonet',
 215     # skip all the ML2 configuration
 216     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 217
 218       class {'::neutron::plugins::midonet':
 219         midonet_api_ip    => hiera('public_virtual_ip'),
 220         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 221         keystone_password => hiera('neutron::server::password')
 222       }
 223     }
 224
 225     Service['neutron-server'] -> Service['neutron-metadata']
 226
 227   }
 228
 229   if $enable_ceph {
 230     $ceph_pools = hiera('ceph_pools')
 231     ceph::pool { $ceph_pools :
 232       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 233       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 234       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 235     }
 236   }
 237
 238   # swift storage
 239   if str2bool(hiera('enable_swift_storage', true)) {
 240     class { '::swift::storage::all':
 241       mount_check => str2bool(hiera('swift_mount_check')),
 242     }
 243     if(!defined(File['/srv/node'])) {
 244       file { '/srv/node':
 245         ensure  => directory,
 246         owner   => 'swift',
 247         group   => 'swift',
 248         require => Package['openstack-swift'],
 249       }
 250     }
 251     $swift_components = ['account', 'container', 'object']
 252     swift::storage::filter::recon { $swift_components : }
 253     swift::storage::filter::healthcheck { $swift_components : }
 254   }
 255
 256   # Ceilometer
 257   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 258   case $ceilometer_backend {
 259     /mysql/ : {
 260       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 261     }
 262     default : {
 263       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 264     }
 265   }
 266   include ::ceilometer
 267   include ::ceilometer::config
 268   include ::ceilometer::api
 269   include ::ceilometer::agent::notification
 270   include ::ceilometer::agent::central
 271   include ::ceilometer::expirer
 272   include ::ceilometer::collector
 273   include ::ceilometer::agent::auth
 274   include ::ceilometer::dispatcher::gnocchi
 275   class { '::ceilometer::db' :
 276     database_connection => $ceilometer_database_connection,
 277   }
 278
 279   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 280
 281   # Aodh
 282   class { '::aodh' :
 283     database_connection => $ceilometer_database_connection,
 284   }
 285   include ::aodh::db::sync
 286   # To manage the upgrade:
 287   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 288   include ::aodh::auth
 289   include ::aodh::api
 290   include ::aodh::wsgi::apache
 291   include ::aodh::evaluator
 292   include ::aodh::notifier
 293   include ::aodh::listener
 294   include ::aodh::client
 295
 296   # Horizon
 297   include ::apache::mod::remoteip
 298   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 299     $_profile_support = 'cisco'
 300   } else {
 301     $_profile_support = 'None'
 302   }
 303   $neutron_options   = {'profile_support' => $_profile_support }
 304
 305   $memcached_ipv6 = hiera('memcached_ipv6', false)
 306   if $memcached_ipv6 {
 307     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 308   } else {
 309     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 310   }
 311
 312   class { '::horizon':
 313     cache_server_ip => $horizon_memcached_servers,
 314     neutron_options => $neutron_options,
 315   }
 316
 317   # Gnocchi
 318   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 319   class { '::gnocchi':
 320     database_connection => $gnocchi_database_connection,
 321   }
 322   include ::gnocchi::api
 323   include ::gnocchi::wsgi::apache
 324   include ::gnocchi::client
 325   include ::gnocchi::db::sync
 326   include ::gnocchi::storage
 327   include ::gnocchi::metricd
 328   include ::gnocchi::statsd
 329   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 330   case $gnocchi_backend {
 331       'swift': { include ::gnocchi::storage::swift }
 332       'file': { include ::gnocchi::storage::file }
 333       'rbd': { include ::gnocchi::storage::ceph }
 334       default: { fail('Unrecognized gnocchi_backend parameter.') }
 335   }
 336
 337   $snmpd_user = hiera('snmpd_readonly_user_name')
 338   snmp::snmpv3_user { $snmpd_user:
 339     authtype => 'MD5',
 340     authpass => hiera('snmpd_readonly_user_password'),
 341   }
 342   class { '::snmp':
 343     agentaddress => ['udp:161','udp6:[::1]:161'],
 344     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 345   }
 346
 347   hiera_include('controller_classes')
 348
 349 } #END STEP 4
 350
 351 if hiera('step') >= 5 {
 352   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 353
 354   if $nova_enable_db_purge {
 355     include ::nova::cron::archive_deleted_rows
 356   }
 357 } #END STEP 5
 358
 359 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 360 package_manifest{$package_manifest_name: ensure => present}