puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  28
  29   if $enable_load_balancer {
  30     class { '::tripleo::loadbalancer' :
  31       controller_hosts => $controller_node_ips,
  32       manage_vip       => true,
  33     }
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   include ::timezone
  45
  46   # MongoDB
  47   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  48     include ::mongodb::globals
  49     include ::mongodb::client
  50     include ::mongodb::server
  51     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  52     # without the brackets as 'members' argument for the 'mongodb_replset'
  53     # resource.
  54     if str2bool(hiera('mongodb::server::ipv6', false)) {
  55       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  56       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  57       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  58     } else {
  59       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  60       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  61     }
  62     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  63
  64     $mongodb_replset = hiera('mongodb::server::replset')
  65     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  66     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  67       mongodb_replset { $mongodb_replset :
  68         members => $mongo_node_ips_with_port_nobr,
  69       }
  70     }
  71   }
  72
  73   # Redis
  74   $redis_node_ips = hiera('redis_node_ips')
  75   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  76
  77   if $redis_master_hostname == $::hostname {
  78     $slaveof = undef
  79   } else {
  80     $slaveof = "${redis_master_hostname} 6379"
  81   }
  82   class {'::redis' :
  83     slaveof => $slaveof,
  84   }
  85
  86   if count($redis_node_ips) > 1 {
  87     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  88     include ::redis::sentinel
  89     include ::tripleo::redis_notification
  90   }
  91
  92   if str2bool(hiera('enable_galera', true)) {
  93     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  94   } else {
  95     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  96   }
  97   # TODO Galara
  98   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  99   # set bind-address to a hostname instead of an ip address; to move Mysql
 100   # from internal_api on another network we'll have to customize both
 101   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
 102   class { '::mysql::server':
 103     config_file             => $mysql_config_file,
 104     override_options        => {
 105       'mysqld' => {
 106         'bind-address'     => $::hostname,
 107         'max_connections'  => hiera('mysql_max_connections'),
 108         'open_files_limit' => '-1',
 109       },
 110     },
 111     remove_default_accounts => true,
 112   }
 113
 114   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 115   # Create all the database schemas
 116   include ::nova::db::mysql
 117   include ::nova::db::mysql_api
 118   include ::neutron::db::mysql
 119   include ::cinder::db::mysql
 120   include ::heat::db::mysql
 121   include ::sahara::db::mysql
 122   if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
 123     include ::gnocchi::db::mysql
 124   }
 125   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 126     include ::ceilometer::db::mysql
 127     include ::aodh::db::mysql
 128   }
 129
 130   $rabbit_nodes = hiera('rabbit_node_ips')
 131   if count($rabbit_nodes) > 1 {
 132
 133     $rabbit_ipv6 = str2bool(hiera('rabbit_ipv6', false))
 134     if $rabbit_ipv6 {
 135       $rabbit_env = merge(hiera('rabbitmq_environment'), {
 136         'RABBITMQ_SERVER_START_ARGS' => '"-proto_dist inet6_tcp"'
 137       })
 138     } else {
 139       $rabbit_env = hiera('rabbitmq_environment')
 140     }
 141
 142     class { '::rabbitmq':
 143       config_cluster          => true,
 144       cluster_nodes           => $rabbit_nodes,
 145       tcp_keepalive           => false,
 146       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 147       config_variables        => hiera('rabbitmq_config_variables'),
 148       environment_variables   => $rabbit_env,
 149     }
 150     rabbitmq_policy { 'ha-all@/':
 151       pattern    => '^(?!amq\.).*',
 152       definition => {
 153         'ha-mode' => 'all',
 154       },
 155     }
 156   } else {
 157     include ::rabbitmq
 158   }
 159
 160   # pre-install swift here so we can build rings
 161   include ::swift
 162
 163   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 164
 165   if $enable_ceph {
 166     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 167     if str2bool(hiera('ceph_ipv6', false)) {
 168       $mon_host = hiera('ceph_mon_host_v6')
 169     } else {
 170       $mon_host = hiera('ceph_mon_host')
 171     }
 172     class { '::ceph::profile::params':
 173       mon_initial_members => $mon_initial_members,
 174       mon_host            => $mon_host,
 175     }
 176     include ::ceph::conf
 177     include ::ceph::profile::mon
 178   }
 179
 180   if str2bool(hiera('enable_ceph_storage', false)) {
 181     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 182       exec { 'set selinux to permissive on boot':
 183         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 184         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 185         path    => ['/usr/bin', '/usr/sbin'],
 186       }
 187
 188       exec { 'set selinux to permissive':
 189         command => 'setenforce 0',
 190         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 191         path    => ['/usr/bin', '/usr/sbin'],
 192       } -> Class['ceph::profile::osd']
 193     }
 194
 195     include ::ceph::conf
 196     include ::ceph::profile::osd
 197   }
 198
 199   if str2bool(hiera('enable_external_ceph', false)) {
 200     if str2bool(hiera('ceph_ipv6', false)) {
 201       $mon_host = hiera('ceph_mon_host_v6')
 202     } else {
 203       $mon_host = hiera('ceph_mon_host')
 204     }
 205     class { '::ceph::profile::params':
 206       mon_host            => $mon_host,
 207     }
 208     include ::ceph::conf
 209     include ::ceph::profile::client
 210   }
 211
 212 } #END STEP 2
 213
 214 if hiera('step') >= 4 {
 215
 216   $nova_ipv6 = hiera('nova::use_ipv6', false)
 217   if $nova_ipv6 {
 218     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 219   } else {
 220     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 221   }
 222
 223   class { '::nova' :
 224     memcached_servers => $memcached_servers
 225   }
 226   include ::nova::config
 227   include ::nova::api
 228   include ::nova::cert
 229   include ::nova::conductor
 230   include ::nova::consoleauth
 231   include ::nova::network::neutron
 232   include ::nova::vncproxy
 233   include ::nova::scheduler
 234   include ::nova::scheduler::filter
 235
 236   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 237
 238     # TODO(devvesa) provide non-controller ips for these services
 239     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 240     $cassandra_node_ips = hiera('neutron_api_node_ips')
 241
 242     # Run zookeeper in the controller if configured
 243     if hiera('enable_zookeeper_on_controller') {
 244       class {'::tripleo::cluster::zookeeper':
 245         zookeeper_server_ips => $zookeeper_node_ips,
 246         # TODO: create a 'bind' hiera key for zookeeper
 247         zookeeper_client_ip  => hiera('neutron::bind_host'),
 248         zookeeper_hostnames  => hiera('controller_node_names')
 249       }
 250     }
 251
 252     # Run cassandra in the controller if configured
 253     if hiera('enable_cassandra_on_controller') {
 254       class {'::tripleo::cluster::cassandra':
 255         cassandra_servers => $cassandra_node_ips,
 256         # TODO: create a 'bind' hiera key for cassandra
 257         cassandra_ip      => hiera('neutron::bind_host'),
 258       }
 259     }
 260
 261     class {'::tripleo::network::midonet::agent':
 262       zookeeper_servers => $zookeeper_node_ips,
 263       cassandra_seeds   => $cassandra_node_ips
 264     }
 265
 266     class {'::tripleo::network::midonet::api':
 267       zookeeper_servers    => $zookeeper_node_ips,
 268       vip                  => hiera('tripleo::loadbalancer::public_virtual_ip'),
 269       keystone_ip          => hiera('tripleo::loadbalancer::public_virtual_ip'),
 270       keystone_admin_token => hiera('keystone::admin_token'),
 271       # TODO: create a 'bind' hiera key for api
 272       bind_address         => hiera('neutron::bind_host'),
 273       admin_password       => hiera('admin_password')
 274     }
 275
 276     # TODO: find a way to get an empty list from hiera
 277     class {'::neutron':
 278       service_plugins => []
 279     }
 280
 281   }
 282   else {
 283
 284     # ML2 plugin
 285     include ::neutron
 286   }
 287
 288   include ::neutron::config
 289   include ::neutron::server
 290   include ::neutron::server::notifications
 291
 292   # If the value of core plugin is set to 'nuage' or'opencontrail' or 'plumgrid',
 293   # include nuage or opencontrail or plumgrid core plugins
 294   # else use the default value of 'ml2'
 295   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 296     include ::neutron::plugins::nuage
 297   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 298     include ::neutron::plugins::opencontrail
 299   }
 300   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 301     class { '::neutron::plugins::plumgrid' :
 302       connection                   => hiera('neutron::server::database_connection'),
 303       controller_priv_host         => hiera('keystone_admin_api_vip'),
 304       admin_password               => hiera('admin_password'),
 305       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 306     }
 307   } else {
 308     include ::neutron::agents::l3
 309     include ::neutron::agents::dhcp
 310     include ::neutron::agents::metadata
 311
 312     file { '/etc/neutron/dnsmasq-neutron.conf':
 313       content => hiera('neutron_dnsmasq_options'),
 314       owner   => 'neutron',
 315       group   => 'neutron',
 316       notify  => Service['neutron-dhcp-service'],
 317       require => Package['neutron'],
 318     }
 319
 320     # If the value of core plugin is set to 'midonet',
 321     # skip all the ML2 configuration
 322     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 323
 324       class {'::neutron::plugins::midonet':
 325         midonet_api_ip    => hiera('tripleo::loadbalancer::public_virtual_ip'),
 326         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 327         keystone_password => hiera('neutron::server::auth_password')
 328       }
 329     } else {
 330
 331       include ::neutron::plugins::ml2
 332       include ::neutron::agents::ml2::ovs
 333
 334       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 335         include ::neutron::plugins::ml2::cisco::nexus1000v
 336
 337         class { '::neutron::agents::n1kv_vem':
 338           n1kv_source  => hiera('n1kv_vem_source', undef),
 339           n1kv_version => hiera('n1kv_vem_version', undef),
 340         }
 341
 342         class { '::n1k_vsm':
 343           n1kv_source       => hiera('n1kv_vsm_source', undef),
 344           n1kv_version      => hiera('n1kv_vsm_version', undef),
 345           pacemaker_control => false,
 346         }
 347       }
 348
 349       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 350         include ::neutron::plugins::ml2::cisco::ucsm
 351       }
 352       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 353         include ::neutron::plugins::ml2::cisco::nexus
 354         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 355       }
 356
 357       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 358         include ::neutron::plugins::ml2::bigswitch::restproxy
 359         include ::neutron::agents::bigswitch
 360       }
 361       neutron_l3_agent_config {
 362         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 363       }
 364       neutron_dhcp_agent_config {
 365         'DEFAULT/ovs_use_veth': value => hiera('neutron_ovs_use_veth', false);
 366       }
 367       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 368     }
 369
 370     Service['neutron-server'] -> Service['neutron-dhcp-service']
 371     Service['neutron-server'] -> Service['neutron-l3']
 372     Service['neutron-server'] -> Service['neutron-metadata']
 373   }
 374
 375   include ::cinder
 376   include ::cinder::config
 377   include ::tripleo::ssl::cinder_config
 378   include ::cinder::api
 379   include ::cinder::glance
 380   include ::cinder::scheduler
 381   include ::cinder::volume
 382   include ::cinder::ceilometer
 383   class { '::cinder::setup_test_volume':
 384     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 385   }
 386
 387   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 388   if $cinder_enable_iscsi {
 389     $cinder_iscsi_backend = 'tripleo_iscsi'
 390
 391     cinder::backend::iscsi { $cinder_iscsi_backend :
 392       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 393       iscsi_helper     => hiera('cinder_iscsi_helper'),
 394     }
 395   }
 396
 397   if $enable_ceph {
 398
 399     $ceph_pools = hiera('ceph_pools')
 400     ceph::pool { $ceph_pools :
 401       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 402       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 403       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 404     }
 405
 406     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 407
 408   } else {
 409     $cinder_pool_requires = []
 410   }
 411
 412   if hiera('cinder_enable_rbd_backend', false) {
 413     $cinder_rbd_backend = 'tripleo_ceph'
 414
 415     cinder::backend::rbd { $cinder_rbd_backend :
 416       backend_host    => hiera('cinder::host'),
 417       rbd_pool        => hiera('cinder_rbd_pool_name'),
 418       rbd_user        => hiera('ceph_client_user_name'),
 419       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 420       require         => $cinder_pool_requires,
 421     }
 422   }
 423
 424   if hiera('cinder_enable_eqlx_backend', false) {
 425     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 426
 427     cinder::backend::eqlx { $cinder_eqlx_backend :
 428       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 429       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 430       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 431       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 432       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 433       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 434       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 435       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 436       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 437       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 438     }
 439   }
 440
 441   if hiera('cinder_enable_dellsc_backend', false) {
 442     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 443
 444     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 445       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 446       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 447       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 448       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 449       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 450       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 451       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 452       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 453       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 454       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 455     }
 456   }
 457
 458   if hiera('cinder_enable_netapp_backend', false) {
 459     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 460
 461     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 462       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 463     }
 464
 465     cinder::backend::netapp { $cinder_netapp_backend :
 466       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 467       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 468       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 469       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 470       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 471       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 472       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 473       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 474       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 475       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 476       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 477       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 478       nfs_shares                   => $cinder_netapp_nfs_shares,
 479       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 480       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 481       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 482       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 483       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 484       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 485       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 486     }
 487   }
 488
 489   if hiera('cinder_enable_nfs_backend', false) {
 490     $cinder_nfs_backend = 'tripleo_nfs'
 491
 492     if str2bool($::selinux) {
 493       selboolean { 'virt_use_nfs':
 494         value      => on,
 495         persistent => true,
 496       } -> Package['nfs-utils']
 497     }
 498
 499     package {'nfs-utils': } ->
 500     cinder::backend::nfs { $cinder_nfs_backend :
 501       nfs_servers       => hiera('cinder_nfs_servers'),
 502       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 503       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 504     }
 505   }
 506
 507   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 508   class { '::cinder::backends' :
 509     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 510   }
 511
 512   # swift proxy
 513   include ::memcached
 514   include ::swift::proxy
 515   include ::swift::proxy::proxy_logging
 516   include ::swift::proxy::healthcheck
 517   include ::swift::proxy::cache
 518   include ::swift::proxy::keystone
 519   include ::swift::proxy::authtoken
 520   include ::swift::proxy::staticweb
 521   include ::swift::proxy::ratelimit
 522   include ::swift::proxy::catch_errors
 523   include ::swift::proxy::tempurl
 524   include ::swift::proxy::formpost
 525
 526   # swift storage
 527   if str2bool(hiera('enable_swift_storage', true)) {
 528     class { '::swift::storage::all':
 529       mount_check => str2bool(hiera('swift_mount_check')),
 530     }
 531     if(!defined(File['/srv/node'])) {
 532       file { '/srv/node':
 533         ensure  => directory,
 534         owner   => 'swift',
 535         group   => 'swift',
 536         require => Package['openstack-swift'],
 537       }
 538     }
 539     $swift_components = ['account', 'container', 'object']
 540     swift::storage::filter::recon { $swift_components : }
 541     swift::storage::filter::healthcheck { $swift_components : }
 542   }
 543
 544   # Ceilometer
 545   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 546   case $ceilometer_backend {
 547     /mysql/ : {
 548       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 549     }
 550     default : {
 551       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 552     }
 553   }
 554   include ::ceilometer
 555   include ::ceilometer::config
 556   include ::ceilometer::api
 557   include ::ceilometer::agent::notification
 558   include ::ceilometer::agent::central
 559   include ::ceilometer::expirer
 560   include ::ceilometer::collector
 561   include ::ceilometer::agent::auth
 562   include ::ceilometer::dispatcher::gnocchi
 563   class { '::ceilometer::db' :
 564     database_connection => $ceilometer_database_connection,
 565   }
 566
 567   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 568
 569   # Aodh
 570   class { '::aodh' :
 571     database_connection => $ceilometer_database_connection,
 572   }
 573   include ::aodh::db::sync
 574   # To manage the upgrade:
 575   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 576   include ::aodh::auth
 577   include ::aodh::api
 578   include ::aodh::wsgi::apache
 579   include ::aodh::evaluator
 580   include ::aodh::notifier
 581   include ::aodh::listener
 582   include ::aodh::client
 583
 584   # Heat
 585   class { '::heat' :
 586     notification_driver => 'messaging',
 587   }
 588   include ::heat::config
 589   include ::heat::api
 590   include ::heat::api_cfn
 591   include ::heat::api_cloudwatch
 592   include ::heat::engine
 593
 594   # Sahara
 595   include ::sahara
 596   include ::sahara::service::api
 597   include ::sahara::service::engine
 598
 599   # Horizon
 600   include ::apache::mod::remoteip
 601   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 602     $_profile_support = 'cisco'
 603   } else {
 604     $_profile_support = 'None'
 605   }
 606   $neutron_options   = {'profile_support' => $_profile_support }
 607
 608   $memcached_ipv6 = hiera('memcached_ipv6', false)
 609   if $memcached_ipv6 {
 610     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 611   } else {
 612     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 613   }
 614
 615   class { '::horizon':
 616     cache_server_ip => $horizon_memcached_servers,
 617     neutron_options => $neutron_options,
 618   }
 619
 620   # Gnocchi
 621   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 622   class { '::gnocchi':
 623     database_connection => $gnocchi_database_connection,
 624   }
 625   include ::gnocchi::api
 626   include ::gnocchi::wsgi::apache
 627   include ::gnocchi::client
 628   include ::gnocchi::db::sync
 629   include ::gnocchi::storage
 630   include ::gnocchi::metricd
 631   include ::gnocchi::statsd
 632   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 633   case $gnocchi_backend {
 634       'swift': { include ::gnocchi::storage::swift }
 635       'file': { include ::gnocchi::storage::file }
 636       'rbd': { include ::gnocchi::storage::ceph }
 637       default: { fail('Unrecognized gnocchi_backend parameter.') }
 638   }
 639
 640   $snmpd_user = hiera('snmpd_readonly_user_name')
 641   snmp::snmpv3_user { $snmpd_user:
 642     authtype => 'MD5',
 643     authpass => hiera('snmpd_readonly_user_password'),
 644   }
 645   class { '::snmp':
 646     agentaddress => ['udp:161','udp6:[::1]:161'],
 647     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 648   }
 649
 650   hiera_include('controller_classes')
 651
 652 } #END STEP 4
 653
 654 if hiera('step') >= 5 {
 655   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 656   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 657   $heat_enable_db_purge = hiera('heat_enable_db_purge', true)
 658
 659   if $nova_enable_db_purge {
 660     include ::nova::cron::archive_deleted_rows
 661   }
 662   if $cinder_enable_db_purge {
 663     include ::cinder::cron::db_purge
 664   }
 665   if $heat_enable_db_purge {
 666     include ::heat::cron::purge_deleted
 667   }
 668
 669   if downcase(hiera('bootstrap_nodeid')) == $::hostname {
 670     # Class ::heat::keystone::domain has to run on bootstrap node
 671     # because it creates DB entities via API calls.
 672     include ::heat::keystone::domain
 673
 674     Class['::keystone::roles::admin'] -> Class['::heat::keystone::domain']
 675   } else {
 676     # On non-bootstrap node we don't need to create Keystone resources again
 677     class { '::heat::keystone::domain':
 678       manage_domain => false,
 679       manage_user   => false,
 680       manage_role   => false,
 681     }
 682   }
 683
 684 } #END STEP 5
 685
 686 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 687 package_manifest{$package_manifest_name: ensure => present}