puppet/manifests/overcloud_controller.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 $enable_load_balancer = hiera('enable_load_balancer', true)
  20
  21 if hiera('step') >= 1 {
  22
  23   create_resources(kmod::load, hiera('kernel_modules'), {})
  24   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  25   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  26
  27 }
  28
  29 if hiera('step') >= 2 {
  30
  31   if count(hiera('ntp::servers')) > 0 {
  32     include ::ntp
  33   }
  34
  35   include ::timezone
  36
  37   # MongoDB
  38   if downcase(hiera('ceilometer_backend')) == 'mongodb' {
  39     include ::mongodb::globals
  40     include ::mongodb::client
  41     include ::mongodb::server
  42     # NOTE(gfidente): We need to pass the list of IPv6 addresses *with* port and
  43     # without the brackets as 'members' argument for the 'mongodb_replset'
  44     # resource.
  45     if str2bool(hiera('mongodb::server::ipv6', false)) {
  46       $mongo_node_ips_with_port_prefixed = prefix(hiera('mongo_node_ips'), '[')
  47       $mongo_node_ips_with_port = suffix($mongo_node_ips_with_port_prefixed, ']:27017')
  48       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  49     } else {
  50       $mongo_node_ips_with_port = suffix(hiera('mongo_node_ips'), ':27017')
  51       $mongo_node_ips_with_port_nobr = suffix(hiera('mongo_node_ips'), ':27017')
  52     }
  53     $mongo_node_string = join($mongo_node_ips_with_port, ',')
  54
  55     $mongodb_replset = hiera('mongodb::server::replset')
  56     $ceilometer_mongodb_conn_string = "mongodb://${mongo_node_string}/ceilometer?replicaSet=${mongodb_replset}"
  57     if downcase(hiera('bootstrap_nodeid')) == $::hostname {
  58       mongodb_replset { $mongodb_replset :
  59         members => $mongo_node_ips_with_port_nobr,
  60       }
  61     }
  62   }
  63
  64   if str2bool(hiera('enable_galera', true)) {
  65     $mysql_config_file = '/etc/my.cnf.d/galera.cnf'
  66   } else {
  67     $mysql_config_file = '/etc/my.cnf.d/server.cnf'
  68   }
  69   # TODO Galara
  70   # FIXME: due to https://bugzilla.redhat.com/show_bug.cgi?id=1298671 we
  71   # set bind-address to a hostname instead of an ip address; to move Mysql
  72   # from internal_api on another network we'll have to customize both
  73   # MysqlNetwork and ControllerHostnameResolveNetwork in ServiceNetMap
  74   class { '::mysql::server':
  75     config_file             => $mysql_config_file,
  76     override_options        => {
  77       'mysqld' => {
  78         'bind-address'     => $::hostname,
  79         'max_connections'  => hiera('mysql_max_connections'),
  80         'open_files_limit' => '-1',
  81       },
  82     },
  83     remove_default_accounts => true,
  84   }
  85
  86   # FIXME: this should only occur on the bootstrap host (ditto for db syncs)
  87   # Create all the database schemas
  88   include ::nova::db::mysql
  89   include ::nova::db::mysql_api
  90   if downcase(hiera('gnocchi_indexer_backend')) == 'mysql' {
  91     include ::gnocchi::db::mysql
  92   }
  93   if downcase(hiera('ceilometer_backend')) == 'mysql' {
  94     include ::ceilometer::db::mysql
  95     include ::aodh::db::mysql
  96   }
  97
  98   $enable_ceph = hiera('ceph_storage_count', 0) > 0 or hiera('enable_ceph_storage', false)
  99
 100   if $enable_ceph {
 101     $mon_initial_members = downcase(hiera('ceph_mon_initial_members'))
 102     if str2bool(hiera('ceph_ipv6', false)) {
 103       $mon_host = hiera('ceph_mon_host_v6')
 104     } else {
 105       $mon_host = hiera('ceph_mon_host')
 106     }
 107     class { '::ceph::profile::params':
 108       mon_initial_members => $mon_initial_members,
 109       mon_host            => $mon_host,
 110     }
 111     include ::ceph::conf
 112     include ::ceph::profile::mon
 113   }
 114
 115   if str2bool(hiera('enable_ceph_storage', false)) {
 116     if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
 117       exec { 'set selinux to permissive on boot':
 118         command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
 119         onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
 120         path    => ['/usr/bin', '/usr/sbin'],
 121       }
 122
 123       exec { 'set selinux to permissive':
 124         command => 'setenforce 0',
 125         onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
 126         path    => ['/usr/bin', '/usr/sbin'],
 127       } -> Class['ceph::profile::osd']
 128     }
 129
 130     include ::ceph::conf
 131     include ::ceph::profile::osd
 132   }
 133
 134   if str2bool(hiera('enable_external_ceph', false)) {
 135     if str2bool(hiera('ceph_ipv6', false)) {
 136       $mon_host = hiera('ceph_mon_host_v6')
 137     } else {
 138       $mon_host = hiera('ceph_mon_host')
 139     }
 140     class { '::ceph::profile::params':
 141       mon_host            => $mon_host,
 142     }
 143     include ::ceph::conf
 144     include ::ceph::profile::client
 145   }
 146
 147 } #END STEP 2
 148
 149 if hiera('step') >= 4 {
 150
 151   $nova_ipv6 = hiera('nova::use_ipv6', false)
 152   if $nova_ipv6 {
 153     $memcached_servers = suffix(hiera('memcache_node_ips_v6'), ':11211')
 154   } else {
 155     $memcached_servers = suffix(hiera('memcache_node_ips'), ':11211')
 156   }
 157
 158   class { '::nova' :
 159     memcached_servers => $memcached_servers
 160   }
 161   include ::nova::config
 162   include ::nova::api
 163   include ::nova::cert
 164   include ::nova::consoleauth
 165   include ::nova::network::neutron
 166   include ::nova::vncproxy
 167   include ::nova::scheduler
 168   include ::nova::scheduler::filter
 169
 170   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 171
 172     # TODO(devvesa) provide non-controller ips for these services
 173     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 174     $cassandra_node_ips = hiera('neutron_api_node_ips')
 175
 176     # Run zookeeper in the controller if configured
 177     if hiera('enable_zookeeper_on_controller') {
 178       class {'::tripleo::cluster::zookeeper':
 179         zookeeper_server_ips => $zookeeper_node_ips,
 180         # TODO: create a 'bind' hiera key for zookeeper
 181         zookeeper_client_ip  => hiera('neutron::bind_host'),
 182         zookeeper_hostnames  => hiera('controller_node_names')
 183       }
 184     }
 185
 186     # Run cassandra in the controller if configured
 187     if hiera('enable_cassandra_on_controller') {
 188       class {'::tripleo::cluster::cassandra':
 189         cassandra_servers => $cassandra_node_ips,
 190         # TODO: create a 'bind' hiera key for cassandra
 191         cassandra_ip      => hiera('neutron::bind_host'),
 192       }
 193     }
 194
 195     class {'::tripleo::network::midonet::agent':
 196       zookeeper_servers => $zookeeper_node_ips,
 197       cassandra_seeds   => $cassandra_node_ips
 198     }
 199
 200     class {'::tripleo::network::midonet::api':
 201       zookeeper_servers    => $zookeeper_node_ips,
 202       vip                  => hiera('public_virtual_ip'),
 203       keystone_ip          => hiera('public_virtual_ip'),
 204       keystone_admin_token => hiera('keystone::admin_token'),
 205       # TODO: create a 'bind' hiera key for api
 206       bind_address         => hiera('neutron::bind_host'),
 207       admin_password       => hiera('admin_password')
 208     }
 209
 210     # TODO: find a way to get an empty list from hiera
 211     class {'::neutron':
 212       service_plugins => []
 213     }
 214
 215   }
 216   else {
 217
 218     # ML2 plugin
 219     include ::neutron
 220   }
 221
 222   include ::neutron::config
 223
 224   # If the value of core plugin is set to 'nuage' or'opencontrail' or 'plumgrid',
 225   # include nuage or opencontrail or plumgrid core plugins
 226   # else use the default value of 'ml2'
 227   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 228     include ::neutron::plugins::nuage
 229   } elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 230     include ::neutron::plugins::opencontrail
 231   }
 232   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 233     class { '::neutron::plugins::plumgrid' :
 234       connection                   => hiera('neutron::server::database_connection'),
 235       controller_priv_host         => hiera('keystone_admin_api_vip'),
 236       admin_password               => hiera('admin_password'),
 237       metadata_proxy_shared_secret => hiera('nova::api::neutron_metadata_proxy_shared_secret'),
 238     }
 239   } else {
 240
 241     # If the value of core plugin is set to 'midonet',
 242     # skip all the ML2 configuration
 243     if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 244
 245       class {'::neutron::plugins::midonet':
 246         midonet_api_ip    => hiera('public_virtual_ip'),
 247         keystone_tenant   => hiera('neutron::server::auth_tenant'),
 248         keystone_password => hiera('neutron::server::password')
 249       }
 250     }
 251
 252     Service['neutron-server'] -> Service['neutron-metadata']
 253
 254   }
 255
 256   if $enable_ceph {
 257     $ceph_pools = hiera('ceph_pools')
 258     ceph::pool { $ceph_pools :
 259       pg_num  => hiera('ceph::profile::params::osd_pool_default_pg_num'),
 260       pgp_num => hiera('ceph::profile::params::osd_pool_default_pgp_num'),
 261       size    => hiera('ceph::profile::params::osd_pool_default_size'),
 262     }
 263   }
 264
 265   # swift storage
 266   if str2bool(hiera('enable_swift_storage', true)) {
 267     class { '::swift::storage::all':
 268       mount_check => str2bool(hiera('swift_mount_check')),
 269     }
 270     if(!defined(File['/srv/node'])) {
 271       file { '/srv/node':
 272         ensure  => directory,
 273         owner   => 'swift',
 274         group   => 'swift',
 275         require => Package['openstack-swift'],
 276       }
 277     }
 278     $swift_components = ['account', 'container', 'object']
 279     swift::storage::filter::recon { $swift_components : }
 280     swift::storage::filter::healthcheck { $swift_components : }
 281   }
 282
 283   # Ceilometer
 284   $ceilometer_backend = downcase(hiera('ceilometer_backend'))
 285   case $ceilometer_backend {
 286     /mysql/ : {
 287       $ceilometer_database_connection = hiera('ceilometer_mysql_conn_string')
 288     }
 289     default : {
 290       $ceilometer_database_connection = $ceilometer_mongodb_conn_string
 291     }
 292   }
 293   include ::ceilometer
 294   include ::ceilometer::config
 295   include ::ceilometer::api
 296   include ::ceilometer::agent::notification
 297   include ::ceilometer::agent::central
 298   include ::ceilometer::expirer
 299   include ::ceilometer::collector
 300   include ::ceilometer::agent::auth
 301   include ::ceilometer::dispatcher::gnocchi
 302   class { '::ceilometer::db' :
 303     database_connection => $ceilometer_database_connection,
 304   }
 305
 306   Cron <| title == 'ceilometer-expirer' |> { command => "sleep $((\$(od -A n -t d -N 3 /dev/urandom) % 86400)) && ${::ceilometer::params::expirer_command}" }
 307
 308   # Aodh
 309   class { '::aodh' :
 310     database_connection => $ceilometer_database_connection,
 311   }
 312   include ::aodh::db::sync
 313   # To manage the upgrade:
 314   Exec['ceilometer-dbsync'] -> Exec['aodh-db-sync']
 315   include ::aodh::auth
 316   include ::aodh::api
 317   include ::aodh::wsgi::apache
 318   include ::aodh::evaluator
 319   include ::aodh::notifier
 320   include ::aodh::listener
 321   include ::aodh::client
 322
 323   # Horizon
 324   include ::apache::mod::remoteip
 325   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 326     $_profile_support = 'cisco'
 327   } else {
 328     $_profile_support = 'None'
 329   }
 330   $neutron_options   = {'profile_support' => $_profile_support }
 331
 332   $memcached_ipv6 = hiera('memcached_ipv6', false)
 333   if $memcached_ipv6 {
 334     $horizon_memcached_servers = hiera('memcache_node_ips_v6', '[::1]')
 335   } else {
 336     $horizon_memcached_servers = hiera('memcache_node_ips', '127.0.0.1')
 337   }
 338
 339   class { '::horizon':
 340     cache_server_ip => $horizon_memcached_servers,
 341     neutron_options => $neutron_options,
 342   }
 343
 344   # Gnocchi
 345   $gnocchi_database_connection = hiera('gnocchi_mysql_conn_string')
 346   class { '::gnocchi':
 347     database_connection => $gnocchi_database_connection,
 348   }
 349   include ::gnocchi::api
 350   include ::gnocchi::wsgi::apache
 351   include ::gnocchi::client
 352   include ::gnocchi::db::sync
 353   include ::gnocchi::storage
 354   include ::gnocchi::metricd
 355   include ::gnocchi::statsd
 356   $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift'))
 357   case $gnocchi_backend {
 358       'swift': { include ::gnocchi::storage::swift }
 359       'file': { include ::gnocchi::storage::file }
 360       'rbd': { include ::gnocchi::storage::ceph }
 361       default: { fail('Unrecognized gnocchi_backend parameter.') }
 362   }
 363
 364   $snmpd_user = hiera('snmpd_readonly_user_name')
 365   snmp::snmpv3_user { $snmpd_user:
 366     authtype => 'MD5',
 367     authpass => hiera('snmpd_readonly_user_password'),
 368   }
 369   class { '::snmp':
 370     agentaddress => ['udp:161','udp6:[::1]:161'],
 371     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 372   }
 373
 374   hiera_include('controller_classes')
 375
 376 } #END STEP 4
 377
 378 if hiera('step') >= 5 {
 379   $nova_enable_db_purge = hiera('nova_enable_db_purge', true)
 380
 381   if $nova_enable_db_purge {
 382     include ::nova::cron::archive_deleted_rows
 383   }
 384 } #END STEP 5
 385
 386 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_controller', hiera('step')])
 387 package_manifest{$package_manifest_name: ensure => present}