puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if hiera('step') >= 1 {
  28
  29   $controller_node_ips = split(hiera('controller_node_ips'), ',')
  30
  31   class { '::tripleo::loadbalancer' :
  32     controller_hosts => $controller_node_ips,
  33     manage_vip       => true,
  34   }
  35
  36 }
  37
  38 if hiera('step') >= 2 {
  39
  40   if count(hiera('ntp::servers')) > 0 {
  41     include ::ntp
  42   }
  43
  44   # MongoDB
  45   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  46     include ::mongodb::globals
  47
  48     include ::mongodb::server
  49     $mongo_node_ips = split(hiera('mongo_node_ips'), ',')
  50     $mongo_node_ips_with_port = suffix($mongo_node_ips, ':27017')
  51     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  52
  53     $mongodb_replset = hiera('mongodb::server::replset')
  54     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  55     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  56       mongodb_replset { $mongodb_replset :
  57         members => $mongo_node_ips_with_port,
  58       }
  59     }
  60   }
  61
  62   # Redis
  63   $redis_node_ips = split(hiera('redis_node_ips'), ',')
  64   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  65
  66   if $redis_master_hostname == $::hostname {
  67     $slaveof = undef
  68   } else {
  69     $slaveof = "${redis_master_hostname} 6379"
  70   }
  71   class {'::redis' :
  72     slaveof => $slaveof,
  73   }
  74
  75   if count($redis_node_ips) > 1 {
  76     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  77     include ::redis::sentinel
  78     class {'::tripleo::redis_notification' :
  79       haproxy_monitor_ip => hiera('tripleo::loadbalancer::controller_virtual_ip'),
  80     }
  81   }
  82
  83   if str2bool(hiera('enable_galera', 'true')) {
  84     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  85   } else {
  86     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  87   }
  88   # TODO Galara
  89   class { 'mysql::server':
  90     config_file => $mysql_config_file,
  91     override_options => {
  92       'mysqld' => {
  93         'bind-address' => hiera('controller_host'),
  94         'max_connections' => '1024',
  95         'open_files_limit' => '-1',
  96       },
  97     }
  98   }
  99
 100   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 101   # Create all the database schemas
 102   # Example DSN format: mysql://user:password@host/dbname
 103   $allowed_hosts = ['%',hiera('controller_host')]
 104   $keystone_dsn = split(hiera('keystone::database_connection'), '[@:/?]')
 105   class { 'keystone::db::mysql':
 106     user          => $keystone_dsn[3],
 107     password      => $keystone_dsn[4],
 108     host          => $keystone_dsn[5],
 109     dbname        => $keystone_dsn[6],
 110     allowed_hosts => $allowed_hosts,
 111   }
 112   $glance_dsn = split(hiera('glance::api::database_connection'), '[@:/?]')
 113   class { 'glance::db::mysql':
 114     user          => $glance_dsn[3],
 115     password      => $glance_dsn[4],
 116     host          => $glance_dsn[5],
 117     dbname        => $glance_dsn[6],
 118     allowed_hosts => $allowed_hosts,
 119   }
 120   $nova_dsn = split(hiera('nova::database_connection'), '[@:/?]')
 121   class { 'nova::db::mysql':
 122     user          => $nova_dsn[3],
 123     password      => $nova_dsn[4],
 124     host          => $nova_dsn[5],
 125     dbname        => $nova_dsn[6],
 126     allowed_hosts => $allowed_hosts,
 127   }
 128   $neutron_dsn = split(hiera('neutron::server::database_connection'), '[@:/?]')
 129   class { 'neutron::db::mysql':
 130     user          => $neutron_dsn[3],
 131     password      => $neutron_dsn[4],
 132     host          => $neutron_dsn[5],
 133     dbname        => $neutron_dsn[6],
 134     allowed_hosts => $allowed_hosts,
 135   }
 136   $cinder_dsn = split(hiera('cinder::database_connection'), '[@:/?]')
 137   class { 'cinder::db::mysql':
 138     user          => $cinder_dsn[3],
 139     password      => $cinder_dsn[4],
 140     host          => $cinder_dsn[5],
 141     dbname        => $cinder_dsn[6],
 142     allowed_hosts => $allowed_hosts,
 143   }
 144   $heat_dsn = split(hiera('heat::database_connection'), '[@:/?]')
 145   class { 'heat::db::mysql':
 146     user          => $heat_dsn[3],
 147     password      => $heat_dsn[4],
 148     host          => $heat_dsn[5],
 149     dbname        => $heat_dsn[6],
 150     allowed_hosts => $allowed_hosts,
 151   }
 152   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 153     $ceilometer_dsn = split(hiera('ceilometer_mysql_conn_string'), '[@:/?]')
 154     class { 'ceilometer::db::mysql':
 155       user          => $ceilometer_dsn[3],
 156       password      => $ceilometer_dsn[4],
 157       host          => $ceilometer_dsn[5],
 158       dbname        => $ceilometer_dsn[6],
 159       allowed_hosts => $allowed_hosts,
 160     }
 161   }
 162
 163   $rabbit_nodes = hiera('rabbit_node_ips')
 164   if count($rabbit_nodes) > 1 {
 165     class { '::rabbitmq':
 166       config_cluster          => true,
 167       cluster_nodes           => $rabbit_nodes,
 168       tcp_keepalive           => false,
 169       config_kernel_variables => hiera('rabbitmq_kernel_variables'),
 170       config_variables        => hiera('rabbitmq_config_variables'),
 171       environment_variables   => hiera('rabbitmq_environment'),
 172     }
 173     rabbitmq_policy { 'ha-all@/':
 174       pattern    => '^(?!amq\.).*',
 175       definition => {
 176         'ha-mode' => 'all',
 177       },
 178     }
 179   } else {
 180     include ::rabbitmq
 181   }
 182
 183   # pre-install swift here so we can build rings
 184   include ::swift
 185
 186   $cinder_enable_rbd_backend = hiera('cinder_enable_rbd_backend', false)
 187   $enable_ceph = $cinder_enable_rbd_backend
 188
 189   if $enable_ceph {
 190     class { 'ceph::profile::params':
 191       mon_initial_members => downcase(hiera('ceph_mon_initial_members'))
 192     }
 193     include ::ceph::profile::mon
 194   }
 195
 196   if str2bool(hiera('enable_ceph_storage', 'false')) {
 197     include ::ceph::profile::client
 198     include ::ceph::profile::osd
 199   }
 200
 201 } #END STEP 2
 202
 203 if hiera('step') >= 3 {
 204
 205   include ::keystone
 206
 207   #TODO: need a cleanup-keystone-tokens.sh solution here
 208   keystone_config {
 209     'ec2/driver': value => 'keystone.contrib.ec2.backends.sql.Ec2';
 210   }
 211   file { [ '/etc/keystone/ssl', '/etc/keystone/ssl/certs', '/etc/keystone/ssl/private' ]:
 212     ensure  => 'directory',
 213     owner   => 'keystone',
 214     group   => 'keystone',
 215     require => Package['keystone'],
 216   }
 217   file { '/etc/keystone/ssl/certs/signing_cert.pem':
 218     content => hiera('keystone_signing_certificate'),
 219     owner   => 'keystone',
 220     group   => 'keystone',
 221     notify  => Service['keystone'],
 222     require => File['/etc/keystone/ssl/certs'],
 223   }
 224   file { '/etc/keystone/ssl/private/signing_key.pem':
 225     content => hiera('keystone_signing_key'),
 226     owner   => 'keystone',
 227     group   => 'keystone',
 228     notify  => Service['keystone'],
 229     require => File['/etc/keystone/ssl/private'],
 230   }
 231   file { '/etc/keystone/ssl/certs/ca.pem':
 232     content => hiera('keystone_ca_certificate'),
 233     owner   => 'keystone',
 234     group   => 'keystone',
 235     notify  => Service['keystone'],
 236     require => File['/etc/keystone/ssl/certs'],
 237   }
 238
 239   $glance_backend = downcase(hiera('glance_backend', 'swift'))
 240   case $glance_backend {
 241       swift: { $glance_store = 'glance.store.swift.Store' }
 242       file: { $glance_store = 'glance.store.filesystem.Store' }
 243       rbd: { $glance_store = 'glance.store.rbd.Store' }
 244       default: { fail('Unrecognized glance_backend parameter.') }
 245   }
 246
 247   # TODO: notifications, scrubber, etc.
 248   include ::glance
 249   class { 'glance::api':
 250     known_stores => [$glance_store]
 251   }
 252   include ::glance::registry
 253   include join(['::glance::backend::', $glance_backend])
 254
 255   class { 'nova':
 256     glance_api_servers     => join([hiera('glance_protocol'), '://', hiera('controller_virtual_ip'), ':', hiera('glance_port')]),
 257   }
 258
 259   include ::nova::api
 260   include ::nova::cert
 261   include ::nova::conductor
 262   include ::nova::consoleauth
 263   include ::nova::network::neutron
 264   include ::nova::vncproxy
 265   include ::nova::scheduler
 266
 267   include ::neutron
 268   include ::neutron::server
 269   include ::neutron::agents::dhcp
 270   include ::neutron::agents::l3
 271
 272   file { '/etc/neutron/dnsmasq-neutron.conf':
 273     content => hiera('neutron_dnsmasq_options'),
 274     owner   => 'neutron',
 275     group   => 'neutron',
 276     notify  => Service['neutron-dhcp-service'],
 277     require => Package['neutron'],
 278   }
 279
 280   class { 'neutron::plugins::ml2':
 281     flat_networks        => split(hiera('neutron_flat_networks'), ','),
 282     tenant_network_types => [hiera('neutron_tenant_network_type')],
 283     type_drivers         => [hiera('neutron_tenant_network_type')],
 284   }
 285
 286   class { 'neutron::agents::ml2::ovs':
 287     bridge_mappings  => split(hiera('neutron_bridge_mappings'), ','),
 288     tunnel_types     => split(hiera('neutron_tunnel_types'), ','),
 289   }
 290
 291   class { 'neutron::agents::metadata':
 292     auth_url => join(['http://', hiera('controller_virtual_ip'), ':35357/v2.0']),
 293   }
 294
 295   Service['neutron-server'] -> Service['neutron-dhcp-service']
 296   Service['neutron-server'] -> Service['neutron-l3']
 297   Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 298   Service['neutron-server'] -> Service['neutron-metadata']
 299
 300   include ::cinder
 301   include ::cinder::api
 302   include ::cinder::glance
 303   include ::cinder::scheduler
 304   include ::cinder::volume
 305   class {'cinder::setup_test_volume':
 306     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 307   }
 308
 309   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 310   if $cinder_enable_iscsi {
 311     $cinder_iscsi_backend = 'tripleo_iscsi'
 312
 313     cinder::backend::iscsi { $cinder_iscsi_backend :
 314       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 315       iscsi_helper     => hiera('cinder_iscsi_helper'),
 316     }
 317   }
 318
 319   if $enable_ceph {
 320
 321     Ceph_pool {
 322       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 323       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 324       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 325     }
 326
 327     $ceph_pools = hiera('ceph_pools')
 328     ceph::pool { $ceph_pools : }
 329   }
 330
 331   if $cinder_enable_rbd_backend {
 332     $cinder_rbd_backend = 'tripleo_ceph'
 333
 334     cinder_config {
 335       "${cinder_rbd_backend}/host": value => 'hostgroup';
 336     }
 337
 338     cinder::backend::rbd { $cinder_rbd_backend :
 339       rbd_pool        => 'volumes',
 340       rbd_user        => 'openstack',
 341       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 342       require         => Ceph::Pool['volumes'],
 343     }
 344   }
 345
 346   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend])
 347   class { '::cinder::backends' :
 348     enabled_backends => $cinder_enabled_backends,
 349   }
 350
 351   # swift proxy
 352   include ::memcached
 353   include ::swift::proxy
 354   include ::swift::proxy::proxy_logging
 355   include ::swift::proxy::healthcheck
 356   include ::swift::proxy::cache
 357   include ::swift::proxy::keystone
 358   include ::swift::proxy::authtoken
 359   include ::swift::proxy::staticweb
 360   include ::swift::proxy::ceilometer
 361   include ::swift::proxy::ratelimit
 362   include ::swift::proxy::catch_errors
 363   include ::swift::proxy::tempurl
 364   include ::swift::proxy::formpost
 365
 366   # swift storage
 367   if str2bool(hiera('enable_swift_storage', 'true')) {
 368     class {'swift::storage::all':
 369       mount_check => str2bool(hiera('swift_mount_check'))
 370     }
 371     if(!defined(File['/srv/node'])) {
 372       file { '/srv/node':
 373         ensure  => directory,
 374         owner   => 'swift',
 375         group   => 'swift',
 376         require => Package['openstack-swift'],
 377       }
 378     }
 379     $swift_components = ['account', 'container', 'object']
 380     swift::storage::filter::recon { $swift_components : }
 381     swift::storage::filter::healthcheck { $swift_components : }
 382   }
 383
 384   # Ceilometer
 385   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 386   case $ceilometer_backend {
 387     /mysql/ : {
 388       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 389     }
 390     default : {
 391       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 392     }
 393   }
 394   include ::ceilometer
 395   include ::ceilometer::api
 396   include ::ceilometer::agent::notification
 397   include ::ceilometer::agent::central
 398   include ::ceilometer::alarm::notifier
 399   include ::ceilometer::alarm::evaluator
 400   include ::ceilometer::expirer
 401   include ::ceilometer::collector
 402   class { '::ceilometer::db' :
 403     database_connection => $ceilometer_database_connection,
 404   }
 405   class { 'ceilometer::agent::auth':
 406     auth_url => join(['http://', hiera('controller_virtual_ip'), ':5000/v2.0']),
 407   }
 408
 409   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 410
 411   # Heat
 412   include ::heat
 413   include ::heat::api
 414   include ::heat::api_cfn
 415   include ::heat::api_cloudwatch
 416   include ::heat::engine
 417
 418   # Horizon
 419   $vhost_params = { add_listen => false }
 420   class { 'horizon':
 421     cache_server_ip    => split(hiera('memcache_node_ips', '127.0.0.1'), ','),
 422     vhost_extra_params => $vhost_params,
 423   }
 424
 425   $snmpd_user = hiera('snmpd_readonly_user_name')
 426   snmp::snmpv3_user { $snmpd_user:
 427     authtype => 'MD5',
 428     authpass => hiera('snmpd_readonly_user_password'),
 429   }
 430   class { 'snmp':
 431     agentaddress => ['udp:161','udp6:[::1]:161'],
 432     snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 433   }
 434
 435 } #END STEP 3