puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27 }
  28
  29 if hiera('step') >= 2 {
  30
  31   if count(hiera('ntp::servers')) > 0 {
  32     include ::ntp
  33   }
  34
  35   include ::timezone
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40     include ::mongodb::client
  41     include ::mongodb::server
  42     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  43     # without the brackets as 'members' argument for the 'mongodb_replset'
  44     # resource.
  45     if str2bool(hiera('mongodb::server::ipv6', false)) {
  46       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  47       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  48       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  49     } else {
  50       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  51       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  52     }
  53     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  54
  55     $mongodb_replset = hiera('mongodb::server::replset')
  56     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  57     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  58       mongodb_replset { $mongodb_replset :
  59         members => $mongo_node_ips_with_port_nobr,
  60       }
  61     }
  62   }
  63
  64   # Redis
  65   $redis_node_ips = hiera('redis_node_ips')
  66   $redis_master_hostname = downcase(hiera('bootstrap_nodeid'))
  67
  68   if $redis_master_hostname == $::hostname {
  69     $slaveof = undef
  70   } else {
  71     $slaveof = "${redis_master_hostname} 6379"
  72   }
  73   class {'::redis' :
  74     slaveof => $slaveof,
  75   }
  76
  77   if count($redis_node_ips) > 1 {
  78     Class['::tripleo::redis_notification'] -> Service['redis-sentinel']
  79     include ::redis::sentinel
  80     include ::tripleo::redis_notification
  81   }
  82
  83   if str2bool(hiera('enable_galera', true)) {
  84     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  85   } else {
  86     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  87   }
  88   # TODO Galara
  89   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  90   # set bind-address to a hostname instead of an ip address; to move Mysql
  91   # from internal_api on another network we'll have to customize both
  92   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  93   class { '::mysql::server':
  94     config_file             => $mysql_config_file,
  95     override_options        => {
  96       'mysqld' => {
  97         'bind-address'     => $::hostname,
  98         'max_connections'  => hiera('mysql_max_connections'),
  99         'open_files_limit' => '-1',
 100       },
 101     },
 102     remove_default_accounts => true,
 103   }
 104
 105   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
 106   # Create all the database schemas
 107   include ::nova::db::mysql
 108   include ::nova::db::mysql_api
 109   include ::neutron::db::mysql
 110   include ::cinder::db::mysql
 111   include ::sahara::db::mysql
 112   if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
 113     include ::gnocchi::db::mysql
 114   }
 115   if downcase(hiera('ceilometer_backend')) == 'mysql' {
 116     include ::ceilometer::db::mysql
 117     include ::aodh::db::mysql
 118   }
 119
 120   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
 121
 122   if $enable_ceph {
 123     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 124     if str2bool(hiera('ceph_ipv6', false)) {
 125       $mon_host = hiera('ceph_mon_host_v6')
 126     } else {
 127       $mon_host = hiera('ceph_mon_host')
 128     }
 129     class { '::ceph::profile::params':
 130       mon_initial_members => $mon_initial_members,
 131       mon_host            => $mon_host,
 132     }
 133     include ::ceph::conf
 134     include ::ceph::profile::mon
 135   }
 136
 137   if str2bool(hiera('enable_ceph_storage', false)) {
 138     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 139       exec { 'set selinux to permissive on boot':
 140         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 141         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 142         path    => ['/usr/bin', '/usr/sbin'],
 143       }
 144
 145       exec { 'set selinux to permissive':
 146         command => 'setenforce 0',
 147         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 148         path    => ['/usr/bin', '/usr/sbin'],
 149       } -> Class['ceph::profile::osd']
 150     }
 151
 152     include ::ceph::conf
 153     include ::ceph::profile::osd
 154   }
 155
 156   if str2bool(hiera('enable_external_ceph', false)) {
 157     if str2bool(hiera('ceph_ipv6', false)) {
 158       $mon_host = hiera('ceph_mon_host_v6')
 159     } else {
 160       $mon_host = hiera('ceph_mon_host')
 161     }
 162     class { '::ceph::profile::params':
 163       mon_host            => $mon_host,
 164     }
 165     include ::ceph::conf
 166     include ::ceph::profile::client
 167   }
 168
 169 } #END STEP 2
 170
 171 if hiera('step') >= 4 {
 172
 173   $nova_ipv6 = hiera('nova::use_ipv6', false)
 174   if $nova_ipv6 {
 175     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 176   } else {
 177     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 178   }
 179
 180   class { '::nova' :
 181     memcached_servers => $memcached_servers
 182   }
 183   include ::nova::config
 184   include ::nova::api
 185   include ::nova::cert
 186   include ::nova::conductor
 187   include ::nova::consoleauth
 188   include ::nova::network::neutron
 189   include ::nova::vncproxy
 190   include ::nova::scheduler
 191   include ::nova::scheduler::filter
 192
 193   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 194
 195     # TODO(devvesa) provide non-controller ips for these services
 196     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 197     $cassandra_node_ips = hiera('neutron_api_node_ips')
 198
 199     # Run zookeeper in the controller if configured
 200     if hiera('enable_zookeeper_on_controller') {
 201       class {'::tripleo::cluster::zookeeper':
 202         zookeeper_server_ips => $zookeeper_node_ips,
 203         # TODO: create a 'bind' hiera key for zookeeper
 204         zookeeper_client_ip  => hiera('neutron::bind_host'),
 205         zookeeper_hostnames  => hiera('controller_node_names')
 206       }
 207     }
 208
 209     # Run cassandra in the controller if configured
 210     if hiera('enable_cassandra_on_controller') {
 211       class {'::tripleo::cluster::cassandra':
 212         cassandra_servers => $cassandra_node_ips,
 213         # TODO: create a 'bind' hiera key for cassandra
 214         cassandra_ip      => hiera('neutron::bind_host'),
 215       }
 216     }
 217
 218     class {'::tripleo::network::midonet::agent':
 219       zookeeper_servers => $zookeeper_node_ips,
 220       cassandra_seeds   => $cassandra_node_ips
 221     }
 222
 223     class {'::tripleo::network::midonet::api':
 224       zookeeper_servers    => $zookeeper_node_ips,
 225       vip                  => hiera('public_virtual_ip'),
 226       keystone_ip          => hiera('public_virtual_ip'),
 227       keystone_admin_token => hiera('keystone::admin_token'),
 228       # TODO: create a 'bind' hiera key for api
 229       bind_address         => hiera('neutron::bind_host'),
 230       admin_password       => hiera('admin_password')
 231     }
 232
 233     # TODO: find a way to get an empty list from hiera
 234     class {'::neutron':
 235       service_plugins => []
 236     }
 237
 238   }
 239   else {
 240
 241     # ML2 plugin
 242     include ::neutron
 243   }
 244
 245   include ::neutron::config
 246   include ::neutron::server
 247   include ::neutron::server::notifications
 248
 249   # If the value of core plugin is set to 'nuage' or'opencontrail' or 'plumgrid',
 250   # include nuage or opencontrail or plumgrid core plugins
 251   # else use the default value of 'ml2'
 252   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 253     include ::neutron::plugins::nuage
 254   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 255     include ::neutron::plugins::opencontrail
 256   }
 257   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 258     class { '::neutron::plugins::plumgrid' :
 259       connection                   => hiera('neutron::server::database_connection'),
 260       controller_priv_host         => hiera('keystone_admin_api_vip'),
 261       admin_password               => hiera('admin_password'),
 262       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 263     }
 264   } else {
 265
 266     # If the value of core plugin is set to 'midonet',
 267     # skip all the ML2 configuration
 268     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 269
 270       class {'::neutron::plugins::midonet':
 271         midonet_api_ip    => hiera('public_virtual_ip'),
 272         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 273         keystone_password => hiera('neutron::server::password')
 274       }
 275     } else {
 276
 277       include ::neutron::plugins::ml2
 278       include ::neutron::agents::ml2::ovs
 279
 280       if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 281         include ::neutron::plugins::ml2::cisco::nexus1000v
 282
 283         class { '::neutron::agents::n1kv_vem':
 284           n1kv_source  => hiera('n1kv_vem_source', undef),
 285           n1kv_version => hiera('n1kv_vem_version', undef),
 286         }
 287
 288         class { '::n1k_vsm':
 289           n1kv_source       => hiera('n1kv_vsm_source', undef),
 290           n1kv_version      => hiera('n1kv_vsm_version', undef),
 291           pacemaker_control => false,
 292         }
 293       }
 294
 295       if 'cisco_ucsm' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 296         include ::neutron::plugins::ml2::cisco::ucsm
 297       }
 298       if 'cisco_nexus' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 299         include ::neutron::plugins::ml2::cisco::nexus
 300         include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
 301       }
 302
 303       if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 304         include ::neutron::plugins::ml2::bigswitch::restproxy
 305         include ::neutron::agents::bigswitch
 306       }
 307       Service['neutron-server'] -> Service['neutron-ovs-agent-service']
 308     }
 309
 310     Service['neutron-server'] -> Service['neutron-metadata']
 311   }
 312
 313   include ::cinder
 314   include ::cinder::config
 315   include ::cinder::api
 316   include ::cinder::glance
 317   include ::cinder::scheduler
 318   include ::cinder::volume
 319   include ::cinder::ceilometer
 320   class { '::cinder::setup_test_volume':
 321     size => join([hiera('cinder_lvm_loop_device_size'), 'M']),
 322   }
 323
 324   $cinder_enable_iscsi = hiera('cinder_enable_iscsi_backend', true)
 325   if $cinder_enable_iscsi {
 326     $cinder_iscsi_backend = 'tripleo_iscsi'
 327
 328     cinder::backend::iscsi { $cinder_iscsi_backend :
 329       iscsi_ip_address => hiera('cinder_iscsi_ip_address'),
 330       iscsi_helper     => hiera('cinder_iscsi_helper'),
 331     }
 332   }
 333
 334   if $enable_ceph {
 335
 336     $ceph_pools = hiera('ceph_pools')
 337     ceph::pool { $ceph_pools :
 338       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 339       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 340       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 341     }
 342
 343     $cinder_pool_requires = [Ceph::Pool[hiera('cinder_rbd_pool_name')]]
 344
 345   } else {
 346     $cinder_pool_requires = []
 347   }
 348
 349   if hiera('cinder_enable_rbd_backend', false) {
 350     $cinder_rbd_backend = 'tripleo_ceph'
 351
 352     cinder::backend::rbd { $cinder_rbd_backend :
 353       backend_host    => hiera('cinder::host'),
 354       rbd_pool        => hiera('cinder_rbd_pool_name'),
 355       rbd_user        => hiera('ceph_client_user_name'),
 356       rbd_secret_uuid => hiera('ceph::profile::params::fsid'),
 357       require         => $cinder_pool_requires,
 358     }
 359   }
 360
 361   if hiera('cinder_enable_eqlx_backend', false) {
 362     $cinder_eqlx_backend = hiera('cinder::backend::eqlx::volume_backend_name')
 363
 364     cinder::backend::eqlx { $cinder_eqlx_backend :
 365       volume_backend_name => hiera('cinder::backend::eqlx::volume_backend_name', undef),
 366       san_ip              => hiera('cinder::backend::eqlx::san_ip', undef),
 367       san_login           => hiera('cinder::backend::eqlx::san_login', undef),
 368       san_password        => hiera('cinder::backend::eqlx::san_password', undef),
 369       san_thin_provision  => hiera('cinder::backend::eqlx::san_thin_provision', undef),
 370       eqlx_group_name     => hiera('cinder::backend::eqlx::eqlx_group_name', undef),
 371       eqlx_pool           => hiera('cinder::backend::eqlx::eqlx_pool', undef),
 372       eqlx_use_chap       => hiera('cinder::backend::eqlx::eqlx_use_chap', undef),
 373       eqlx_chap_login     => hiera('cinder::backend::eqlx::eqlx_chap_login', undef),
 374       eqlx_chap_password  => hiera('cinder::backend::eqlx::eqlx_san_password', undef),
 375     }
 376   }
 377
 378   if hiera('cinder_enable_dellsc_backend', false) {
 379     $cinder_dellsc_backend = hiera('cinder::backend::dellsc_iscsi::volume_backend_name')
 380
 381     cinder::backend::dellsc_iscsi{ $cinder_dellsc_backend :
 382       volume_backend_name   => hiera('cinder::backend::dellsc_iscsi::volume_backend_name', undef),
 383       san_ip                => hiera('cinder::backend::dellsc_iscsi::san_ip', undef),
 384       san_login             => hiera('cinder::backend::dellsc_iscsi::san_login', undef),
 385       san_password          => hiera('cinder::backend::dellsc_iscsi::san_password', undef),
 386       dell_sc_ssn           => hiera('cinder::backend::dellsc_iscsi::dell_sc_ssn', undef),
 387       iscsi_ip_address      => hiera('cinder::backend::dellsc_iscsi::iscsi_ip_address', undef),
 388       iscsi_port            => hiera('cinder::backend::dellsc_iscsi::iscsi_port', undef),
 389       dell_sc_api_port      => hiera('cinder::backend::dellsc_iscsi::dell_sc_api_port', undef),
 390       dell_sc_server_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_server_folder', undef),
 391       dell_sc_volume_folder => hiera('cinder::backend::dellsc_iscsi::dell_sc_volume_folder', undef),
 392     }
 393   }
 394
 395   if hiera('cinder_enable_netapp_backend', false) {
 396     $cinder_netapp_backend = hiera('cinder::backend::netapp::title')
 397
 398     if hiera('cinder::backend::netapp::nfs_shares', undef) {
 399       $cinder_netapp_nfs_shares = split(hiera('cinder::backend::netapp::nfs_shares', undef), ',')
 400     }
 401
 402     cinder::backend::netapp { $cinder_netapp_backend :
 403       netapp_login                 => hiera('cinder::backend::netapp::netapp_login', undef),
 404       netapp_password              => hiera('cinder::backend::netapp::netapp_password', undef),
 405       netapp_server_hostname       => hiera('cinder::backend::netapp::netapp_server_hostname', undef),
 406       netapp_server_port           => hiera('cinder::backend::netapp::netapp_server_port', undef),
 407       netapp_size_multiplier       => hiera('cinder::backend::netapp::netapp_size_multiplier', undef),
 408       netapp_storage_family        => hiera('cinder::backend::netapp::netapp_storage_family', undef),
 409       netapp_storage_protocol      => hiera('cinder::backend::netapp::netapp_storage_protocol', undef),
 410       netapp_transport_type        => hiera('cinder::backend::netapp::netapp_transport_type', undef),
 411       netapp_vfiler                => hiera('cinder::backend::netapp::netapp_vfiler', undef),
 412       netapp_volume_list           => hiera('cinder::backend::netapp::netapp_volume_list', undef),
 413       netapp_vserver               => hiera('cinder::backend::netapp::netapp_vserver', undef),
 414       netapp_partner_backend_name  => hiera('cinder::backend::netapp::netapp_partner_backend_name', undef),
 415       nfs_shares                   => $cinder_netapp_nfs_shares,
 416       nfs_shares_config            => hiera('cinder::backend::netapp::nfs_shares_config', undef),
 417       netapp_copyoffload_tool_path => hiera('cinder::backend::netapp::netapp_copyoffload_tool_path', undef),
 418       netapp_controller_ips        => hiera('cinder::backend::netapp::netapp_controller_ips', undef),
 419       netapp_sa_password           => hiera('cinder::backend::netapp::netapp_sa_password', undef),
 420       netapp_storage_pools         => hiera('cinder::backend::netapp::netapp_storage_pools', undef),
 421       netapp_eseries_host_type     => hiera('cinder::backend::netapp::netapp_eseries_host_type', undef),
 422       netapp_webservice_path       => hiera('cinder::backend::netapp::netapp_webservice_path', undef),
 423     }
 424   }
 425
 426   if hiera('cinder_enable_nfs_backend', false) {
 427     $cinder_nfs_backend = 'tripleo_nfs'
 428
 429     if str2bool($::selinux) {
 430       selboolean { 'virt_use_nfs':
 431         value      => on,
 432         persistent => true,
 433       } -> Package['nfs-utils']
 434     }
 435
 436     package {'nfs-utils': } ->
 437     cinder::backend::nfs { $cinder_nfs_backend :
 438       nfs_servers       => hiera('cinder_nfs_servers'),
 439       nfs_mount_options => hiera('cinder_nfs_mount_options',''),
 440       nfs_shares_config => '/etc/cinder/shares-nfs.conf',
 441     }
 442   }
 443
 444   $cinder_enabled_backends = delete_undef_values([$cinder_iscsi_backend, $cinder_rbd_backend, $cinder_eqlx_backend, $cinder_dellsc_backend, $cinder_netapp_backend, $cinder_nfs_backend])
 445   class { '::cinder::backends' :
 446     enabled_backends => union($cinder_enabled_backends, hiera('cinder_user_enabled_backends')),
 447   }
 448
 449   # swift storage
 450   if str2bool(hiera('enable_swift_storage', true)) {
 451     class { '::swift::storage::all':
 452       mount_check => str2bool(hiera('swift_mount_check')),
 453     }
 454     if(!defined(File['/srv/node'])) {
 455       file { '/srv/node':
 456         ensure  => directory,
 457         owner   => 'swift',
 458         group   => 'swift',
 459         require => Package['openstack-swift'],
 460       }
 461     }
 462     $swift_components = ['account', 'container', 'object']
 463     swift::storage::filter::recon { $swift_components : }
 464     swift::storage::filter::healthcheck { $swift_components : }
 465   }
 466
 467   # Ceilometer
 468   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 469   case $ceilometer_backend {
 470     /mysql/ : {
 471       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 472     }
 473     default : {
 474       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 475     }
 476   }
 477   include ::ceilometer
 478   include ::ceilometer::config
 479   include ::ceilometer::api
 480   include ::ceilometer::agent::notification
 481   include ::ceilometer::agent::central
 482   include ::ceilometer::expirer
 483   include ::ceilometer::collector
 484   include ::ceilometer::agent::auth
 485   include ::ceilometer::dispatcher::gnocchi
 486   class { '::ceilometer::db' :
 487     database_connection => $ceilometer_database_connection,
 488   }
 489
 490   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 491
 492   # Aodh
 493   class { '::aodh' :
 494     database_connection => $ceilometer_database_connection,
 495   }
 496   include ::aodh::db::sync
 497   # To manage the upgrade:
 498   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 499   include ::aodh::auth
 500   include ::aodh::api
 501   include ::aodh::wsgi::apache
 502   include ::aodh::evaluator
 503   include ::aodh::notifier
 504   include ::aodh::listener
 505   include ::aodh::client
 506
 507   # Sahara
 508   include ::sahara
 509   include ::sahara::service::api
 510   include ::sahara::service::engine
 511
 512   # Horizon
 513   include ::apache::mod::remoteip
 514   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 515     $_profile_support = 'cisco'
 516   } else {
 517     $_profile_support = 'None'
 518   }
 519   $neutron_options   = {'profile_support' => $_profile_support }
 520
 521   $memcached_ipv6 = hiera('memcached_ipv6', false)
 522   if $memcached_ipv6 {
 523     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 524   } else {
 525     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 526   }
 527
 528   class { '::horizon':
 529     cache_server_ip => $horizon_memcached_servers,
 530     neutron_options => $neutron_options,
 531   }
 532
 533   # Gnocchi
 534   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 535   class { '::gnocchi':
 536     database_connection => $gnocchi_database_connection,
 537   }
 538   include ::gnocchi::api
 539   include ::gnocchi::wsgi::apache
 540   include ::gnocchi::client
 541   include ::gnocchi::db::sync
 542   include ::gnocchi::storage
 543   include ::gnocchi::metricd
 544   include ::gnocchi::statsd
 545   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 546   case $gnocchi_backend {
 547       'swift': { include ::gnocchi::storage::swift }
 548       'file': { include ::gnocchi::storage::file }
 549       'rbd': { include ::gnocchi::storage::ceph }
 550       default: { fail('Unrecognized gnocchi_backend parameter.') }
 551   }
 552
 553   $snmpd_user = hiera('snmpd_readonly_user_name')
 554   snmp::snmpv3_user { $snmpd_user:
 555     authtype => 'MD5',
 556     authpass => hiera('snmpd_readonly_user_password'),
 557   }
 558   class { '::snmp':
 559     agentaddress => ['udp:161','udp6:[::1]:161'],
 560     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 561   }
 562
 563   hiera_include('controller_classes')
 564
 565 } #END STEP 4
 566
 567 if hiera('step') >= 5 {
 568   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 569   $cinder_enable_db_purge = hiera('cinder_enable_db_purge', true)
 570
 571   if $nova_enable_db_purge {
 572     include ::nova::cron::archive_deleted_rows
 573   }
 574   if $cinder_enable_db_purge {
 575     include ::cinder::cron::db_purge
 576   }
 577 } #END STEP 5
 578
 579 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 580 package_manifest{$package_manifest_name: ensure => present}