puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 if hiera('step') >= 1 {
  20
  21   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  22
  23   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  24
  25   class { '::tripleo::loadbalancer' :
  26     controller_hosts => $controller_node_ips,
  27     manage_vip       => true,
  28   }
  29
  30 }
  31
  32 if hiera('step') >= 2 {
  33
  34   if count(hiera('ntp::servers')) > 0 {
  35     include ::ntp
  36   }
  37
  38   # MongoDB
  39   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  40     include ::mongodb::globals
  41
  42     include ::mongodb::server
  43     $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  44     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  45
  46     $mongodb_replset = hiera('mongodb::server::replset')
  47     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  48     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  49       mongodb_replset { $mongodb_replset :
  50         members => $mongo_node_ips_with_port,
  51       }
  52     }
  53   }
  54
  55   # Redis
  56   $redis_node_ips = hiera('redis_node_ips')
  57   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  58
  59   if $redis_master_hostname == $::hostname {
  60     $slaveof = undef
  61   } else {
  62     $slaveof = "${redis_master_hostname} 6379"
  63   }
  64   class {'::redis' :
  65     slaveof => $slaveof,
  66   }
  67
  68   if count($redis_node_ips) > 1 {
  69     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  70     include ::redis::sentinel
  71     include ::tripleo::redis_notification
  72   }
  73
  74   if str2bool(hiera('enable_galera', true)) {
  75     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  76   } else {
  77     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  78   }
  79   # TODO Galara
  80   class { '::mysql::server':
  81     config_file             => $mysql_config_file,
  82     override_options        => {
  83       'mysqld' => {
  84         'bind-address'     => hiera('mysql_bind_host'),
  85         'max_connections'  => hiera('mysql_max_connections'),
  86         'open_files_limit' => '-1',
  87       },
  88     },
  89     remove_default_accounts => true,
  90   }
  91
  92   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  93   # Create all the database schemas
  94   include ::keystone::db::mysql
  95   include ::glance::db::mysql
  96   include ::nova::db::mysql
  97   include ::neutron::db::mysql
  98   include ::cinder::db::mysql
  99   include ::heat::db::mysql
 100   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 101     include ::ceilometer::db::mysql
 102   }
 103
 104   $rabbit_nodes = hiera('rabbit_node_ips')
 105   if count($rabbit_nodes) > 1 {
 106     class { '::rabbitmq':
 107       config_cluster          => true,
 108       cluster_nodes           => $rabbit_nodes,
 109       tcp_keepalive           => false,
 110       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 111       config_variables        => hiera('rabbitmq_config_variables'),
 112       environment_variables   => hiera('rabbitmq_environment'),
 113     }
 114     rabbitmq_policy { 'ha-all@/':
 115       pattern    => '^(?!amq\.).*',
 116       definition => {
 117         'ha-mode' => 'all',
 118       },
 119     }
 120   } else {
 121     include ::rabbitmq
 122   }
 123
 124   # pre-install swift here so we can build rings
 125   include ::swift
 126
 127   $enable_ceph = hiera('ceph_storage_count', 0) > 0
 128
 129   if $enable_ceph {
 130     class { '::ceph::profile::params':
 131       mon_initial_members => downcase(hiera('ceph_mon_initial_members')),
 132     }
 133     include ::ceph::profile::mon
 134   }
 135
 136   if str2bool(hiera('enable_ceph_storage', false)) {
 137     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 138       exec { 'set selinux to permissive on boot':
 139         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 140         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 141         path    => ['/usr/bin', '/usr/sbin'],
 142       }
 143
 144       exec { 'set selinux to permissive':
 145         command => 'setenforce 0',
 146         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 147         path    => ['/usr/bin', '/usr/sbin'],
 148       } -> Class['ceph::profile::osd']
 149     }
 150
 151     include ::ceph::profile::osd
 152   }
 153
 154   if str2bool(hiera('enable_external_ceph', false)) {
 155     include ::ceph::profile::client
 156   }
 157
 158 } #END STEP 2
 159
 160 if hiera('step') >= 3 {
 161
 162   include ::keystone
 163   include ::keystone::roles::admin
 164   include ::keystone::endpoint
 165
 166   #TODO: need a cleanup-keystone-tokens.sh solution here
 167   keystone_config {
 168     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 169   }
 170   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 171     ensure  => 'directory',
 172     owner   => 'keystone',
 173     group   => 'keystone',
 174     require => Package['keystone'],
 175   }
 176   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 177     content => hiera('keystone_signing_certificate'),
 178     owner   => 'keystone',
 179     group   => 'keystone',
 180     notify  => Service['keystone'],
 181     require => File['/etc/keystone/ssl/certs'],
 182   }
 183   file { '/etc/keystone/ssl/private/signing_key.pem':
 184     content => hiera('keystone_signing_key'),
 185     owner   => 'keystone',
 186     group   => 'keystone',
 187     notify  => Service['keystone'],
 188     require => File['/etc/keystone/ssl/private'],
 189   }
 190   file { '/etc/keystone/ssl/certs/ca.pem':
 191     content => hiera('keystone_ca_certificate'),
 192     owner   => 'keystone',
 193     group   => 'keystone',
 194     notify  => Service['keystone'],
 195     require => File['/etc/keystone/ssl/certs'],
 196   }
 197
 198   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 199   case $glance_backend {
 200       'swift': { $backend_store = 'glance.store.swift.Store' }
 201       'file': { $backend_store = 'glance.store.filesystem.Store' }
 202       'rbd': { $backend_store = 'glance.store.rbd.Store' }
 203       default: { fail('Unrecognized glance_backend parameter.') }
 204   }
 205   $http_store = ['glance.store.http.Store']
 206   $glance_store = concat($http_store, $backend_store)
 207
 208   # TODO: notifications, scrubber, etc.
 209   include ::glance
 210   class { '::glance::api':
 211     known_stores => $glance_store,
 212   }
 213   include ::glance::registry
 214   include join(['::glance::backend::', $glance_backend])
 215
 216   class { '::nova' :
 217     memcached_servers => suffix(hiera('memcache_node_ips'), ':11211'),
 218   }
 219   include ::nova::config
 220   include ::nova::api
 221   include ::nova::cert
 222   include ::nova::conductor
 223   include ::nova::consoleauth
 224   include ::nova::network::neutron
 225   include ::nova::vncproxy
 226   include ::nova::scheduler
 227   include ::nova::scheduler::filter
 228
 229   include ::neutron
 230   include ::neutron::server
 231   include ::neutron::server::notifications
 232   include ::neutron::agents::l3
 233   include ::neutron::agents::dhcp
 234   include ::neutron::agents::metadata
 235
 236   file { '/etc/neutron/dnsmasq-neutron.conf':
 237     content => hiera('neutron_dnsmasq_options'),
 238     owner   => 'neutron',
 239     group   => 'neutron',
 240     notify  => Service['neutron-dhcp-service'],
 241     require => Package['neutron'],
 242   }
 243
 244   class { '::neutron::plugins::ml2':
 245     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 246     tenant_network_types => [hiera('neutron_tenant_network_type')],
 247     mechanism_drivers    => [hiera('neutron_mechanism_drivers')],
 248   }
 249   class { '::neutron::agents::ml2::ovs':
 250     bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
 251     tunnel_types    => split(hiera('neutron_tunnel_types'), ','),
 252   }
 253   if 'cisco_n1kv' in hiera('neutron_mechanism_drivers') {
 254     include ::neutron::plugins::ml2::cisco::nexus1000v
 255
 256     class { '::neutron::agents::n1kv_vem':
 257       n1kv_source  => hiera('n1kv_vem_source', undef),
 258       n1kv_version => hiera('n1kv_vem_version', undef),
 259     }
 260
 261     class { '::n1k_vsm':
 262       n1kv_source       => hiera('n1kv_vsm_source', undef),
 263       n1kv_version      => hiera('n1kv_vsm_version', undef),
 264       pacemaker_control => false,
 265     }
 266   }
 267
 268   if 'cisco_ucsm' in hiera('neutron_mechanism_drivers') {
 269     include ::neutron::plugins::ml2::cisco::ucsm
 270   }
 271   if 'cisco_nexus' in hiera('neutron_mechanism_drivers') {
 272     include ::neutron::plugins::ml2::cisco::nexus
 273     include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 274   }
 275
 276   if hiera('neutron_enable_bigswitch_ml2', false) {
 277     include ::neutron::plugins::ml2::bigswitch::restproxy
 278   }
 279   neutron_l3_agent_config {
 280     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 281   }
 282   neutron_dhcp_agent_config {
 283     'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 284   }
 285
 286   Service['neutron-server'] -> Service['neutron-dhcp-service']
 287   Service['neutron-server'] -> Service['neutron-l3']
 288   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 289   Service['neutron-server'] -> Service['neutron-metadata']
 290
 291   include ::cinder
 292   include ::cinder::api
 293   include ::cinder::glance
 294   include ::cinder::scheduler
 295   include ::cinder::volume
 296   class { '::cinder::setup_test_volume':
 297     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 298   }
 299
 300   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 301   if $cinder_enable_iscsi {
 302     $cinder_iscsi_backend = 'tripleo_iscsi'
 303
 304     cinder::backend::iscsi { $cinder_iscsi_backend :
 305       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 306       iscsi_helper     => hiera('cinder_iscsi_helper'),
 307     }
 308   }
 309
 310   if $enable_ceph {
 311
 312     $ceph_pools = hiera('ceph_pools')
 313     ceph::pool { $ceph_pools :
 314       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 315       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 316       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 317     }
 318
 319     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 320
 321   } else {
 322     $cinder_pool_requires = []
 323   }
 324
 325   if hiera('cinder_enable_rbd_backend', false) {
 326     $cinder_rbd_backend = 'tripleo_ceph'
 327
 328     cinder::backend::rbd { $cinder_rbd_backend :
 329       rbd_pool        => hiera('cinder_rbd_pool_name'),
 330       rbd_user        => hiera('ceph_client_user_name'),
 331       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 332       require         => $cinder_pool_requires,
 333     }
 334   }
 335
 336   if hiera('cinder_enable_netapp_backend', false) {
 337     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 338
 339     cinder_config {
 340       "${cinder_netapp_backend}/host": value => 'hostgroup';
 341     }
 342
 343     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 344       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 345     }
 346
 347     cinder::backend::netapp { $cinder_netapp_backend :
 348       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 349       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 350       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 351       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 352       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 353       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 354       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 355       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 356       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 357       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 358       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 359       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 360       nfs_shares                   => $cinder_netapp_nfs_shares,
 361       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 362       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 363       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 364       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 365       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 366       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 367       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 368     }
 369   }
 370
 371   if hiera('cinder_enable_nfs_backend', false) {
 372     $cinder_nfs_backend = 'tripleo_nfs'
 373
 374     if str2bool($::selinux) {
 375       selboolean { 'virt_use_nfs':
 376         value      => on,
 377         persistent => true,
 378       } -> Package['nfs-utils']
 379     }
 380
 381     package {'nfs-utils': } ->
 382     cinder::backend::nfs { $cinder_nfs_backend :
 383       nfs_servers       => hiera('cinder_nfs_servers'),
 384       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 385       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 386     }
 387   }
 388
 389   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 390   class { '::cinder::backends' :
 391     enabled_backends => $cinder_enabled_backends,
 392   }
 393
 394   # swift proxy
 395   include ::memcached
 396   include ::swift::proxy
 397   include ::swift::proxy::proxy_logging
 398   include ::swift::proxy::healthcheck
 399   include ::swift::proxy::cache
 400   include ::swift::proxy::keystone
 401   include ::swift::proxy::authtoken
 402   include ::swift::proxy::staticweb
 403   include ::swift::proxy::ratelimit
 404   include ::swift::proxy::catch_errors
 405   include ::swift::proxy::tempurl
 406   include ::swift::proxy::formpost
 407
 408   # swift storage
 409   if str2bool(hiera('enable_swift_storage', true)) {
 410     class { '::swift::storage::all':
 411       mount_check => str2bool(hiera('swift_mount_check')),
 412     }
 413     if(!defined(File['/srv/node'])) {
 414       file { '/srv/node':
 415         ensure  => directory,
 416         owner   => 'swift',
 417         group   => 'swift',
 418         require => Package['openstack-swift'],
 419       }
 420     }
 421     $swift_components = ['account', 'container', 'object']
 422     swift::storage::filter::recon { $swift_components : }
 423     swift::storage::filter::healthcheck { $swift_components : }
 424   }
 425
 426   # Ceilometer
 427   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 428   case $ceilometer_backend {
 429     /mysql/ : {
 430       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 431     }
 432     default : {
 433       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 434     }
 435   }
 436   include ::ceilometer
 437   include ::ceilometer::config
 438   include ::ceilometer::api
 439   include ::ceilometer::agent::notification
 440   include ::ceilometer::agent::central
 441   include ::ceilometer::alarm::notifier
 442   include ::ceilometer::alarm::evaluator
 443   include ::ceilometer::expirer
 444   include ::ceilometer::collector
 445   include ::ceilometer::agent::auth
 446   class { '::ceilometer::db' :
 447     database_connection => $ceilometer_database_connection,
 448   }
 449
 450   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 451
 452   # Heat
 453   include ::heat
 454   include ::heat::api
 455   include ::heat::api_cfn
 456   include ::heat::api_cloudwatch
 457   include ::heat::engine
 458
 459   # Horizon
 460   if 'cisco_n1kv' in hiera('neutron_mechanism_drivers') {
 461     $_profile_support = 'cisco'
 462   } else {
 463     $_profile_support = 'None'
 464   }
 465   $neutron_options   = {'profile_support' => $_profile_support }
 466
 467   class { '::horizon':
 468     cache_server_ip => hiera('memcache_node_ips', '127.0.0.1'),
 469     neutron_options => $neutron_options,
 470   }
 471
 472   $snmpd_user = hiera('snmpd_readonly_user_name')
 473   snmp::snmpv3_user { $snmpd_user:
 474     authtype => 'MD5',
 475     authpass => hiera('snmpd_readonly_user_password'),
 476   }
 477   class { '::snmp':
 478     agentaddress => ['udp:161','udp6:[::1]:161'],
 479     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 480   }
 481
 482   hiera_include('controller_classes')
 483
 484 } #END STEP 3
 485
 486 if hiera('step') >= 4 {
 487   include ::keystone::cron::token_flush
 488 } #END STEP 4
 489
 490 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 491 package_manifest{$package_manifest_name: ensure => present}