puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 create_resources(kmod::load, hiera('kernel_modules'), {})
  20 create_resources(sysctl::value, hiera('sysctl_settings'), {})
  21 Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  22
  23 if count(hiera('ntp::servers')) > 0 {
  24   include ::ntp
  25 }
  26
  27 include ::timezone
  28
  29 file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  30         '/etc/libvirt/qemu/networks/default.xml']:
  31   ensure => absent,
  32   before => Service['libvirt'],
  33 }
  34 # in case libvirt has been already running before the Puppet run, make
  35 # sure the default network is destroyed
  36 exec { 'libvirt-default-net-destroy':
  37   command => '/usr/bin/virsh net-destroy default',
  38   onlyif  => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  39   before  => Service['libvirt'],
  40 }
  41
  42 # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  43 exec { 'reset-iscsi-initiator-name':
  44   command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  45   onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  46 }->
  47
  48 file { '/etc/iscsi/.initiator_reset':
  49   ensure => present,
  50 }
  51
  52 include ::nova
  53 include ::nova::config
  54 include ::nova::compute
  55
  56 nova_config {
  57   'DEFAULT/my_ip':                     value => $ipaddress;
  58   'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  59 }
  60
  61 $rbd_ephemeral_storage = hiera('nova::compute::rbd::ephemeral_storage', false)
  62 $rbd_persistent_storage = hiera('rbd_persistent_storage', false)
  63 if $rbd_ephemeral_storage or $rbd_persistent_storage {
  64   include ::ceph::conf
  65   include ::ceph::profile::client
  66
  67   $client_keys = hiera('ceph::profile::params::client_keys')
  68   $client_user = join(['client.', hiera('ceph_client_user_name')])
  69   class { '::nova::compute::rbd':
  70     libvirt_rbd_secret_key => $client_keys[$client_user]['secret'],
  71   }
  72 }
  73
  74 if hiera('cinder_enable_nfs_backend', false) {
  75   if str2bool($::selinux) {
  76     selboolean { 'virt_use_nfs':
  77       value      => on,
  78       persistent => true,
  79     } -> Package['nfs-utils']
  80   }
  81
  82   package {'nfs-utils': } -> Service['nova-compute']
  83 }
  84
  85 include ::nova::compute::libvirt
  86 if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
  87   file {'/etc/libvirt/qemu.conf':
  88     ensure  => present,
  89     content => hiera('midonet_libvirt_qemu_data')
  90   }
  91 }
  92 include ::nova::network::neutron
  93 include ::neutron
  94 include ::neutron::config
  95
  96 # If the value of core plugin is set to 'nuage',
  97 # include nuage agent,
  98 # If the value of core plugin is set to 'midonet',
  99 # include midonet agent,
 100 # else use the default value of 'ml2'
 101 if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 102   include ::nuage::vrs
 103   include ::nova::compute::neutron
 104
 105   class { '::nuage::metadataagent':
 106     nova_os_tenant_name => hiera('nova::api::admin_tenant_name'),
 107     nova_os_password    => hiera('nova_password'),
 108     nova_metadata_ip    => hiera('nova_metadata_node_ips'),
 109     nova_auth_ip        => hiera('keystone_public_api_virtual_ip'),
 110   }
 111 }
 112 elsif hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 113
 114   # TODO(devvesa) provide non-controller ips for these services
 115   $zookeeper_node_ips = hiera('neutron_api_node_ips')
 116   $cassandra_node_ips = hiera('neutron_api_node_ips')
 117
 118   class {'::tripleo::network::midonet::agent':
 119     zookeeper_servers => $zookeeper_node_ips,
 120     cassandra_seeds   => $cassandra_node_ips
 121   }
 122 }
 123 elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 124
 125   include ::contrail::vrouter
 126   # NOTE: it's not possible to use this class without a functional
 127   # contrail controller up and running
 128   #class {'::contrail::vrouter::provision_vrouter':
 129   #  require => Class['contrail::vrouter'],
 130   #}
 131 }
 132 else {
 133
 134   include ::neutron::plugins::ml2
 135   include ::neutron::agents::ml2::ovs
 136
 137   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 138     class { '::neutron::agents::n1kv_vem':
 139       n1kv_source  => hiera('n1kv_vem_source', undef),
 140       n1kv_version => hiera('n1kv_vem_version', undef),
 141     }
 142   }
 143
 144   if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 145     include ::neutron::agents::bigswitch
 146   }
 147 }
 148
 149
 150 include ::ceilometer
 151 include ::ceilometer::config
 152 include ::ceilometer::agent::compute
 153 include ::ceilometer::agent::auth
 154
 155 $snmpd_user = hiera('snmpd_readonly_user_name')
 156 snmp::snmpv3_user { $snmpd_user:
 157   authtype => 'MD5',
 158   authpass => hiera('snmpd_readonly_user_password'),
 159 }
 160 class { '::snmp':
 161   agentaddress => ['udp:161','udp6:[::1]:161'],
 162   snmpd_config => [ join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 163 }
 164
 165 hiera_include('compute_classes')
 166 package_manifest{'/var/lib/tripleo/installed-packages/overcloud_compute': ensure => present}