puppet/manifests/overcloud_compute.pp

   1 # Copyright 2014 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 create_resources(kmod::load, hiera('kernel_modules'), { })
  20 create_resources(sysctl::value, hiera('sysctl_settings'), { })
  21 Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  22
  23 if count(hiera('ntp::servers')) > 0 {
  24   include ::ntp
  25 }
  26
  27 include ::timezone
  28
  29 if hiera('step') >= 4 {
  30
  31   file { ['/etc/libvirt/qemu/networks/autostart/default.xml',
  32     '/etc/libvirt/qemu/networks/default.xml']:
  33     ensure => absent,
  34     before => Service['libvirt'],
  35   }
  36   # in case libvirt has been already running before the Puppet run, make
  37   # sure the default network is destroyed
  38   exec { 'libvirt-default-net-destroy':
  39     command => '/usr/bin/virsh net-destroy default',
  40     onlyif  => '/usr/bin/virsh net-info default | /bin/grep -i "^active:\s*yes"',
  41     before  => Service['libvirt'],
  42   }
  43
  44   # When utilising images for deployment, we need to reset the iSCSI initiator name to make it unique
  45   exec { 'reset-iscsi-initiator-name':
  46     command => '/bin/echo InitiatorName=$(/usr/sbin/iscsi-iname) > /etc/iscsi/initiatorname.iscsi',
  47     onlyif  => '/usr/bin/test ! -f /etc/iscsi/.initiator_reset',
  48   }->
  49
  50   file { '/etc/iscsi/.initiator_reset':
  51     ensure => present,
  52   }
  53
  54   $rbd_ephemeral_storage = hiera('nova::compute::rbd::ephemeral_storage', false)
  55   $rbd_persistent_storage = hiera('rbd_persistent_storage', false)
  56   if $rbd_ephemeral_storage or $rbd_persistent_storage {
  57     if str2bool(hiera('ceph_ipv6', false)) {
  58       $mon_host = hiera('ceph_mon_host_v6')
  59     } else {
  60       $mon_host = hiera('ceph_mon_host')
  61     }
  62     class { '::ceph::profile::params':
  63       mon_host            => $mon_host,
  64     }
  65     include ::ceph::conf
  66     include ::ceph::profile::client
  67
  68     $client_keys = hiera('ceph::profile::params::client_keys')
  69     $client_user = join(['client.', hiera('tripleo::profile::base::cinder::volume::rbd::cinder_rbd_user_name')])
  70     class { '::nova::compute::rbd':
  71       libvirt_rbd_secret_key => $client_keys[$client_user]['secret'],
  72     }
  73   }
  74
  75   if hiera('cinder_enable_nfs_backend', false) {
  76     if str2bool($::selinux) {
  77       selboolean { 'virt_use_nfs':
  78         value      => on,
  79         persistent => true,
  80       } -> Package['nfs-utils']
  81     }
  82
  83     package { 'nfs-utils': } -> Service['nova-compute']
  84   }
  85
  86   if str2bool(hiera('nova::use_ipv6', false)) {
  87     $vncserver_listen = '::0'
  88   } else {
  89     $vncserver_listen = '0.0.0.0'
  90   }
  91
  92   if $rbd_ephemeral_storage {
  93     class { '::nova::compute::libvirt':
  94       libvirt_disk_cachemodes => ['network=writeback'],
  95       libvirt_hw_disk_discard => 'unmap',
  96       vncserver_listen        => $vncserver_listen,
  97     }
  98   } else {
  99     class { '::nova::compute::libvirt' :
 100       vncserver_listen => $vncserver_listen,
 101     }
 102   }
 103
 104   nova_config {
 105     'DEFAULT/my_ip': value => $ipaddress;
 106     'DEFAULT/linuxnet_interface_driver': value => 'nova.network.linux_net.LinuxOVSInterfaceDriver';
 107   }
 108
 109   if hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 110     file { '/etc/libvirt/qemu.conf':
 111       ensure  => present,
 112       content => hiera('midonet_libvirt_qemu_data')
 113     }
 114   }
 115   include ::nova::network::neutron
 116   include ::neutron
 117   include ::neutron::config
 118
 119   # If the value of core plugin is set to 'nuage',
 120   # include nuage agent,
 121   # If the value of core plugin is set to 'midonet',
 122   # include midonet agent,
 123   # else use the default value of 'ml2'
 124   if hiera('neutron::core_plugin') == 'neutron.plugins.nuage.plugin.NuagePlugin' {
 125     include ::nuage::vrs
 126     include ::nova::compute::neutron
 127
 128     class { '::nuage::metadataagent':
 129       nova_os_tenant_name => hiera('nova::api::admin_tenant_name'),
 130       nova_os_password    => hiera('nova_password'),
 131       nova_metadata_ip    => hiera('nova_metadata_node_ips'),
 132       nova_auth_ip        => hiera('keystone_public_api_virtual_ip'),
 133     }
 134   }
 135   elsif hiera('neutron::core_plugin') == 'midonet.neutron.plugin_v1.MidonetPluginV2' {
 136
 137     # TODO(devvesa) provide non-controller ips for these services
 138     $zookeeper_node_ips = hiera('neutron_api_node_ips')
 139     $cassandra_node_ips = hiera('neutron_api_node_ips')
 140
 141     class { '::tripleo::network::midonet::agent':
 142       zookeeper_servers => $zookeeper_node_ips,
 143       cassandra_seeds   => $cassandra_node_ips
 144     }
 145   }
 146   elsif hiera('neutron::core_plugin') == 'neutron_plugin_contrail.plugins.opencontrail.contrail_plugin.NeutronPluginContrailCoreV2' {
 147
 148     include ::contrail::vrouter
 149     # NOTE: it's not possible to use this class without a functional
 150     # contrail controller up and running
 151     #class {'::contrail::vrouter::provision_vrouter':
 152     #  require => Class['contrail::vrouter'],
 153     #}
 154   }
 155   elsif hiera('neutron::core_plugin') == 'networking_plumgrid.neutron.plugins.plugin.NeutronPluginPLUMgridV2' {
 156     # forward all ipv4 traffic
 157     # this is required for the vms to pass through the gateways public interface
 158     sysctl::value { 'net.ipv4.ip_forward': value => '1' }
 159
 160     # ifc_ctl_pp needs to be invoked by root as part of the vif.py when a VM is powered on
 161     file { '/etc/sudoers.d/ifc_ctl_sudoers':
 162       ensure  => file,
 163       owner   => root,
 164       group   => root,
 165       mode    => '0440',
 166       content => "nova ALL=(root) NOPASSWD: /opt/pg/bin/ifc_ctl_pp *\n",
 167     }
 168   }
 169   else {
 170
 171     # NOTE: this code won't live in puppet-neutron until Neutron OVS agent
 172     # can be gracefully restarted. See https://review.openstack.org/#/c/297211
 173     # In the meantime, it's safe to restart the agent on each change in neutron.conf,
 174     # because Puppet changes are supposed to be done during bootstrap and upgrades.
 175     # Some resource managed by Neutron_config (like messaging and logging options) require
 176     # a restart of OVS agent. This code does it.
 177     # In Newton, OVS agent will be able to be restarted gracefully so we'll drop the code
 178     # from here and fix it in puppet-neutron.
 179     Neutron_config<||> ~> Service['neutron-ovs-agent-service']
 180
 181     include ::neutron::plugins::ml2
 182     include ::neutron::agents::ml2::ovs
 183
 184     if 'cisco_n1kv' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 185       class { '::neutron::agents::n1kv_vem':
 186         n1kv_source  => hiera('n1kv_vem_source', undef),
 187         n1kv_version => hiera('n1kv_vem_version', undef),
 188       }
 189     }
 190
 191     if 'bsn_ml2' in hiera('neutron::plugins::ml2::mechanism_drivers') {
 192       include ::neutron::agents::bigswitch
 193     }
 194   }
 195
 196   include ::ceilometer
 197   include ::ceilometer::config
 198   include ::ceilometer::agent::compute
 199   include ::ceilometer::agent::auth
 200
 201   $snmpd_user = hiera('snmpd_readonly_user_name')
 202   snmp::snmpv3_user { $snmpd_user:
 203     authtype => 'MD5',
 204     authpass => hiera('snmpd_readonly_user_password'),
 205   }
 206   class { '::snmp':
 207     agentaddress => ['udp:161','udp6:[::1]:161'],
 208     snmpd_config => [ join(['createUser ', hiera('snmpd_readonly_user_name'), ' MD5 "', hiera('snmpd_readonly_user_password'), '"']), join(['rouser ', hiera('snmpd_readonly_user_name')]), 'proc  cron', 'includeAllDisks  10%', 'master agentx', 'trapsink localhost public', 'iquerySecName internalUser', 'rouser internalUser', 'defaultMonitors yes', 'linkUpDownNotifications yes' ],
 209   }
 210
 211   hiera_include('compute_classes')
 212   package_manifest{ '/var/lib/tripleo/installed-packages/overcloud_compute': ensure => present }
 213
 214 }