puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 create_resources(kmod::load, hiera('kernel_modules'), { })
  20 create_resources(sysctl::value, hiera('sysctl_settings'), { })
  21 Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  22
  23 include ::timezone
  24
  25 if hiera('step') >= 4 {
  26
  27   file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  28     '/etc/libvirt/qemu/networks/default.xml']:
  29     ensure => absent,
  30     before => Service['libvirt'],
  31   }
  32   # in case libvirt has been already running before the Puppet run, make
  33   # sure the default network is destroyed
  34   exec { 'libvirt-default-net-destroy':
  35     command => '/usr/bin/virsh net-destroy default',
  36     onlyif  => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  37     before  => Service['libvirt'],
  38   }
  39
  40   # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  41   exec { 'reset-iscsi-initiator-name':
  42     command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  43     onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  44   }->
  45
  46   file { '/etc/iscsi/.initiator_reset':
  47     ensure => present,
  48   }
  49
  50   $rbd_ephemeral_storage = hiera('nova::compute::rbd::ephemeral_storage', false)
  51   $rbd_persistent_storage = hiera('rbd_persistent_storage', false)
  52   if $rbd_ephemeral_storage or $rbd_persistent_storage {
  53     if str2bool(hiera('ceph_ipv6', false)) {
  54       $mon_host = hiera('ceph_mon_host_v6')
  55     } else {
  56       $mon_host = hiera('ceph_mon_host')
  57     }
  58     class { '::ceph::profile::params':
  59       mon_host            => $mon_host,
  60     }
  61     include ::ceph::conf
  62     include ::ceph::profile::client
  63
  64     $client_keys = hiera('ceph::profile::params::client_keys')
  65     $client_user = join(['client.', hiera('tripleo::profile::base::cinder::volume::rbd::cinder_rbd_user_name')])
  66     class { '::nova::compute::rbd':
  67       libvirt_rbd_secret_key => $client_keys[$client_user]['secret'],
  68     }
  69   }
  70
  71   if hiera('cinder_enable_nfs_backend', false) {
  72     if str2bool($::selinux) {
  73       selboolean { 'virt_use_nfs':
  74         value      => on,
  75         persistent => true,
  76       } -> Package['nfs-utils']
  77     }
  78
  79     package { 'nfs-utils': } -> Service['nova-compute']
  80   }
  81
  82   if str2bool(hiera('nova::use_ipv6', false)) {
  83     $vncserver_listen = '::0'
  84   } else {
  85     $vncserver_listen = '0.0.0.0'
  86   }
  87
  88   if $rbd_ephemeral_storage {
  89     class { '::nova::compute::libvirt':
  90       libvirt_disk_cachemodes => ['network=writeback'],
  91       libvirt_hw_disk_discard => 'unmap',
  92       vncserver_listen        => $vncserver_listen,
  93     }
  94   } else {
  95     class { '::nova::compute::libvirt' :
  96       vncserver_listen => $vncserver_listen,
  97     }
  98   }
  99
 100   nova_config {
 101     'DEFAULT/my_ip': value => $ipaddress;
 102     'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
 103   }
 104
 105   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 106     file { '/etc/libvirt/qemu.conf':
 107       ensure  => present,
 108       content => hiera('midonet_libvirt_qemu_data')
 109     }
 110   }
 111   include ::nova::network::neutron
 112   include ::neutron
 113   include ::neutron::config
 114
 115   # If the value of core plugin is set to 'nuage',
 116   # include nuage agent,
 117   # If the value of core plugin is set to 'midonet',
 118   # include midonet agent,
 119   # else use the default value of 'ml2'
 120   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 121     include ::nuage::vrs
 122     include ::nova::compute::neutron
 123
 124     class { '::nuage::metadataagent':
 125       nova_os_tenant_name => hiera('nova::api::admin_tenant_name'),
 126       nova_os_password    => hiera('nova_password'),
 127       nova_metadata_ip    => hiera('nova_metadata_node_ips'),
 128       nova_auth_ip        => hiera('keystone_public_api_virtual_ip'),
 129     }
 130   }
 131   elsif hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 132
 133     # TODO(devvesa) provide non-controller ips for these services
 134     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 135     $cassandra_node_ips = hiera('neutron_api_node_ips')
 136
 137     class { '::tripleo::network::midonet::agent':
 138       zookeeper_servers => $zookeeper_node_ips,
 139       cassandra_seeds   => $cassandra_node_ips
 140     }
 141   }
 142   elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 143
 144     include ::contrail::vrouter
 145     # NOTE: it's not possible to use this class without a functional
 146     # contrail controller up and running
 147     #class {'::contrail::vrouter::provision_vrouter':
 148     #  require => Class['contrail::vrouter'],
 149     #}
 150   }
 151   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 152     # forward all ipv4 traffic
 153     # this is required for the vms to pass through the gateways public interface
 154     sysctl::value { 'net.ipv4.ip_forward': value => '1' }
 155
 156     # ifc_ctl_pp needs to be invoked by root as part of the vif.py when a VM is powered on
 157     file { '/etc/sudoers.d/ifc_ctl_sudoers':
 158       ensure  => file,
 159       owner   => root,
 160       group   => root,
 161       mode    => '0440',
 162       content => "nova ALL=(root) NOPASSWD: /opt/pg/bin/ifc_ctl_pp *\n",
 163     }
 164   }
 165   else {
 166
 167     # NOTE: this code won't live in puppet-neutron until Neutron OVS agent
 168     # can be gracefully restarted. See https://review.openstack.org/#/c/297211
 169     # In the meantime, it's safe to restart the agent on each change in neutron.conf,
 170     # because Puppet changes are supposed to be done during bootstrap and upgrades.
 171     # Some resource managed by Neutron_config (like messaging and logging options) require
 172     # a restart of OVS agent. This code does it.
 173     # In Newton, OVS agent will be able to be restarted gracefully so we'll drop the code
 174     # from here and fix it in puppet-neutron.
 175     Neutron_config<||> ~> Service['neutron-ovs-agent-service']
 176
 177     include ::neutron::plugins::ml2
 178     include ::neutron::agents::ml2::ovs
 179
 180     if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 181       class { '::neutron::agents::n1kv_vem':
 182         n1kv_source  => hiera('n1kv_vem_source', undef),
 183         n1kv_version => hiera('n1kv_vem_version', undef),
 184       }
 185     }
 186
 187     if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 188       include ::neutron::agents::bigswitch
 189     }
 190   }
 191
 192   include ::ceilometer
 193   include ::ceilometer::config
 194   include ::ceilometer::agent::compute
 195   include ::ceilometer::agent::auth
 196
 197   $snmpd_user = hiera('snmpd_readonly_user_name')
 198   snmp::snmpv3_user { $snmpd_user:
 199     authtype => 'MD5',
 200     authpass => hiera('snmpd_readonly_user_password'),
 201   }
 202   class { '::snmp':
 203     agentaddress => ['udp:161','udp6:[::1]:161'],
 204     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 205   }
 206
 207   hiera_include('compute_classes')
 208 }
 209
 210 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_compute', hiera('step')])
 211 package_manifest{$package_manifest_name: ensure => present}