puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include tripleo::packages
  17
  18 create_resources(sysctl::value, hiera('sysctl_settings'), {})
  19
  20 if count(hiera('ntp::servers')) > 0 {
  21   include ::ntp
  22 }
  23
  24 file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  25         '/etc/libvirt/qemu/networks/default.xml']:
  26   ensure => absent,
  27   before => Service['libvirt']
  28 }
  29 # in case libvirt has been already running before the Puppet run, make
  30 # sure the default network is destroyed
  31 exec { 'libvirt-default-net-destroy':
  32   command => '/usr/bin/virsh net-destroy default',
  33   onlyif => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  34   before => Service['libvirt'],
  35 }
  36
  37 include ::nova
  38 include ::nova::config
  39 include ::nova::compute
  40
  41 nova_config {
  42   'DEFAULT/my_ip':                     value => $ipaddress;
  43   'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  44 }
  45
  46 $nova_enable_rbd_backend = hiera('nova::compute::rbd::ephemeral_storage', false)
  47 if $nova_enable_rbd_backend {
  48   include ::ceph::profile::client
  49
  50   $client_keys = hiera('ceph::profile::params::client_keys')
  51   class { '::nova::compute::rbd':
  52     libvirt_rbd_secret_key => $client_keys['client.openstack']['secret'],
  53   }
  54 }
  55
  56 include ::nova::compute::libvirt
  57 include ::nova::network::neutron
  58 include ::neutron
  59
  60 class { 'neutron::plugins::ml2':
  61   flat_networks        => split(hiera('neutron_flat_networks'), ','),
  62   tenant_network_types => [hiera('neutron_tenant_network_type')],
  63 }
  64
  65 class { 'neutron::agents::ml2::ovs':
  66   bridge_mappings => split(hiera('neutron_bridge_mappings'), ','),
  67   tunnel_types    => split(hiera('neutron_tunnel_types'), ','),
  68 }
  69
  70 include ::ceilometer
  71 include ::ceilometer::agent::compute
  72 include ::ceilometer::agent::auth
  73
  74 $snmpd_user = hiera('snmpd_readonly_user_name')
  75 snmp::snmpv3_user { $snmpd_user:
  76   authtype => 'MD5',
  77   authpass => hiera('snmpd_readonly_user_password'),
  78 }
  79 class { 'snmp':
  80   agentaddress => ['udp:161','udp6:[::1]:161'],
  81   snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
  82 }
  83
  84 hiera_include('compute_classes')