puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if hiera('step') >= 1 {
  28
  29   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  30   $enable_pacemaker = str2bool(hiera('enable_pacemaker'))
  31   $enable_keepalived = !$enable_pacemaker
  32
  33   class { '::tripleo::loadbalancer' :
  34     controller_hosts => $controller_node_ips,
  35   }
  36
  37   if $enable_pacemaker {
  38     $pacemaker_cluster_members = regsubst(hiera('controller_node_ips'), ',', ' ', 'G')
  39     if $::hostname == downcase(hiera('bootstrap_nodeid')) {
  40       $pacemaker_master = true
  41     } else {
  42       $pacemaker_master = false
  43     }
  44     user { 'hacluster':
  45      ensure => present,
  46     } ->
  47     class { '::pacemaker':
  48       hacluster_pwd => hiera('hacluster_pwd'),
  49     } ->
  50     class { '::pacemaker::corosync':
  51       cluster_members => $pacemaker_cluster_members,
  52       setup_cluster   => $pacemaker_master,
  53     }
  54     class { '::pacemaker::stonith':
  55       disable => true,
  56     }
  57   }
  58
  59 }
  60
  61 if hiera('step') >= 2 {
  62
  63   if count(hiera('ntp::servers')) > 0 {
  64     include ::ntp
  65   }
  66
  67   # MongoDB
  68   include ::mongodb::globals
  69   include ::mongodb::server
  70   $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
  71   $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
  72   $mongo_node_string = join($mongo_node_ips_with_port, ',')
  73
  74   $mongodb_replset = hiera('mongodb::server::replset')
  75   $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  76   if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  77     mongodb_replset { $mongodb_replset :
  78       members => $mongo_node_ips_with_port,
  79     }
  80   }
  81
  82   # Redis
  83   $redis_node_ips = split(hiera('redis_node_ips'), ',')
  84   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  85
  86   if $redis_master_hostname == $::hostname {
  87     $slaveof = undef
  88   } else {
  89     $slaveof = "${redis_master_hostname} 6379"
  90   }
  91   class {'::redis' :
  92     slaveof => $slaveof,
  93   }
  94
  95   if count($redis_node_ips) > 1 {
  96     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  97     include ::redis::sentinel
  98     class {'::tripleo::redis_notification' :
  99       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
 100     }
 101   }
 102
 103   if str2bool(hiera('enable_galera', 'true')) {
 104     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
 105   } else {
 106     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
 107   }
 108   # TODO Galara
 109   class { 'mysql::server':
 110     config_file => $mysql_config_file,
 111     override_options => {
 112       'mysqld' => {
 113         'bind-address' => hiera('controller_host')
 114       }
 115     }
 116   }
 117
 118   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 119   # Create all the database schemas
 120   # Example DSN format: mysql://user:password@host/dbname
 121   $allowed_hosts = ['%',hiera('controller_host')]
 122   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 123   class { 'keystone::db::mysql':
 124     user          => $keystone_dsn[3],
 125     password      => $keystone_dsn[4],
 126     host          => $keystone_dsn[5],
 127     dbname        => $keystone_dsn[6],
 128     allowed_hosts => $allowed_hosts,
 129   }
 130   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 131   class { 'glance::db::mysql':
 132     user          => $glance_dsn[3],
 133     password      => $glance_dsn[4],
 134     host          => $glance_dsn[5],
 135     dbname        => $glance_dsn[6],
 136     allowed_hosts => $allowed_hosts,
 137   }
 138   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 139   class { 'nova::db::mysql':
 140     user          => $nova_dsn[3],
 141     password      => $nova_dsn[4],
 142     host          => $nova_dsn[5],
 143     dbname        => $nova_dsn[6],
 144     allowed_hosts => $allowed_hosts,
 145   }
 146   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 147   class { 'neutron::db::mysql':
 148     user          => $neutron_dsn[3],
 149     password      => $neutron_dsn[4],
 150     host          => $neutron_dsn[5],
 151     dbname        => $neutron_dsn[6],
 152     allowed_hosts => $allowed_hosts,
 153   }
 154   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 155   class { 'cinder::db::mysql':
 156     user          => $cinder_dsn[3],
 157     password      => $cinder_dsn[4],
 158     host          => $cinder_dsn[5],
 159     dbname        => $cinder_dsn[6],
 160     allowed_hosts => $allowed_hosts,
 161   }
 162   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 163   class { 'heat::db::mysql':
 164     user          => $heat_dsn[3],
 165     password      => $heat_dsn[4],
 166     host          => $heat_dsn[5],
 167     dbname        => $heat_dsn[6],
 168     allowed_hosts => $allowed_hosts,
 169   }
 170
 171   $rabbit_nodes = split(downcase(hiera('rabbit_node_names', $::hostname)), ',')
 172   if count($rabbit_nodes) > 1 {
 173     $rabbit_cluster = true
 174   }
 175   else {
 176     $rabbit_cluster = false
 177   }
 178   class { 'rabbitmq':
 179     config_cluster   => $rabbit_cluster,
 180     cluster_nodes    => $rabbit_nodes,
 181     node_ip_address  => hiera('controller_host'),
 182   }
 183   if $rabbit_cluster {
 184     rabbitmq_policy { 'ha-all@/':
 185       pattern    => '^(?!amq\.).*',
 186       definition => {
 187         'ha-mode'      => 'all',
 188         'ha-sync-mode' => 'automatic',
 189       },
 190     }
 191   }
 192   rabbitmq_vhost { '/':
 193     provider => 'rabbitmqctl',
 194   }
 195
 196   # pre-install swift here so we can build rings
 197   include ::swift
 198
 199   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 200   $enable_ceph = $cinder_enable_rbd_backend
 201
 202   if $enable_ceph {
 203     class { 'ceph::profile::params':
 204       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 205     }
 206     include ::ceph::profile::mon
 207   }
 208
 209   if str2bool(hiera('enable_ceph_storage', 'false')) {
 210     include ::ceph::profile::client
 211     include ::ceph::profile::osd
 212   }
 213
 214 } #END STEP 2
 215
 216 if hiera('step') >= 3 {
 217
 218   include ::keystone
 219
 220   #TODO: need a cleanup-keystone-tokens.sh solution here
 221   keystone_config {
 222     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 223   }
 224   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 225     ensure  => 'directory',
 226     owner   => 'keystone',
 227     group   => 'keystone',
 228     require => Package['keystone'],
 229   }
 230   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 231     content => hiera('keystone_signing_certificate'),
 232     owner   => 'keystone',
 233     group   => 'keystone',
 234     notify  => Service['keystone'],
 235     require => File['/etc/keystone/ssl/certs'],
 236   }
 237   file { '/etc/keystone/ssl/private/signing_key.pem':
 238     content => hiera('keystone_signing_key'),
 239     owner   => 'keystone',
 240     group   => 'keystone',
 241     notify  => Service['keystone'],
 242     require => File['/etc/keystone/ssl/private'],
 243   }
 244   file { '/etc/keystone/ssl/certs/ca.pem':
 245     content => hiera('keystone_ca_certificate'),
 246     owner   => 'keystone',
 247     group   => 'keystone',
 248     notify  => Service['keystone'],
 249     require => File['/etc/keystone/ssl/certs'],
 250   }
 251
 252   # TODO: notifications, scrubber, etc.
 253   include ::glance
 254   include ::glance::api
 255   include ::glance::registry
 256   include ::glance::backend::swift
 257
 258   class { 'nova':
 259     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 260   }
 261
 262   include ::nova::api
 263   include ::nova::cert
 264   include ::nova::conductor
 265   include ::nova::consoleauth
 266   include ::nova::network::neutron
 267   include ::nova::vncproxy
 268   include ::nova::scheduler
 269
 270   include ::neutron
 271   include ::neutron::server
 272   include ::neutron::agents::dhcp
 273   include ::neutron::agents::l3
 274
 275   file { '/etc/neutron/dnsmasq-neutron.conf':
 276     content => hiera('neutron_dnsmasq_options'),
 277     owner   => 'neutron',
 278     group   => 'neutron',
 279     notify  => Service['neutron-dhcp-service'],
 280     require => Package['neutron'],
 281   }
 282
 283   class { 'neutron::plugins::ml2':
 284     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 285     tenant_network_types => [hiera('neutron_tenant_network_type')],
 286     type_drivers         => [hiera('neutron_tenant_network_type')],
 287   }
 288
 289   class { 'neutron::agents::ml2::ovs':
 290     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 291     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 292   }
 293
 294   class { 'neutron::agents::metadata':
 295     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 296   }
 297
 298   Service['neutron-server'] -> Service['neutron-dhcp-service']
 299   Service['neutron-server'] -> Service['neutron-l3']
 300   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 301   Service['neutron-server'] -> Service['neutron-metadata']
 302
 303   include ::cinder
 304   include ::cinder::api
 305   include ::cinder::glance
 306   include ::cinder::scheduler
 307   include ::cinder::volume
 308   class {'cinder::setup_test_volume':
 309     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 310   }
 311
 312   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 313   if $cinder_enable_iscsi {
 314     $cinder_iscsi_backend = 'tripleo_iscsi'
 315
 316     cinder::backend::iscsi { $cinder_iscsi_backend :
 317       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 318       iscsi_helper     => hiera('cinder_iscsi_helper'),
 319     }
 320   }
 321
 322   if $enable_ceph {
 323
 324     Ceph_pool {
 325       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 326       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 327       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 328     }
 329
 330     $ceph_pools = hiera('ceph_pools')
 331     ceph::pool { $ceph_pools : }
 332   }
 333
 334   if $cinder_enable_rbd_backend {
 335     $cinder_rbd_backend = 'tripleo_ceph'
 336
 337     cinder_config {
 338       "${cinder_rbd_backend}/host": value => 'hostgroup';
 339     }
 340
 341     cinder::backend::rbd { $cinder_rbd_backend :
 342       rbd_pool        => 'volumes',
 343       rbd_user        => 'openstack',
 344       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 345       require         => Ceph::Pool['volumes'],
 346     }
 347   }
 348
 349   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 350   class { '::cinder::backends' :
 351     enabled_backends => $cinder_enabled_backends,
 352   }
 353
 354   # swift proxy
 355   include ::memcached
 356   include ::swift::proxy
 357   include ::swift::proxy::proxy_logging
 358   include ::swift::proxy::healthcheck
 359   include ::swift::proxy::cache
 360   include ::swift::proxy::keystone
 361   include ::swift::proxy::authtoken
 362   include ::swift::proxy::staticweb
 363   include ::swift::proxy::ceilometer
 364   include ::swift::proxy::ratelimit
 365   include ::swift::proxy::catch_errors
 366   include ::swift::proxy::tempurl
 367   include ::swift::proxy::formpost
 368
 369   # swift storage
 370   if str2bool(hiera('enable_swift_storage', 'true')) {
 371     class {'swift::storage::all':
 372       mount_check => str2bool(hiera('swift_mount_check'))
 373     }
 374     if(!defined(File['/srv/node'])) {
 375       file { '/srv/node':
 376         ensure  => directory,
 377         owner   => 'swift',
 378         group   => 'swift',
 379         require => Package['openstack-swift'],
 380       }
 381     }
 382     $swift_components = ['account', 'container', 'object']
 383     swift::storage::filter::recon { $swift_components : }
 384     swift::storage::filter::healthcheck { $swift_components : }
 385   }
 386
 387   # Ceilometer
 388   include ::ceilometer
 389   include ::ceilometer::api
 390   include ::ceilometer::agent::notification
 391   include ::ceilometer::agent::central
 392   include ::ceilometer::alarm::notifier
 393   include ::ceilometer::alarm::evaluator
 394   include ::ceilometer::expirer
 395   include ::ceilometer::collector
 396   class { '::ceilometer::db' :
 397     database_connection => $ceilometer_mongodb_conn_string,
 398   }
 399   class { 'ceilometer::agent::auth':
 400     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 401   }
 402
 403   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 404
 405   # Heat
 406   include ::heat
 407   include ::heat::api
 408   include ::heat::api_cfn
 409   include ::heat::api_cloudwatch
 410   include ::heat::engine
 411
 412   $snmpd_user = hiera('snmpd_readonly_user_name')
 413   snmp::snmpv3_user { $snmpd_user:
 414     authtype => 'MD5',
 415     authpass => hiera('snmpd_readonly_user_password'),
 416   }
 417   class { 'snmp':
 418     agentaddress => ['udp:161','udp6:[::1]:161'],
 419     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 420   }
 421
 422 } #END STEP 3