puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 if hiera('step') >= 4 {
  20
  21   # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  22   exec { 'reset-iscsi-initiator-name':
  23     command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  24     onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  25   }->
  26
  27   file { '/etc/iscsi/.initiator_reset':
  28     ensure => present,
  29   }
  30
  31   nova_config {
  32     'DEFAULT/my_ip': value => $ipaddress;
  33     'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  34   }
  35
  36   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
  37     file { '/etc/libvirt/qemu.conf':
  38       ensure  => present,
  39       content => hiera('midonet_libvirt_qemu_data')
  40     }
  41   }
  42
  43   # If the value of core plugin is set to 'midonet',
  44   # include midonet agent,
  45   # else use the default value of 'ml2'
  46   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
  47
  48     # TODO(devvesa) provide non-controller ips for these services
  49     $zookeeper_node_ips = hiera('neutron_api_node_ips')
  50     $cassandra_node_ips = hiera('neutron_api_node_ips')
  51
  52     class { '::tripleo::network::midonet::agent':
  53       zookeeper_servers => $zookeeper_node_ips,
  54       cassandra_seeds   => $cassandra_node_ips
  55     }
  56   }
  57   elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
  58
  59     include ::contrail::vrouter
  60     # NOTE: it's not possible to use this class without a functional
  61     # contrail controller up and running
  62     #class {'::contrail::vrouter::provision_vrouter':
  63     #  require => Class['contrail::vrouter'],
  64     #}
  65   }
  66   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
  67     # forward all ipv4 traffic
  68     # this is required for the vms to pass through the gateways public interface
  69     sysctl::value { 'net.ipv4.ip_forward': value => '1' }
  70
  71     # ifc_ctl_pp needs to be invoked by root as part of the vif.py when a VM is powered on
  72     file { '/etc/sudoers.d/ifc_ctl_sudoers':
  73       ensure  => file,
  74       owner   => root,
  75       group   => root,
  76       mode    => '0440',
  77       content => "nova ALL=(root) NOPASSWD: /opt/pg/bin/ifc_ctl_pp *\n",
  78     }
  79   }
  80
  81   include ::ceilometer
  82   include ::ceilometer::config
  83   include ::ceilometer::agent::compute
  84   include ::ceilometer::agent::auth
  85
  86   hiera_include('compute_classes')
  87 }
  88
  89 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_compute', hiera('step')])
  90 package_manifest{$package_manifest_name: ensure => present}