puppet/manifests/overcloud_cephstorage.pp

   1 # Copyright 2015 Red Hat, Inc.
   2 # All Rights Reserved.
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   5 # not use this file except in compliance with the License. You may obtain
   6 # a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  12 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  13 # License for the specific language governing permissions and limitations
  14 # under the License.
  15
  16 include ::tripleo::packages
  17 include ::tripleo::firewall
  18
  19 if hiera('step') >= 1 {
  20
  21   create_resources(kmod::load, hiera('kernel_modules'), {})
  22   create_resources(sysctl::value, hiera('sysctl_settings'), {})
  23   Exec <| tag == 'kmod::load' |>  -> Sysctl <| |>
  24
  25   include ::timezone
  26
  27 }
  28
  29 if hiera('step') >= 3 {
  30   if str2bool(hiera('ceph_osd_selinux_permissive', true)) {
  31     exec { 'set selinux to permissive on boot':
  32       command => "sed -ie 's/^SELINUX=.*/SELINUX=permissive/' /etc/selinux/config",
  33       onlyif  => "test -f /etc/selinux/config && ! grep '^SELINUX=permissive' /etc/selinux/config",
  34       path    => ['/usr/bin', '/usr/sbin'],
  35     }
  36
  37     exec { 'set selinux to permissive':
  38       command => 'setenforce 0',
  39       onlyif  => "which setenforce && getenforce | grep -i 'enforcing'",
  40       path    => ['/usr/bin', '/usr/sbin'],
  41     } -> Class['ceph::profile::osd']
  42   }
  43
  44   if str2bool(hiera('ceph_ipv6', false)) {
  45     $mon_host = hiera('ceph_mon_host_v6')
  46   } else {
  47     $mon_host = hiera('ceph_mon_host')
  48   }
  49   class { '::ceph::profile::params':
  50     mon_host            => $mon_host,
  51   }
  52   include ::ceph::conf
  53   include ::ceph::profile::client
  54   include ::ceph::profile::osd
  55
  56   hiera_include('ceph_classes')
  57 }
  58
  59 $package_manifest_name = join(['/var/lib/tripleo/installed-packages/overcloud_ceph', hiera('step')])
  60 package_manifest{$package_manifest_name: ensure => present}