puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17
  18 if hiera('step') >= 1 {
  19
  20   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  21
  22   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  23
  24   class { '::tripleo::loadbalancer' :
  25     controller_hosts => $controller_node_ips,
  26     manage_vip       => true,
  27   }
  28
  29 }
  30
  31 if hiera('step') >= 2 {
  32
  33   if count(hiera('ntp::servers')) > 0 {
  34     include ::ntp
  35   }
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40
  41     include ::mongodb::server
  42     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  43     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  44
  45     $mongodb_replset = hiera('mongodb::server::replset')
  46     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  47     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  48       mongodb_replset { $mongodb_replset :
  49         members => $mongo_node_ips_with_port,
  50       }
  51     }
  52   }
  53
  54   # Redis
  55   $redis_node_ips = hiera('redis_node_ips')
  56   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  57
  58   if $redis_master_hostname == $::hostname {
  59     $slaveof = undef
  60   } else {
  61     $slaveof = "${redis_master_hostname} 6379"
  62   }
  63   class {'::redis' :
  64     slaveof => $slaveof,
  65   }
  66
  67   if count($redis_node_ips) > 1 {
  68     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  69     include ::redis::sentinel
  70     include ::tripleo::redis_notification
  71   }
  72
  73   if str2bool(hiera('enable_galera', true)) {
  74     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  75   } else {
  76     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  77   }
  78   # TODO Galara
  79   class { '::mysql::server':
  80     config_file             => $mysql_config_file,
  81     override_options        => {
  82       'mysqld' => {
  83         'bind-address'     => hiera('mysql_bind_host'),
  84         'max_connections'  => hiera('mysql_max_connections'),
  85         'open_files_limit' => '-1',
  86       },
  87     },
  88     remove_default_accounts => true,
  89   }
  90
  91   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  92   # Create all the database schemas
  93   include ::keystone::db::mysql
  94   include ::glance::db::mysql
  95   include ::nova::db::mysql
  96   include ::neutron::db::mysql
  97   include ::cinder::db::mysql
  98   include ::heat::db::mysql
  99   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 100     include ::ceilometer::db::mysql
 101   }
 102
 103   $rabbit_nodes = hiera('rabbit_node_ips')
 104   if count($rabbit_nodes) > 1 {
 105     class { '::rabbitmq':
 106       config_cluster          => true,
 107       cluster_nodes           => $rabbit_nodes,
 108       tcp_keepalive           => false,
 109       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 110       config_variables        => hiera('rabbitmq_config_variables'),
 111       environment_variables   => hiera('rabbitmq_environment'),
 112     }
 113     rabbitmq_policy { 'ha-all@/':
 114       pattern    => '^(?!amq\.).*',
 115       definition => {
 116         'ha-mode' => 'all',
 117       },
 118     }
 119   } else {
 120     include ::rabbitmq
 121   }
 122
 123   # pre-install swift here so we can build rings
 124   include ::swift
 125
 126   $enable_ceph = hiera('ceph_storage_count', 0) > 0
 127
 128   if $enable_ceph {
 129     class { '::ceph::profile::params':
 130       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 131     }
 132     include ::ceph::profile::mon
 133   }
 134
 135   if str2bool(hiera('enable_ceph_storage', false)) {
 136     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 137       exec { 'set selinux to permissive on boot':
 138         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 139         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 140         path    => ['/usr/bin', '/usr/sbin'],
 141       }
 142
 143       exec { 'set selinux to permissive':
 144         command => 'setenforce 0',
 145         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 146         path    => ['/usr/bin', '/usr/sbin'],
 147       } -> Class['ceph::profile::osd']
 148     }
 149
 150     include ::ceph::profile::osd
 151   }
 152
 153   if str2bool(hiera('enable_external_ceph', false)) {
 154     include ::ceph::profile::client
 155   }
 156
 157 } #END STEP 2
 158
 159 if hiera('step') >= 3 {
 160
 161   include ::keystone
 162   include ::keystone::roles::admin
 163   include ::keystone::endpoint
 164
 165   #TODO: need a cleanup-keystone-tokens.sh solution here
 166   keystone_config {
 167     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 168   }
 169   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 170     ensure  => 'directory',
 171     owner   => 'keystone',
 172     group   => 'keystone',
 173     require => Package['keystone'],
 174   }
 175   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 176     content => hiera('keystone_signing_certificate'),
 177     owner   => 'keystone',
 178     group   => 'keystone',
 179     notify  => Service['keystone'],
 180     require => File['/etc/keystone/ssl/certs'],
 181   }
 182   file { '/etc/keystone/ssl/private/signing_key.pem':
 183     content => hiera('keystone_signing_key'),
 184     owner   => 'keystone',
 185     group   => 'keystone',
 186     notify  => Service['keystone'],
 187     require => File['/etc/keystone/ssl/private'],
 188   }
 189   file { '/etc/keystone/ssl/certs/ca.pem':
 190     content => hiera('keystone_ca_certificate'),
 191     owner   => 'keystone',
 192     group   => 'keystone',
 193     notify  => Service['keystone'],
 194     require => File['/etc/keystone/ssl/certs'],
 195   }
 196
 197   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 198   case $glance_backend {
 199       'swift': { $backend_store = 'glance.store.swift.Store' }
 200       'file': { $backend_store = 'glance.store.filesystem.Store' }
 201       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 202       default: { fail('Unrecognized glance_backend parameter.') }
 203   }
 204   $http_store = ['glance.store.http.Store']
 205   $glance_store = concat($http_store, $backend_store)
 206
 207   # TODO: notifications, scrubber, etc.
 208   include ::glance
 209   class { '::glance::api':
 210     known_stores => $glance_store,
 211   }
 212   include ::glance::registry
 213   include join(['::glance::backend::', $glance_backend])
 214
 215   class { '::nova' :
 216     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 217   }
 218   include ::nova::config
 219   include ::nova::api
 220   include ::nova::cert
 221   include ::nova::conductor
 222   include ::nova::consoleauth
 223   include ::nova::network::neutron
 224   include ::nova::vncproxy
 225   include ::nova::scheduler
 226   include ::nova::scheduler::filter
 227
 228   include ::neutron
 229   include ::neutron::server
 230   include ::neutron::server::notifications
 231   include ::neutron::agents::l3
 232   include ::neutron::agents::dhcp
 233   include ::neutron::agents::metadata
 234
 235   file { '/etc/neutron/dnsmasq-neutron.conf':
 236     content => hiera('neutron_dnsmasq_options'),
 237     owner   => 'neutron',
 238     group   => 'neutron',
 239     notify  => Service['neutron-dhcp-service'],
 240     require => Package['neutron'],
 241   }
 242
 243   class { '::neutron::plugins::ml2':
 244     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 245     tenant_network_types => [hiera('neutron_tenant_network_type')],
 246     mechanism_drivers    => [hiera('neutron_mechanism_drivers')],
 247   }
 248   class { '::neutron::agents::ml2::ovs':
 249     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 250     tunnel_types    => split(hiera('neutron_tunnel_types'), ','),
 251   }
 252   if 'cisco_n1kv' in hiera('neutron_mechanism_drivers') {
 253     include ::neutron::plugins::ml2::cisco::nexus1000v
 254
 255     class { '::neutron::agents::n1kv_vem':
 256       n1kv_source  => hiera('n1kv_vem_source', undef),
 257       n1kv_version => hiera('n1kv_vem_version', undef),
 258     }
 259
 260     class { '::n1k_vsm':
 261       n1kv_source       => hiera('n1kv_vsm_source', undef),
 262       n1kv_version      => hiera('n1kv_vsm_version', undef),
 263       pacemaker_control => false,
 264     }
 265   }
 266
 267   if 'cisco_ucsm' in hiera('neutron_mechanism_drivers') {
 268     include ::neutron::plugins::ml2::cisco::ucsm
 269   }
 270   if 'cisco_nexus' in hiera('neutron_mechanism_drivers') {
 271     include ::neutron::plugins::ml2::cisco::nexus
 272     include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 273   }
 274
 275   if hiera('neutron_enable_bigswitch_ml2', false) {
 276     include ::neutron::plugins::ml2::bigswitch::restproxy
 277   }
 278   neutron_l3_agent_config {
 279     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 280   }
 281   neutron_dhcp_agent_config {
 282     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 283   }
 284
 285   Service['neutron-server'] -> Service['neutron-dhcp-service']
 286   Service['neutron-server'] -> Service['neutron-l3']
 287   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 288   Service['neutron-server'] -> Service['neutron-metadata']
 289
 290   include ::cinder
 291   include ::cinder::api
 292   include ::cinder::glance
 293   include ::cinder::scheduler
 294   include ::cinder::volume
 295   class { '::cinder::setup_test_volume':
 296     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 297   }
 298
 299   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 300   if $cinder_enable_iscsi {
 301     $cinder_iscsi_backend = 'tripleo_iscsi'
 302
 303     cinder::backend::iscsi { $cinder_iscsi_backend :
 304       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 305       iscsi_helper     => hiera('cinder_iscsi_helper'),
 306     }
 307   }
 308
 309   if $enable_ceph {
 310
 311     Ceph_pool {
 312       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 313       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 314       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 315     }
 316
 317     $ceph_pools = hiera('ceph_pools')
 318     ceph::pool { $ceph_pools : }
 319
 320     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 321
 322   } else {
 323     $cinder_pool_requires = []
 324   }
 325
 326   if hiera('cinder_enable_rbd_backend', false) {
 327     $cinder_rbd_backend = 'tripleo_ceph'
 328
 329     cinder::backend::rbd { $cinder_rbd_backend :
 330       rbd_pool        => hiera('cinder_rbd_pool_name'),
 331       rbd_user        => hiera('ceph_client_user_name'),
 332       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 333       require         => $cinder_pool_requires,
 334     }
 335   }
 336
 337   if hiera('cinder_enable_netapp_backend', false) {
 338     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 339
 340     cinder_config {
 341       "${cinder_netapp_backend}/host": value => 'hostgroup';
 342     }
 343
 344     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 345       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 346     }
 347
 348     cinder::backend::netapp { $cinder_netapp_backend :
 349       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 350       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 351       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 352       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 353       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 354       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 355       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 356       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 357       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 358       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 359       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 360       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 361       nfs_shares                   => $cinder_netapp_nfs_shares,
 362       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 363       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 364       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 365       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 366       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 367       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 368       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 369     }
 370   }
 371
 372   if hiera('cinder_enable_nfs_backend', false) {
 373     $cinder_nfs_backend = 'tripleo_nfs'
 374
 375     if str2bool($::selinux) {
 376       selboolean { 'virt_use_nfs':
 377         value      => on,
 378         persistent => true,
 379       } -> Package['nfs-utils']
 380     }
 381
 382     package {'nfs-utils': } ->
 383     cinder::backend::nfs { $cinder_nfs_backend :
 384       nfs_servers       => hiera('cinder_nfs_servers'),
 385       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 386       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 387     }
 388   }
 389
 390   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 391   class { '::cinder::backends' :
 392     enabled_backends => $cinder_enabled_backends,
 393   }
 394
 395   # swift proxy
 396   include ::memcached
 397   include ::swift::proxy
 398   include ::swift::proxy::proxy_logging
 399   include ::swift::proxy::healthcheck
 400   include ::swift::proxy::cache
 401   include ::swift::proxy::keystone
 402   include ::swift::proxy::authtoken
 403   include ::swift::proxy::staticweb
 404   include ::swift::proxy::ratelimit
 405   include ::swift::proxy::catch_errors
 406   include ::swift::proxy::tempurl
 407   include ::swift::proxy::formpost
 408
 409   # swift storage
 410   if str2bool(hiera('enable_swift_storage', true)) {
 411     class { '::swift::storage::all':
 412       mount_check => str2bool(hiera('swift_mount_check')),
 413     }
 414     if(!defined(File['/srv/node'])) {
 415       file { '/srv/node':
 416         ensure  => directory,
 417         owner   => 'swift',
 418         group   => 'swift',
 419         require => Package['openstack-swift'],
 420       }
 421     }
 422     $swift_components = ['account', 'container', 'object']
 423     swift::storage::filter::recon { $swift_components : }
 424     swift::storage::filter::healthcheck { $swift_components : }
 425   }
 426
 427   # Ceilometer
 428   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 429   case $ceilometer_backend {
 430     /mysql/ : {
 431       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 432     }
 433     default : {
 434       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 435     }
 436   }
 437   include ::ceilometer
 438   include ::ceilometer::config
 439   include ::ceilometer::api
 440   include ::ceilometer::agent::notification
 441   include ::ceilometer::agent::central
 442   include ::ceilometer::alarm::notifier
 443   include ::ceilometer::alarm::evaluator
 444   include ::ceilometer::expirer
 445   include ::ceilometer::collector
 446   include ::ceilometer::agent::auth
 447   class { '::ceilometer::db' :
 448     database_connection => $ceilometer_database_connection,
 449   }
 450
 451   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 452
 453   # Heat
 454   include ::heat
 455   include ::heat::api
 456   include ::heat::api_cfn
 457   include ::heat::api_cloudwatch
 458   include ::heat::engine
 459
 460   # Horizon
 461   if 'cisco_n1kv' in hiera('neutron_mechanism_drivers') {
 462     $_profile_support = 'cisco'
 463   } else {
 464     $_profile_support = 'None'
 465   }
 466   $neutron_options   = {'profile_support' => $_profile_support }
 467
 468   class { '::horizon':
 469     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 470     neutron_options => $neutron_options,
 471   }
 472
 473   $snmpd_user = hiera('snmpd_readonly_user_name')
 474   snmp::snmpv3_user { $snmpd_user:
 475     authtype => 'MD5',
 476     authpass => hiera('snmpd_readonly_user_password'),
 477   }
 478   class { '::snmp':
 479     agentaddress => ['udp:161','udp6:[::1]:161'],
 480     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 481   }
 482
 483   hiera_include('controller_classes')
 484
 485 } #END STEP 3
 486
 487 if hiera('step') >= 4 {
 488   include ::keystone::cron::token_flush
 489 } #END STEP 4
 490
 491 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 492 package_manifest{$package_manifest_name: ensure => present}