puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 if count(hiera('ntp::servers')) > 0 {
  28   include ::ntp
  29 }
  30
  31 file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  32         '/etc/libvirt/qemu/networks/default.xml']:
  33   ensure => absent,
  34   before => Service['libvirt']
  35 }
  36
  37 include ::nova
  38 include ::nova::compute
  39
  40 nova_config {
  41   'DEFAULT/my_ip':                     value => $ipaddress;
  42   'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  43 }
  44
  45 include ::nova::compute::libvirt
  46 include ::nova::network::neutron
  47 include ::neutron
  48
  49 class { 'neutron::plugins::ml2':
  50   flat_networks        => split(hiera('neutron_flat_networks'), ','),
  51   tenant_network_types => [hiera('neutron_tenant_network_type')],
  52   type_drivers         => [hiera('neutron_tenant_network_type')],
  53 }
  54
  55 class { 'neutron::agents::ml2::ovs':
  56   bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
  57   tunnel_types    => split(hiera('neutron_tunnel_types'), ','),
  58 }
  59
  60 include ::ceilometer
  61 include ::ceilometer::agent::compute
  62 include ::ceilometer::agent::auth
  63
  64 $snmpd_user = hiera('snmpd_readonly_user_name')
  65 snmp::snmpv3_user { $snmpd_user:
  66   authtype => 'MD5',
  67   authpass => hiera('snmpd_readonly_user_password'),
  68 }
  69 class { 'snmp':
  70   agentaddress => ['udp:161','udp6:[::1]:161'],
  71   snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
  72 }