puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 if !str2bool(hiera('enable_package_install', 'false')) {
  17   case $::osfamily {
  18     'RedHat': {
  19       Package { provider => 'norpm' } # provided by tripleo-puppet
  20     }
  21     default: {
  22       warning('enable_package_install option not supported.')
  23     }
  24   }
  25 }
  26
  27 create_resources(sysctl::value, hiera('sysctl_settings'), {})
  28
  29 if count(hiera('ntp::servers')) > 0 {
  30   include ::ntp
  31 }
  32
  33 file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  34         '/etc/libvirt/qemu/networks/default.xml']:
  35   ensure => absent,
  36   before => Service['libvirt']
  37 }
  38 # in case libvirt has been already running before the Puppet run, make
  39 # sure the default network is destroyed
  40 exec { 'libvirt-default-net-destroy':
  41   command => '/usr/bin/virsh net-destroy default',
  42   onlyif => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  43   before => Service['libvirt'],
  44 }
  45
  46 include ::nova
  47 include ::nova::compute
  48
  49 nova_config {
  50   'DEFAULT/my_ip':                     value => $ipaddress;
  51   'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  52 }
  53
  54 $nova_enable_rbd_backend = hiera('nova_enable_rbd_backend', false)
  55 if $nova_enable_rbd_backend {
  56   include ::ceph::profile::client
  57
  58   $client_keys = hiera('ceph::profile::params::client_keys')
  59   class { '::nova::compute::rbd':
  60     libvirt_rbd_secret_key => $client_keys['client.openstack']['secret'],
  61   }
  62 }
  63
  64 include ::nova::compute::libvirt
  65 include ::nova::network::neutron
  66 include ::neutron
  67
  68 class { 'neutron::plugins::ml2':
  69   flat_networks        => split(hiera('neutron_flat_networks'), ','),
  70   tenant_network_types => [hiera('neutron_tenant_network_type')],
  71   type_drivers         => [hiera('neutron_tenant_network_type')],
  72 }
  73
  74 class { 'neutron::agents::ml2::ovs':
  75   bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
  76   tunnel_types    => split(hiera('neutron_tunnel_types'), ','),
  77 }
  78
  79 include ::ceilometer
  80 include ::ceilometer::agent::compute
  81 include ::ceilometer::agent::auth
  82
  83 $snmpd_user = hiera('snmpd_readonly_user_name')
  84 snmp::snmpv3_user { $snmpd_user:
  85   authtype => 'MD5',
  86   authpass => hiera('snmpd_readonly_user_password'),
  87 }
  88 class { 'snmp':
  89   agentaddress => ['udp:161','udp6:[::1]:161'],
  90   snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
  91 }