puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49     include ::mongodb::client
  50     include ::mongodb::server
  51     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  52     # without the brackets as 'members' argument for the 'mongodb_replset'
  53     # resource.
  54     if str2bool(hiera('mongodb::server::ipv6', false)) {
  55       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  56       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  57       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  58     } else {
  59       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  60       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  61     }
  62     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  63
  64     $mongodb_replset = hiera('mongodb::server::replset')
  65     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  66     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  67       mongodb_replset { $mongodb_replset :
  68         members => $mongo_node_ips_with_port_nobr,
  69       }
  70     }
  71   }
  72
  73   # Redis
  74   $redis_node_ips = hiera('redis_node_ips')
  75   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  76
  77   if $redis_master_hostname == $::hostname {
  78     $slaveof = undef
  79   } else {
  80     $slaveof = "${redis_master_hostname} 6379"
  81   }
  82   class {'::redis' :
  83     slaveof => $slaveof,
  84   }
  85
  86   if count($redis_node_ips) > 1 {
  87     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  88     include ::redis::sentinel
  89     include ::tripleo::redis_notification
  90   }
  91
  92   if str2bool(hiera('enable_galera', true)) {
  93     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  94   } else {
  95     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  96   }
  97   # TODO Galara
  98   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  99   # set bind-address to a hostname instead of an ip address; to move Mysql
 100   # from internal_api on another network we'll have to customize both
 101   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 102   class { '::mysql::server':
 103     config_file             => $mysql_config_file,
 104     override_options        => {
 105       'mysqld' => {
 106         'bind-address'     => $::hostname,
 107         'max_connections'  => hiera('mysql_max_connections'),
 108         'open_files_limit' => '-1',
 109       },
 110     },
 111     remove_default_accounts => true,
 112   }
 113
 114   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 115   # Create all the database schemas
 116   include ::keystone::db::mysql
 117   include ::glance::db::mysql
 118   include ::nova::db::mysql
 119   include ::nova::db::mysql_api
 120   include ::neutron::db::mysql
 121   include ::cinder::db::mysql
 122   include ::heat::db::mysql
 123   include ::sahara::db::mysql
 124   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 125     include ::ceilometer::db::mysql
 126     include ::aodh::db::mysql
 127   }
 128
 129   $rabbit_nodes = hiera('rabbit_node_ips')
 130   if count($rabbit_nodes) > 1 {
 131
 132     $rabbit_ipv6 = str2bool(hiera('rabbit_ipv6', false))
 133     if $rabbit_ipv6 {
 134       $rabbit_env = merge(hiera('rabbitmq_environment'), {
 135         'RABBITMQ_SERVER_START_ARGS' => '"-proto_dist inet6_tcp"'
 136       })
 137     } else {
 138       $rabbit_env = hiera('rabbitmq_environment')
 139     }
 140
 141     class { '::rabbitmq':
 142       config_cluster          => true,
 143       cluster_nodes           => $rabbit_nodes,
 144       tcp_keepalive           => false,
 145       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 146       config_variables        => hiera('rabbitmq_config_variables'),
 147       environment_variables   => $rabbit_env,
 148     }
 149     rabbitmq_policy { 'ha-all@/':
 150       pattern    => '^(?!amq\.).*',
 151       definition => {
 152         'ha-mode' => 'all',
 153       },
 154     }
 155   } else {
 156     include ::rabbitmq
 157   }
 158
 159   # pre-install swift here so we can build rings
 160   include ::swift
 161
 162   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 163
 164   if $enable_ceph {
 165     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 166     if str2bool(hiera('ceph_ipv6', false)) {
 167       $mon_host = hiera('ceph_mon_host_v6')
 168     } else {
 169       $mon_host = hiera('ceph_mon_host')
 170     }
 171     class { '::ceph::profile::params':
 172       mon_initial_members => $mon_initial_members,
 173       mon_host            => $mon_host,
 174     }
 175     include ::ceph::conf
 176     include ::ceph::profile::mon
 177   }
 178
 179   if str2bool(hiera('enable_ceph_storage', false)) {
 180     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 181       exec { 'set selinux to permissive on boot':
 182         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 183         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 184         path    => ['/usr/bin', '/usr/sbin'],
 185       }
 186
 187       exec { 'set selinux to permissive':
 188         command => 'setenforce 0',
 189         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 190         path    => ['/usr/bin', '/usr/sbin'],
 191       } -> Class['ceph::profile::osd']
 192     }
 193
 194     include ::ceph::conf
 195     include ::ceph::profile::osd
 196   }
 197
 198   if str2bool(hiera('enable_external_ceph', false)) {
 199     if str2bool(hiera('ceph_ipv6', false)) {
 200       $mon_host = hiera('ceph_mon_host_v6')
 201     } else {
 202       $mon_host = hiera('ceph_mon_host')
 203     }
 204     class { '::ceph::profile::params':
 205       mon_host            => $mon_host,
 206     }
 207     include ::ceph::conf
 208     include ::ceph::profile::client
 209   }
 210
 211 } #END STEP 2
 212
 213 if hiera('step') >= 4 {
 214
 215   include ::keystone
 216   include ::keystone::config
 217   include ::keystone::roles::admin
 218   include ::keystone::endpoint
 219   include ::keystone::wsgi::apache
 220
 221   #TODO: need a cleanup-keystone-tokens.sh solution here
 222
 223   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 224     ensure  => 'directory',
 225     owner   => 'keystone',
 226     group   => 'keystone',
 227     require => Package['keystone'],
 228   }
 229   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 230     content => hiera('keystone_signing_certificate'),
 231     owner   => 'keystone',
 232     group   => 'keystone',
 233     notify  => Service['keystone'],
 234     require => File['/etc/keystone/ssl/certs'],
 235   }
 236   file { '/etc/keystone/ssl/private/signing_key.pem':
 237     content => hiera('keystone_signing_key'),
 238     owner   => 'keystone',
 239     group   => 'keystone',
 240     notify  => Service['keystone'],
 241     require => File['/etc/keystone/ssl/private'],
 242   }
 243   file { '/etc/keystone/ssl/certs/ca.pem':
 244     content => hiera('keystone_ca_certificate'),
 245     owner   => 'keystone',
 246     group   => 'keystone',
 247     notify  => Service['keystone'],
 248     require => File['/etc/keystone/ssl/certs'],
 249   }
 250
 251   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 252   case $glance_backend {
 253       'swift': { $backend_store = 'glance.store.swift.Store' }
 254       'file': { $backend_store = 'glance.store.filesystem.Store' }
 255       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 256       default: { fail('Unrecognized glance_backend parameter.') }
 257   }
 258   $http_store = ['glance.store.http.Store']
 259   $glance_store = concat($http_store, $backend_store)
 260
 261   # TODO: scrubber and other additional optional features
 262   include ::glance
 263   include ::glance::config
 264   class { '::glance::api':
 265     known_stores => $glance_store,
 266   }
 267   include ::glance::registry
 268   include ::glance::notify::rabbitmq
 269   include join(['::glance::backend::', $glance_backend])
 270
 271   $nova_ipv6 = hiera('nova::use_ipv6', false)
 272   if $nova_ipv6 {
 273     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 274   } else {
 275     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 276   }
 277
 278   class { '::nova' :
 279     memcached_servers => $memcached_servers
 280   }
 281   include ::nova::config
 282   include ::nova::api
 283   include ::nova::cert
 284   include ::nova::conductor
 285   include ::nova::consoleauth
 286   include ::nova::network::neutron
 287   include ::nova::vncproxy
 288   include ::nova::scheduler
 289   include ::nova::scheduler::filter
 290
 291   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 292
 293     # TODO(devvesa) provide non-controller ips for these services
 294     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 295     $cassandra_node_ips = hiera('neutron_api_node_ips')
 296
 297     # Run zookeeper in the controller if configured
 298     if hiera('enable_zookeeper_on_controller') {
 299       class {'::tripleo::cluster::zookeeper':
 300         zookeeper_server_ips => $zookeeper_node_ips,
 301         # TODO: create a 'bind' hiera key for zookeeper
 302         zookeeper_client_ip  => hiera('neutron::bind_host'),
 303         zookeeper_hostnames  => hiera('controller_node_names')
 304       }
 305     }
 306
 307     # Run cassandra in the controller if configured
 308     if hiera('enable_cassandra_on_controller') {
 309       class {'::tripleo::cluster::cassandra':
 310         cassandra_servers => $cassandra_node_ips,
 311         # TODO: create a 'bind' hiera key for cassandra
 312         cassandra_ip      => hiera('neutron::bind_host'),
 313       }
 314     }
 315
 316     class {'::tripleo::network::midonet::agent':
 317       zookeeper_servers => $zookeeper_node_ips,
 318       cassandra_seeds   => $cassandra_node_ips
 319     }
 320
 321     class {'::tripleo::network::midonet::api':
 322       zookeeper_servers    => $zookeeper_node_ips,
 323       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 324       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 325       keystone_admin_token => hiera('keystone::admin_token'),
 326       # TODO: create a 'bind' hiera key for api
 327       bind_address         => hiera('neutron::bind_host'),
 328       admin_password       => hiera('admin_password')
 329     }
 330
 331     # TODO: find a way to get an empty list from hiera
 332     class {'::neutron':
 333       service_plugins => []
 334     }
 335
 336   }
 337   else {
 338
 339     # ML2 plugin
 340     include ::neutron
 341   }
 342
 343   include ::neutron::config
 344   include ::neutron::server
 345   include ::neutron::server::notifications
 346
 347   # If the value of core plugin is set to 'nuage' or 'opencontrail',
 348   # include nuage or opencontrail core plugins, and it does not
 349   # need the l3, dhcp and metadata agents
 350   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 351     include ::neutron::plugins::nuage
 352   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 353     include ::neutron::plugins::opencontrail
 354   } else {
 355     include ::neutron::agents::l3
 356     include ::neutron::agents::dhcp
 357     include ::neutron::agents::metadata
 358
 359     file { '/etc/neutron/dnsmasq-neutron.conf':
 360       content => hiera('neutron_dnsmasq_options'),
 361       owner   => 'neutron',
 362       group   => 'neutron',
 363       notify  => Service['neutron-dhcp-service'],
 364       require => Package['neutron'],
 365     }
 366
 367     # If the value of core plugin is set to 'midonet',
 368     # skip all the ML2 configuration
 369     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 370
 371       class {'::neutron::plugins::midonet':
 372         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 373         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 374         keystone_password => hiera('neutron::server::auth_password')
 375       }
 376     } else {
 377
 378       include ::neutron::plugins::ml2
 379       include ::neutron::agents::ml2::ovs
 380
 381       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 382         include ::neutron::plugins::ml2::cisco::nexus1000v
 383
 384         class { '::neutron::agents::n1kv_vem':
 385           n1kv_source  => hiera('n1kv_vem_source', undef),
 386           n1kv_version => hiera('n1kv_vem_version', undef),
 387         }
 388
 389         class { '::n1k_vsm':
 390           n1kv_source       => hiera('n1kv_vsm_source', undef),
 391           n1kv_version      => hiera('n1kv_vsm_version', undef),
 392           pacemaker_control => false,
 393         }
 394       }
 395
 396       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 397         include ::neutron::plugins::ml2::cisco::ucsm
 398       }
 399       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 400         include ::neutron::plugins::ml2::cisco::nexus
 401         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 402       }
 403
 404       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 405         include ::neutron::plugins::ml2::bigswitch::restproxy
 406         include ::neutron::agents::bigswitch
 407       }
 408       neutron_l3_agent_config {
 409         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 410       }
 411       neutron_dhcp_agent_config {
 412         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 413       }
 414       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 415     }
 416
 417     Service['neutron-server'] -> Service['neutron-dhcp-service']
 418     Service['neutron-server'] -> Service['neutron-l3']
 419     Service['neutron-server'] -> Service['neutron-metadata']
 420   }
 421
 422   include ::cinder
 423   include ::cinder::config
 424   include ::tripleo::ssl::cinder_config
 425   include ::cinder::api
 426   include ::cinder::glance
 427   include ::cinder::scheduler
 428   include ::cinder::volume
 429   include ::cinder::ceilometer
 430   class { '::cinder::setup_test_volume':
 431     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 432   }
 433
 434   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 435   if $cinder_enable_iscsi {
 436     $cinder_iscsi_backend = 'tripleo_iscsi'
 437
 438     cinder::backend::iscsi { $cinder_iscsi_backend :
 439       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 440       iscsi_helper     => hiera('cinder_iscsi_helper'),
 441     }
 442   }
 443
 444   if $enable_ceph {
 445
 446     $ceph_pools = hiera('ceph_pools')
 447     ceph::pool { $ceph_pools :
 448       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 449       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 450       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 451     }
 452
 453     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 454
 455   } else {
 456     $cinder_pool_requires = []
 457   }
 458
 459   if hiera('cinder_enable_rbd_backend', false) {
 460     $cinder_rbd_backend = 'tripleo_ceph'
 461
 462     cinder::backend::rbd { $cinder_rbd_backend :
 463       rbd_pool        => hiera('cinder_rbd_pool_name'),
 464       rbd_user        => hiera('ceph_client_user_name'),
 465       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 466       require         => $cinder_pool_requires,
 467     }
 468   }
 469
 470   if hiera('cinder_enable_eqlx_backend', false) {
 471     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 472
 473     cinder::backend::eqlx { $cinder_eqlx_backend :
 474       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 475       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 476       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 477       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 478       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 479       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 480       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 481       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 482       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 483       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 484     }
 485   }
 486
 487   if hiera('cinder_enable_dellsc_backend', false) {
 488     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 489
 490     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 491       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 492       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 493       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 494       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 495       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 496       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 497       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 498       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 499       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 500       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 501     }
 502   }
 503
 504   if hiera('cinder_enable_netapp_backend', false) {
 505     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 506
 507     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 508       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 509     }
 510
 511     cinder::backend::netapp { $cinder_netapp_backend :
 512       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 513       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 514       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 515       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 516       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 517       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 518       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 519       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 520       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 521       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 522       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 523       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 524       nfs_shares                   => $cinder_netapp_nfs_shares,
 525       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 526       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 527       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 528       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 529       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 530       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 531       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 532     }
 533   }
 534
 535   if hiera('cinder_enable_nfs_backend', false) {
 536     $cinder_nfs_backend = 'tripleo_nfs'
 537
 538     if str2bool($::selinux) {
 539       selboolean { 'virt_use_nfs':
 540         value      => on,
 541         persistent => true,
 542       } -> Package['nfs-utils']
 543     }
 544
 545     package {'nfs-utils': } ->
 546     cinder::backend::nfs { $cinder_nfs_backend :
 547       nfs_servers       => hiera('cinder_nfs_servers'),
 548       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 549       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 550     }
 551   }
 552
 553   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 554   class { '::cinder::backends' :
 555     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 556   }
 557
 558   # swift proxy
 559   include ::memcached
 560   include ::swift::proxy
 561   include ::swift::proxy::proxy_logging
 562   include ::swift::proxy::healthcheck
 563   include ::swift::proxy::cache
 564   include ::swift::proxy::keystone
 565   include ::swift::proxy::authtoken
 566   include ::swift::proxy::staticweb
 567   include ::swift::proxy::ratelimit
 568   include ::swift::proxy::catch_errors
 569   include ::swift::proxy::tempurl
 570   include ::swift::proxy::formpost
 571
 572   # swift storage
 573   if str2bool(hiera('enable_swift_storage', true)) {
 574     class { '::swift::storage::all':
 575       mount_check => str2bool(hiera('swift_mount_check')),
 576     }
 577     if(!defined(File['/srv/node'])) {
 578       file { '/srv/node':
 579         ensure  => directory,
 580         owner   => 'swift',
 581         group   => 'swift',
 582         require => Package['openstack-swift'],
 583       }
 584     }
 585     $swift_components = ['account', 'container', 'object']
 586     swift::storage::filter::recon { $swift_components : }
 587     swift::storage::filter::healthcheck { $swift_components : }
 588   }
 589
 590   # Ceilometer
 591   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 592   case $ceilometer_backend {
 593     /mysql/ : {
 594       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 595     }
 596     default : {
 597       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 598     }
 599   }
 600   include ::ceilometer
 601   include ::ceilometer::config
 602   include ::ceilometer::api
 603   include ::ceilometer::agent::notification
 604   include ::ceilometer::agent::central
 605   include ::ceilometer::expirer
 606   include ::ceilometer::collector
 607   include ::ceilometer::agent::auth
 608   class { '::ceilometer::db' :
 609     database_connection => $ceilometer_database_connection,
 610   }
 611
 612   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 613
 614   # Aodh
 615   class { '::aodh' :
 616     database_connection => $ceilometer_database_connection,
 617   }
 618   include ::aodh::db::sync
 619   # To manage the upgrade:
 620   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 621   include ::aodh::auth
 622   include ::aodh::api
 623   include ::aodh::wsgi::apache
 624   include ::aodh::evaluator
 625   include ::aodh::notifier
 626   include ::aodh::listener
 627   include ::aodh::client
 628
 629   # Heat
 630   class { '::heat' :
 631     notification_driver => 'messaging',
 632   }
 633   include ::heat::config
 634   include ::heat::api
 635   include ::heat::api_cfn
 636   include ::heat::api_cloudwatch
 637   include ::heat::engine
 638
 639   # Sahara
 640   include ::sahara
 641   include ::sahara::service::api
 642   include ::sahara::service::engine
 643
 644   # Horizon
 645   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 646     $_profile_support = 'cisco'
 647   } else {
 648     $_profile_support = 'None'
 649   }
 650   $neutron_options   = {'profile_support' => $_profile_support }
 651
 652   $memcached_ipv6 = hiera('memcached_ipv6', false)
 653   if $memcached_ipv6 {
 654     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 655   } else {
 656     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 657   }
 658
 659   class { '::horizon':
 660     cache_server_ip => $horizon_memcached_servers,
 661     neutron_options => $neutron_options,
 662   }
 663
 664   $snmpd_user = hiera('snmpd_readonly_user_name')
 665   snmp::snmpv3_user { $snmpd_user:
 666     authtype => 'MD5',
 667     authpass => hiera('snmpd_readonly_user_password'),
 668   }
 669   class { '::snmp':
 670     agentaddress => ['udp:161','udp6:[::1]:161'],
 671     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 672   }
 673
 674   hiera_include('controller_classes')
 675
 676 } #END STEP 4
 677
 678 if hiera('step') >= 5 {
 679   $keystone_enable_db_purge = hiera('keystone_enable_db_purge', true)
 680   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 681   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 682   $heat_enable_db_purge = hiera('heat_enable_db_purge', true)
 683
 684   if $keystone_enable_db_purge {
 685     include ::keystone::cron::token_flush
 686   }
 687   if $nova_enable_db_purge {
 688     include ::nova::cron::archive_deleted_rows
 689   }
 690   if $cinder_enable_db_purge {
 691     include ::cinder::cron::db_purge
 692   }
 693   if $heat_enable_db_purge {
 694     include ::heat::cron::purge_deleted
 695   }
 696
 697   if downcase(hiera('bootstrap_nodeid')) == $::hostname {
 698     include ::keystone::roles::admin
 699     # Class ::heat::keystone::domain has to run on bootstrap node
 700     # because it creates DB entities via API calls.
 701     include ::heat::keystone::domain
 702
 703     Class['::keystone::roles::admin'] -> Class['::heat::keystone::domain']
 704   } else {
 705     # On non-bootstrap node we don't need to create Keystone resources again
 706     class { '::heat::keystone::domain':
 707       manage_domain => false,
 708       manage_user   => false,
 709       manage_role   => false,
 710     }
 711   }
 712
 713 } #END STEP 5
 714
 715 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 716 package_manifest{$package_manifest_name: ensure => present}