kernel/arch/tile/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3 #include <asm/cache.h>
   4 #include <asm/thread_info.h>
   5 #include <hv/hypervisor.h>
   6
   7 /* Text loads starting from the supervisor interrupt vector address. */
   8 #define TEXT_OFFSET MEM_SV_START
   9
  10 OUTPUT_ARCH(tile)
  11 ENTRY(_start)
  12 jiffies = jiffies_64;
  13
  14 PHDRS
  15 {
  16   intrpt PT_LOAD ;
  17   text PT_LOAD ;
  18   data PT_LOAD ;
  19 }
  20 SECTIONS
  21 {
  22   /* Text is loaded with a different VA than data; start with text. */
  23   #undef LOAD_OFFSET
  24   #define LOAD_OFFSET TEXT_OFFSET
  25
  26   /* Interrupt vectors */
  27   .intrpt (LOAD_OFFSET) : AT ( 0 )   /* put at the start of physical memory */
  28   {
  29     _text = .;
  30     *(.intrpt)
  31   } :intrpt =0
  32
  33   /* Hypervisor call vectors */
  34   . = ALIGN(0x10000);
  35   .hvglue : AT (ADDR(.hvglue) - LOAD_OFFSET) {
  36     *(.hvglue)
  37   } :NONE
  38
  39   /* Now the real code */
  40   . = ALIGN(0x20000);
  41   _stext = .;
  42   .text : AT (ADDR(.text) - LOAD_OFFSET) {
  43     HEAD_TEXT
  44     SCHED_TEXT
  45     LOCK_TEXT
  46     KPROBES_TEXT
  47     IRQENTRY_TEXT
  48     __fix_text_end = .;   /* tile-cpack won't rearrange before this */
  49     ALIGN_FUNCTION();
  50     *(.hottext*)
  51     TEXT_TEXT
  52     *(.text.*)
  53     *(.coldtext*)
  54     *(.fixup)
  55     *(.gnu.warning)
  56   } :text =0
  57   _etext = .;
  58
  59   /* "Init" is divided into two areas with very different virtual addresses. */
  60   INIT_TEXT_SECTION(PAGE_SIZE)
  61
  62   /* Now we skip back to PAGE_OFFSET for the data. */
  63   . = (. - TEXT_OFFSET + PAGE_OFFSET);
  64   #undef LOAD_OFFSET
  65   #define LOAD_OFFSET PAGE_OFFSET
  66
  67   . = ALIGN(PAGE_SIZE);
  68   __init_begin = .;
  69   INIT_DATA_SECTION(16) :data =0
  70   PERCPU_SECTION(L2_CACHE_BYTES)
  71   . = ALIGN(PAGE_SIZE);
  72   __init_end = .;
  73
  74   _sdata = .;                   /* Start of data section */
  75   RO_DATA_SECTION(PAGE_SIZE)
  76   RW_DATA_SECTION(L2_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  77   _edata = .;
  78
  79   EXCEPTION_TABLE(L2_CACHE_BYTES)
  80   NOTES
  81
  82
  83   BSS_SECTION(8, PAGE_SIZE, 1)
  84   _end = . ;
  85
  86   STABS_DEBUG
  87   DWARF_DEBUG
  88
  89   DISCARDS
  90 }