puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 create_resources(kmod::load, hiera('kernel_modules'), {})
  20 create_resources(sysctl::value, hiera('sysctl_settings'), {})
  21 Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  22
  23 if count(hiera('ntp::servers')) > 0 {
  24   include ::ntp
  25 }
  26
  27 include ::timezone
  28
  29 file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  30         '/etc/libvirt/qemu/networks/default.xml']:
  31   ensure => absent,
  32   before => Service['libvirt'],
  33 }
  34 # in case libvirt has been already running before the Puppet run, make
  35 # sure the default network is destroyed
  36 exec { 'libvirt-default-net-destroy':
  37   command => '/usr/bin/virsh net-destroy default',
  38   onlyif  => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  39   before  => Service['libvirt'],
  40 }
  41
  42 # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  43 exec { 'reset-iscsi-initiator-name':
  44   command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  45   onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  46 }->
  47
  48 file { '/etc/iscsi/.initiator_reset':
  49   ensure => present,
  50 }
  51
  52 include ::nova
  53 include ::nova::config
  54 include ::nova::compute
  55
  56 nova_config {
  57   'DEFAULT/my_ip':                     value => $ipaddress;
  58   'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  59   'DEFAULT/host':                      value => $fqdn;
  60 }
  61
  62 $rbd_ephemeral_storage = hiera('nova::compute::rbd::ephemeral_storage', false)
  63 $rbd_persistent_storage = hiera('rbd_persistent_storage', false)
  64 if $rbd_ephemeral_storage or $rbd_persistent_storage {
  65   include ::ceph::conf
  66   include ::ceph::profile::client
  67
  68   $client_keys = hiera('ceph::profile::params::client_keys')
  69   $client_user = join(['client.', hiera('ceph_client_user_name')])
  70   class { '::nova::compute::rbd':
  71     libvirt_rbd_secret_key => $client_keys[$client_user]['secret'],
  72   }
  73 }
  74
  75 if hiera('cinder_enable_nfs_backend', false) {
  76   if str2bool($::selinux) {
  77     selboolean { 'virt_use_nfs':
  78       value      => on,
  79       persistent => true,
  80     } -> Package['nfs-utils']
  81   }
  82
  83   package {'nfs-utils': } -> Service['nova-compute']
  84 }
  85
  86 if str2bool(hiera('nova::use_ipv6', false)) {
  87   $vncserver_listen = '::0'
  88 } else {
  89   $vncserver_listen = '0.0.0.0'
  90 }
  91 class { '::nova::compute::libvirt' :
  92   vncserver_listen => $vncserver_listen,
  93 }
  94 if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
  95   file {'/etc/libvirt/qemu.conf':
  96     ensure  => present,
  97     content => hiera('midonet_libvirt_qemu_data')
  98   }
  99 }
 100 include ::nova::network::neutron
 101 include ::neutron
 102 include ::neutron::config
 103
 104 # If the value of core plugin is set to 'nuage',
 105 # include nuage agent,
 106 # If the value of core plugin is set to 'midonet',
 107 # include midonet agent,
 108 # else use the default value of 'ml2'
 109 if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 110   include ::nuage::vrs
 111   include ::nova::compute::neutron
 112
 113   class { '::nuage::metadataagent':
 114     nova_os_tenant_name => hiera('nova::api::admin_tenant_name'),
 115     nova_os_password    => hiera('nova_password'),
 116     nova_metadata_ip    => hiera('nova_metadata_node_ips'),
 117     nova_auth_ip        => hiera('keystone_public_api_virtual_ip'),
 118   }
 119 }
 120 elsif hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 121
 122   # TODO(devvesa) provide non-controller ips for these services
 123   $zookeeper_node_ips = hiera('neutron_api_node_ips')
 124   $cassandra_node_ips = hiera('neutron_api_node_ips')
 125
 126   class {'::tripleo::network::midonet::agent':
 127     zookeeper_servers => $zookeeper_node_ips,
 128     cassandra_seeds   => $cassandra_node_ips
 129   }
 130 }
 131 elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 132
 133   include ::contrail::vrouter
 134   # NOTE: it's not possible to use this class without a functional
 135   # contrail controller up and running
 136   #class {'::contrail::vrouter::provision_vrouter':
 137   #  require => Class['contrail::vrouter'],
 138   #}
 139 }
 140 else {
 141
 142   include ::neutron::plugins::ml2
 143   include ::neutron::agents::ml2::ovs
 144
 145   if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 146     class { '::neutron::agents::n1kv_vem':
 147       n1kv_source  => hiera('n1kv_vem_source', undef),
 148       n1kv_version => hiera('n1kv_vem_version', undef),
 149     }
 150   }
 151
 152   if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 153     include ::neutron::agents::bigswitch
 154   }
 155 }
 156
 157 neutron_config {
 158   'DEFAULT/host': value => $fqdn;
 159 }
 160
 161 include ::ceilometer
 162 include ::ceilometer::config
 163 include ::ceilometer::agent::compute
 164 include ::ceilometer::agent::auth
 165
 166 $snmpd_user = hiera('snmpd_readonly_user_name')
 167 snmp::snmpv3_user { $snmpd_user:
 168   authtype => 'MD5',
 169   authpass => hiera('snmpd_readonly_user_password'),
 170 }
 171 class { '::snmp':
 172   agentaddress => ['udp:161','udp6:[::1]:161'],
 173   snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 174 }
 175
 176 hiera_include('compute_classes')
 177 package_manifest{'/var/lib/tripleo/installed-packages/overcloud_compute': ensure => present}