puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 create_resources(kmod::load, hiera('kernel_modules'), { })
  20 create_resources(sysctl::value, hiera('sysctl_settings'), { })
  21 Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  22
  23 if count(hiera('ntp::servers')) > 0 {
  24   include ::ntp
  25 }
  26
  27 include ::timezone
  28
  29 if hiera('step') >= 4 {
  30
  31   file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  32     '/etc/libvirt/qemu/networks/default.xml']:
  33     ensure => absent,
  34     before => Service['libvirt'],
  35   }
  36   # in case libvirt has been already running before the Puppet run, make
  37   # sure the default network is destroyed
  38   exec { 'libvirt-default-net-destroy':
  39     command => '/usr/bin/virsh net-destroy default',
  40     onlyif  => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  41     before  => Service['libvirt'],
  42   }
  43
  44   # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  45   exec { 'reset-iscsi-initiator-name':
  46     command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  47     onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  48   }->
  49
  50   file { '/etc/iscsi/.initiator_reset':
  51     ensure => present,
  52   }
  53
  54   include ::nova
  55   include ::nova::config
  56   include ::nova::compute
  57
  58   $rbd_ephemeral_storage = hiera('nova::compute::rbd::ephemeral_storage', false)
  59   $rbd_persistent_storage = hiera('rbd_persistent_storage', false)
  60   if $rbd_ephemeral_storage or $rbd_persistent_storage {
  61     if str2bool(hiera('ceph_ipv6', false)) {
  62       $mon_host = hiera('ceph_mon_host_v6')
  63     } else {
  64       $mon_host = hiera('ceph_mon_host')
  65     }
  66     class { '::ceph::profile::params':
  67       mon_host            => $mon_host,
  68     }
  69     include ::ceph::conf
  70     include ::ceph::profile::client
  71
  72     $client_keys = hiera('ceph::profile::params::client_keys')
  73     $client_user = join(['client.', hiera('ceph_client_user_name')])
  74     class { '::nova::compute::rbd':
  75       libvirt_rbd_secret_key => $client_keys[$client_user]['secret'],
  76     }
  77   }
  78
  79   if hiera('cinder_enable_nfs_backend', false) {
  80     if str2bool($::selinux) {
  81       selboolean { 'virt_use_nfs':
  82         value      => on,
  83         persistent => true,
  84       } -> Package['nfs-utils']
  85     }
  86
  87     package { 'nfs-utils': } -> Service['nova-compute']
  88   }
  89
  90   if str2bool(hiera('nova::use_ipv6', false)) {
  91     $vncserver_listen = '::0'
  92   } else {
  93     $vncserver_listen = '0.0.0.0'
  94   }
  95
  96   if $rbd_ephemeral_storage {
  97     class { '::nova::compute::libvirt':
  98       libvirt_disk_cachemodes => ['network=writeback'],
  99       libvirt_hw_disk_discard => 'unmap',
 100       vncserver_listen        => $vncserver_listen,
 101     }
 102   } else {
 103     class { '::nova::compute::libvirt' :
 104       vncserver_listen => $vncserver_listen,
 105     }
 106   }
 107
 108   nova_config {
 109     'DEFAULT/my_ip': value => $ipaddress;
 110     'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
 111   }
 112
 113   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 114     file { '/etc/libvirt/qemu.conf':
 115       ensure  => present,
 116       content => hiera('midonet_libvirt_qemu_data')
 117     }
 118   }
 119   include ::nova::network::neutron
 120   include ::neutron
 121   include ::neutron::config
 122
 123   # If the value of core plugin is set to 'nuage',
 124   # include nuage agent,
 125   # If the value of core plugin is set to 'midonet',
 126   # include midonet agent,
 127   # else use the default value of 'ml2'
 128   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 129     include ::nuage::vrs
 130     include ::nova::compute::neutron
 131
 132     class { '::nuage::metadataagent':
 133       nova_os_tenant_name => hiera('nova::api::admin_tenant_name'),
 134       nova_os_password    => hiera('nova_password'),
 135       nova_metadata_ip    => hiera('nova_metadata_node_ips'),
 136       nova_auth_ip        => hiera('keystone_public_api_virtual_ip'),
 137     }
 138   }
 139   elsif hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 140
 141     # TODO(devvesa) provide non-controller ips for these services
 142     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 143     $cassandra_node_ips = hiera('neutron_api_node_ips')
 144
 145     class { '::tripleo::network::midonet::agent':
 146       zookeeper_servers => $zookeeper_node_ips,
 147       cassandra_seeds   => $cassandra_node_ips
 148     }
 149   }
 150   elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 151
 152     include ::contrail::vrouter
 153     # NOTE: it's not possible to use this class without a functional
 154     # contrail controller up and running
 155     #class {'::contrail::vrouter::provision_vrouter':
 156     #  require => Class['contrail::vrouter'],
 157     #}
 158   }
 159   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 160     # forward all ipv4 traffic
 161     # this is required for the vms to pass through the gateways public interface
 162     sysctl::value { 'net.ipv4.ip_forward': value => '1' }
 163
 164     # ifc_ctl_pp needs to be invoked by root as part of the vif.py when a VM is powered on
 165     file { '/etc/sudoers.d/ifc_ctl_sudoers':
 166       ensure  => file,
 167       owner   => root,
 168       group   => root,
 169       mode    => '0440',
 170       content => "nova ALL=(root) NOPASSWD: /opt/pg/bin/ifc_ctl_pp *\n",
 171     }
 172   }
 173   else {
 174
 175     # NOTE: this code won't live in puppet-neutron until Neutron OVS agent
 176     # can be gracefully restarted. See https://review.openstack.org/#/c/297211
 177     # In the meantime, it's safe to restart the agent on each change in neutron.conf,
 178     # because Puppet changes are supposed to be done during bootstrap and upgrades.
 179     # Some resource managed by Neutron_config (like messaging and logging options) require
 180     # a restart of OVS agent. This code does it.
 181     # In Newton, OVS agent will be able to be restarted gracefully so we'll drop the code
 182     # from here and fix it in puppet-neutron.
 183     Neutron_config<||> ~> Service['neutron-ovs-agent-service']
 184
 185     include ::neutron::plugins::ml2
 186     include ::neutron::agents::ml2::ovs
 187
 188     if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 189       class { '::neutron::agents::n1kv_vem':
 190         n1kv_source  => hiera('n1kv_vem_source', undef),
 191         n1kv_version => hiera('n1kv_vem_version', undef),
 192       }
 193     }
 194
 195     if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 196       include ::neutron::agents::bigswitch
 197     }
 198   }
 199
 200   neutron_config {
 201     'DEFAULT/host': value => $fqdn;
 202   }
 203
 204   include ::ceilometer
 205   include ::ceilometer::config
 206   include ::ceilometer::agent::compute
 207   include ::ceilometer::agent::auth
 208
 209   $snmpd_user = hiera('snmpd_readonly_user_name')
 210   snmp::snmpv3_user { $snmpd_user:
 211     authtype => 'MD5',
 212     authpass => hiera('snmpd_readonly_user_password'),
 213   }
 214   class { '::snmp':
 215     agentaddress => ['udp:161','udp6:[::1]:161'],
 216     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 217   }
 218
 219   hiera_include('compute_classes')
 220   package_manifest{ '/var/lib/tripleo/installed-packages/overcloud_compute': ensure => present }
 221
 222 }