puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 create_resources(kmod::load, hiera('kernel_modules'), { })
  20 create_resources(sysctl::value, hiera('sysctl_settings'), { })
  21 Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  22
  23 if hiera('step') >= 4 {
  24
  25   # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  26   exec { 'reset-iscsi-initiator-name':
  27     command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  28     onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  29   }->
  30
  31   file { '/etc/iscsi/.initiator_reset':
  32     ensure => present,
  33   }
  34
  35   nova_config {
  36     'DEFAULT/my_ip': value => $ipaddress;
  37     'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
  38   }
  39
  40   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
  41     file { '/etc/libvirt/qemu.conf':
  42       ensure  => present,
  43       content => hiera('midonet_libvirt_qemu_data')
  44     }
  45   }
  46
  47   include ::neutron
  48   include ::neutron::config
  49
  50   # If the value of core plugin is set to 'nuage',
  51   # include nuage agent,
  52   # If the value of core plugin is set to 'midonet',
  53   # include midonet agent,
  54   # else use the default value of 'ml2'
  55   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
  56     include ::nuage::vrs
  57     include ::nova::compute::neutron
  58
  59     class { '::nuage::metadataagent':
  60       nova_os_tenant_name => hiera('nova::api::admin_tenant_name'),
  61       nova_os_password    => hiera('nova_password'),
  62       nova_metadata_ip    => hiera('nova_metadata_node_ips'),
  63       nova_auth_ip        => hiera('keystone_public_api_virtual_ip'),
  64     }
  65   }
  66   elsif hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
  67
  68     # TODO(devvesa) provide non-controller ips for these services
  69     $zookeeper_node_ips = hiera('neutron_api_node_ips')
  70     $cassandra_node_ips = hiera('neutron_api_node_ips')
  71
  72     class { '::tripleo::network::midonet::agent':
  73       zookeeper_servers => $zookeeper_node_ips,
  74       cassandra_seeds   => $cassandra_node_ips
  75     }
  76   }
  77   elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
  78
  79     include ::contrail::vrouter
  80     # NOTE: it's not possible to use this class without a functional
  81     # contrail controller up and running
  82     #class {'::contrail::vrouter::provision_vrouter':
  83     #  require => Class['contrail::vrouter'],
  84     #}
  85   }
  86   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
  87     # forward all ipv4 traffic
  88     # this is required for the vms to pass through the gateways public interface
  89     sysctl::value { 'net.ipv4.ip_forward': value => '1' }
  90
  91     # ifc_ctl_pp needs to be invoked by root as part of the vif.py when a VM is powered on
  92     file { '/etc/sudoers.d/ifc_ctl_sudoers':
  93       ensure  => file,
  94       owner   => root,
  95       group   => root,
  96       mode    => '0440',
  97       content => "nova ALL=(root) NOPASSWD: /opt/pg/bin/ifc_ctl_pp *\n",
  98     }
  99   }
 100   else {
 101
 102     # NOTE: this code won't live in puppet-neutron until Neutron OVS agent
 103     # can be gracefully restarted. See https://review.openstack.org/#/c/297211
 104     # In the meantime, it's safe to restart the agent on each change in neutron.conf,
 105     # because Puppet changes are supposed to be done during bootstrap and upgrades.
 106     # Some resource managed by Neutron_config (like messaging and logging options) require
 107     # a restart of OVS agent. This code does it.
 108     # In Newton, OVS agent will be able to be restarted gracefully so we'll drop the code
 109     # from here and fix it in puppet-neutron.
 110     Neutron_config<||> ~> Service['neutron-ovs-agent-service']
 111
 112     include ::neutron::plugins::ml2
 113     include ::neutron::agents::ml2::ovs
 114
 115     if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 116       class { '::neutron::agents::n1kv_vem':
 117         n1kv_source  => hiera('n1kv_vem_source', undef),
 118         n1kv_version => hiera('n1kv_vem_version', undef),
 119       }
 120     }
 121
 122     if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 123       include ::neutron::agents::bigswitch
 124     }
 125   }
 126
 127   include ::ceilometer
 128   include ::ceilometer::config
 129   include ::ceilometer::agent::compute
 130   include ::ceilometer::agent::auth
 131
 132   hiera_include('compute_classes')
 133 }
 134
 135 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_compute', hiera('step')])
 136 package_manifest{$package_manifest_name: ensure => present}